[cezars]

Can anyone make a plugin to use more the 1 sv_downloadurl ?it can be done ? if someone can that will be great couse some of the ftps are limited no more then 1 gb or .... pls drop me a link if someone can do this

[Bugsy]

You could make a plugin that cycles through a list of download URLs; the game does not support using more than 1 at a time. Perhaps to avoid the bandwidth limit, you could cycle to the next download URL after X clients connect to the server.

If you are interested I can write this up for you.

[KadiR]

im interested too

[koleos]

Same here

[ConnorMcLeod]

I have this amx plugin :

Basically, you have to store all default files on all urls (plugins models/sprites/sounds), but you can dispatch maps (and attachments) files on specific url?
Code have to be ported to amxx.
May be this event could be replaced with plugin_end() forward

PHP Code:

#include <amxmod>

public plugin_init() 
{
    register_plugin("Download URL", "0.1", "KRoT@L")
    register_event( "30" , "changeMap", "a" )
}

public changeMap()
{
    new nextmap[32], filename[128], text[128]
    get_cvar_string("amx_nextmap", nextmap, 31)
    format(filename, 127, "addons/amx/config/maps/%s.cfg", nextmap)
    new len, i = 0
    if(file_exists(filename))
    { 
        while(read_file(filename,i++,text,127,len))
        {
            if(containi(text, "sv_downloadurl") != -1)
            {
                new var[64], downloadurl[128]
                parse(text, var, 63, downloadurl, 127)
                set_cvar_string("sv_downloadurl", downloadurl)
                return PLUGIN_CONTINUE
            }
        }
    }

    return PLUGIN_CONTINUE
} 


[Bugsy]

This will load your URLs from a file and then rotate through the list.

Example:

Suppose you have 3 download URLs in the file. For this example I will use 10 as the connecting player number at which we will rotate to the next URL. You can change this by setting the cvar downloadurl_rotate to the appropriate number.

Server start\map-change, all URLs get loaded from file, sv_downloadurl set to URL1
When the 10th player connects to server, sv_downloadurl gets set to URL2
When the 10th player connects to server, sv_downloadurl gets set to URL3
When the 10th player connects to server, sv_downloadurl gets set to URL1
When the 10th player connects to server, sv_downloadurl gets set to URL2
When the 10th player connects to server, sv_downloadurl gets set to URL3

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN    "sv_downloadurl Rotator"
#define VERSION    "1.0"
#define AUTHOR    "bugsy"

#define MAX_URLS    10
#define MAX_SIZE    64

/* Create file [addons/amxmodx/configs/downloadurls.txt] with the URLs in below format:

http://www.theurl.net/whatever/
http://www.thenexturl.org/location/of/files/
http://www.anotherurl.net/~hi/

Currently the plugin supports 10 URLs but you can increase this if you want.*/
    
new g_iNumberConnections = -1;        //Connection counter for current URL
new g_iCurrentURL;            //Current URL index of g_szURL

new g_szURL[MAX_URLS][MAX_SIZE];    //Array of URLs loaded from file
new g_iNumURL;                //Number of URLs loaded from file

new g_pDownloadURL            //CVar pointer for sv_downloadurl
new g_pURLRotate;            //CVar specifying at how many connections to move to next URL
new g_pEnabled;                //CVar to enable\disable. If no URLs are loaded from file the plugin will
                    //automatically disable itself.

new const g_szURLFile[] = "addons/amxmodx/configs/downloadurls.txt";

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_pDownloadURL = get_cvar_pointer( "sv_downloadurl" );
    g_pURLRotate = register_cvar( "downloadurl_rotate" , "10" );
    g_pEnabled = register_cvar(" downloadurl_enable" , "1" );
}

public plugin_cfg()
{
    g_iNumURL = ReadURL();
    
    if ( g_iNumURL > -1 )
        set_pcvar_string( g_pDownloadURL , g_szURL[ g_iCurrentURL ] );
    else
        set_pcvar_string( g_pEnabled , "0" );
}

public client_connect(id)
{
    if ( !get_pcvar_num( g_pEnabled ) || is_user_bot( id ) )
        return PLUGIN_CONTINUE;
        
    if ( ++g_iNumberConnections >= get_pcvar_num( g_pURLRotate ) )
    {
        if ( ++g_iCurrentURL > g_iNumURL )
            g_iCurrentURL = 0;
            
        set_pcvar_string( g_pDownloadURL , g_szURL[ g_iCurrentURL ] );
        
        g_iNumberConnections = 0;
    }
    
    return PLUGIN_CONTINUE;
}
        
public ReadURL()
{
    if ( !file_exists( g_szURLFile ) )
        return -1;
        
    new iHandle = fopen( g_szURLFile , "rt" );
    new iURL = -1;
    new iLen;
    
    if ( !iHandle )
        return -1;
    
    while ( !feof( iHandle ) )
    {
        iLen = fgets ( iHandle , g_szURL[ ++iURL ] , MAX_SIZE - 1 );
        
        //Skip line-items that begin with a space or new line
        if ( !iLen || ( g_szURL[ iURL ][ 0 ] == ' ' ) || ( g_szURL[ iURL ][ 0 ] == '^n' ) )
            g_szURL[ iURL-- ][ 0 ] = 0;
        else if ( g_szURL[ iURL ][ iLen-1 ] == '^n' )
            g_szURL[ iURL ][ iLen-1 ] = 0;
    }
    
    fclose( iHandle );
    
    return iURL;
} 


[ConnorMcLeod]

I don't think he wants few urls because of limited traffic, but because of the place he has on ftps.

I think there's a tip to do to redirect 1st url to 2nd one if a requested file is not on the first one (with apache ?)

[Exolent[jNr]]

@Bugsy

public plugin_cfg()
{
    g_iNumURL = ReadURL();
    
    if ( g_iNumURL )
        set_pcvar_string( g_pDownloadURL , g_szURL[ g_iCurrentURL ] );
    else
        set_pcvar_string( g_pEnabled , "0" );
}

Should be:

public plugin_cfg()
{
    g_iNumURL = ReadURL();
    
    if ( g_iNumURL > 0 )
        set_pcvar_string( g_pDownloadURL , g_szURL[ g_iCurrentURL ] );
    else
        set_pcvar_string( g_pEnabled , "0" );
}

Because ReadUrl() can return -1 if the file exists but is empty.

[Bugsy]

What I ascertained out of his post\request is he is trying to avoid excessive bandwidth usage on a single URL and would like to use multiple URLs so one does not get over-used.

Edit: Thx Exolent

[cezars]

many thx to all for enswer so fast is not abbout avoid bandwidth usage its abbout space on ftps i have 5gb of maps and other stuff moust of the host dont have more then 1gb space and i need to put 800mb -1gb maps and stuf to each host and if 1 host dont have that maps that i change to go to next one