[micapat]

Bonjour

Je tente de "spawner" une arme, ca m'affiche le model mais ce n'est pas réellement une armoury_entity : le model 'ne tombe pas' et n'est pas une arme (impossible de ramasser l'arme).

Code :

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <engine>

#define PLUGIN "Test_Arme"
#define VERSION "1.0"
#define AUTHOR "Mariko <3"

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /test","Spawn_Armoury");
}

public Spawn_Armoury(id)
{
    new Float:Origin[3] = {0.0, 0.0, 0.0};
    new ent = create_entity("armoury_entity");
    entity_set_model(ent, "models/w_mp5.mdl");
    entity_set_origin(ent,Origin);
    
    client_print(id, print_chat, "Entite placer : %d", ent); // Vérification
} 


Merci d'avance =)

[ConnorMcLeod]

PHP Code:

public plugin_init()
{
    register_clcmd("say /mp5", "Spawn_MP5")
    register_clcmd("say /m4a1", "Spawn_M4A1")
}

public Spawn_MP5(id)
{
    new iOrigin[3]
    get_user_origin(id, iOrigin, 3)
    iOrigin[2] += 32

    new Float:vecOrigin[3]
    IVecFVec(iOrigin, vecOrigin)

    client_print(id, print_chat, "Entite placer : %d", SpawnArmouryEntity(CSW_MP5NAVY, vecOrigin) ); // Vérification
}

public Spawn_M4A1(id)
{
    new iOrigin[3]
    get_user_origin(id, iOrigin, 3)
    iOrigin[2] += 32

    new Float:vecOrigin[3]
    IVecFVec(iOrigin, vecOrigin)

    client_print(id, print_chat, "Entite placer : %d", SpawnArmouryEntity(CSW_M4A1, vecOrigin, "10") ); // Vérification
} 


Version engine :

PHP Code:

SpawnArmouryEntity(CSW_WEAPONID, Float:vecOrigin[3], szCount[] = "1")
{
    new iEnt = create_entity("armoury_entity")

    if( iEnt > 0 && cs_set_armoury_type(iEnt, CSW_WEAPONID) )
    {
        DispatchKeyValue(iEnt, "count", szCount)
        entity_set_vector(iEnt, EV_VEC_origin, vecOrigin)
        DispatchSpawn(iEnt)
        return iEnt
    }
    return 0
} 


fakemeta :

PHP Code:

SpawnArmouryEntity(CSW_WEAPONID, Float:vecOrigin[3], iCount = 1)
{
    static iszArmouryEntity
    if( !iszArmouryEntity )
    {
        iszArmouryEntity = engfunc(EngFunc_AllocString, "armoury_entity")
    }

    new iEnt = engfunc(EngFunc_CreateNamedEntity, iszArmouryEntity)

    if( iEnt > 0 && cs_set_armoury_type(iEnt, CSW_WEAPONID) )
    {
        #define XO_ARMOURY_ENTITY 4
        #define m_iCount 35
        set_pdata_int(iEnt, m_iCount, iCount, XO_ARMOURY_ENTITY)
        set_pev(iEnt, pev_origin, vecOrigin)
        dllfunc(DLLFunc_Spawn, iEnt)
        return iEnt
    }
    return 0
} 


Note: je n'utilise ni set_entity_origin ni EngFunc_SetOrigin car on spawn l'entité donc l'origine (de même que le model) est réglé à ce moment là.

[micapat]

Ok ok, j'essaie d'apprendre là à relier un peu mapping à plugin =)

Merci beaucoup

[ConnorMcLeod]

Dans ce cas regarde du côté du HLSDK : http://metamod.sourceforge.net/files/sdk/
C'est du C/C++ mais c'est très lisible quand on connait le pawn.
C'est franchement LA référence.

Arkshine a déjà décompilé et retranscrit quelques (quelques mais c'est un boulot énorme) parties du cssdk : http://cs-sdk.googlecode.com/svn/trunk/

[Arkshine]

Faudrait p-e que je m'y remette d'ailleurs !

[ConnorMcLeod]

Ah, t'as fini cs-amx ?

[Arkshine]

Ah merde.

En fait, ca avance quand même :p.