[SM9]

Right, so I have made a quick system which adds weapons to an array then respawns them.

But it appears that midway through my loop, my client index becomes invalid, this makes no sense whatsoever.

Here are the error logs:

PHP Code:

L 12/05/2016 - 21:38:48: [manicure.smx] Client is named SM9(); [1]
L 12/05/2016 - 21:38:48: [manicure.smx] Client is named Console [2]
L 12/05/2016 - 21:38:48: [manicure.smx] Client is named Console [3]
L 12/05/2016 - 21:38:48: [manicure.smx] Client is named Console [4]
L 12/05/2016 - 21:38:48: [manicure.smx] Client is named Console [5]
L 12/05/2016 - 21:38:48: [SM] Exception reported: Entity index 0 is not a valid client
L 12/05/2016 - 21:38:48: [SM] Blaming: manicure.smx
L 12/05/2016 - 21:38:48: [SM] Call stack trace:
L 12/05/2016 - 21:38:48: [SM]   [0] GivePlayerItem
L 12/05/2016 - 21:38:48: [SM]   [1] Line 417, C:\Users\Michael\Documents\manicure.sp::Timer_GiveWeapons
L 12/05/2016 - 21:38:48: [SM] Exception reported: Invalid Handle 0 (error: 4)
L 12/05/2016 - 21:38:48: [SM] Blaming: manicure.smx
L 12/05/2016 - 21:38:48: [SM] Call stack trace:
L 12/05/2016 - 21:38:48: [SM]   [0] ArrayList.Length.get
L 12/05/2016 - 21:38:48: [SM]   [1] Line 392, C:\Users\Michael\Documents\manicure.sp::Timer_GiveWeapons
L 12/05/2016 - 21:38:48: [SM] Exception reported: Invalid Handle 0 (error: 4)
L 12/05/2016 - 21:38:48: [SM] Blaming: manicure.smx
L 12/05/2016 - 21:38:48: [SM] Call stack trace:
L 12/05/2016 - 21:38:48: [SM]   [0] ArrayList.Clear
L 12/05/2016 - 21:38:48: [SM]   [1] Line 422, C:\Users\Michael\Documents\manicure.sp::Timer_GiveWeapons
L 12/05/2016 - 21:38:48: [SM] Exception reported: Stack leak detected: sp:4402556 should be 4402564! 


Here is the code:

PHP Code:

stock void AddToWeaponRespawnArray(int iClient, int iWeapon = -1, const char[] chClassName)
{
    if (g_alGiveWeapons[iClient] == null) {
        g_alGiveWeapons[iClient] = new ArrayList(128);
    }
    
    CEconItemView ceItem; int iReserveAmmo = -1; int iClipAmmo = -1;
    
    if (IsValidEntity(iWeapon)) {
        ceItem = PTaH_GetEconItemViewFromWeapon(iWeapon);
        iReserveAmmo = GetEntProp(iWeapon, Prop_Send, "m_iPrimaryReserveAmmoCount");
        iClipAmmo = GetEntProp(iWeapon, Prop_Send, "m_iClip1");
    }
    
    int iValues[4];
    
    iValues[0] = iReserveAmmo;
    iValues[1] = iClipAmmo;
    iValues[2] = view_as<int>(ceItem);
    iValues[3] = StringToInt(chClassName);
    
    g_alGiveWeapons[iClient].PushArray(iValues);
}

public Action Timer_GiveWeapons(Handle hTimer, int iSerial)
{
    int iClient = GetClientFromSerial(iSerial);
    
    if (!IsValidClient(iClient)) {
        return Plugin_Stop;
    }
    
    if (!IsPlayerAlive(iClient)) {
        return Plugin_Continue;
    }
    
    char chBuffer[64]; int iValues[4];
    
    for (int i = 0; i < g_alGiveWeapons[iClient].Length; i++) {
        LogError("Client is named %N [1]", iClient);
        
        g_alGiveWeapons[iClient].GetArray(i, iValues);
        
        LogError("Client is named %N [2]", iClient);
        
        int iReserveAmmo = iValues[0]; int iClipAmmo = iValues[1];
        
        LogError("Client is named %N [3]", iClient);
        
        CEconItemView ceItem = view_as<CEconItemView>(iValues[2]); 
        
        LogError("Client is named %N [4]", iClient);
        
        IntToString(iValues[2], chBuffer, 64);
        
        LogError("Client is named %N [5]", iClient);
        
        if (StrEqual(chBuffer, "weapon_c4", false)) {
            PTaH_GivePlayerItem(iClient, "weapon_c4", ceItem);
        } else {
            if (iReserveAmmo > -1 || iClipAmmo > -1) {
                CSGOItems_GiveWeapon(iClient, chBuffer, iReserveAmmo, iClipAmmo, CSGOItems_GetActiveWeaponSlot(iClient));
            } else {
                GivePlayerItem(iClient, chBuffer);
            }
        }
    }
    
    g_alGiveWeapons[iClient].Clear();
    g_bGivingWeaponsPending[iClient] = false;
    delete g_alGiveWeapons[iClient];
    
    g_hGiveTimer[iClient] = null;
    return Plugin_Stop;
} 


Should I file a bug report?

[Fyren]

What's your compiler version?

[Grey83]

You need add this

PHP Code:

public Action Timer_GiveWeapons(Handle hTimer, int iSerial) 
{ 
    int iClient = GetClientFromSerial(iSerial); 
     
    if (!iClient && !IsValidClient(iClient)) { 
        return Plugin_Stop; 
    } 


or add this check in function IsValidClient()
Bkz

GetClientFromSerial Function Returns the client index by its serial number. int GetClientFromSerial(int serial) Parameters int serial Serial number. Return Value Client index, or 0 for invalid serial.

[Grey83]

Wait

L 12/05/2016 - 218:48: [manicure.smx] Client is named SM9(); [1] L 12/05/2016 - 218:48: [manicure.smx] Client is named Console [2]

A player at this moment gone from the server?

Why not just make something like that?

PHP Code:

int iBufferValues[MAXPLAYERS+1][4];

stock void AddToWeaponRespawnArray(int iClient, int iWeapon = -1, const char[] chClassName)
{
    if(!iClient || !IsValidClient(iClient)) return;

    iBufferValues[0] = iBufferValues[1] = -1;
    if (IsValidEntity(iWeapon))
    {
        iBufferValues[iClient][0] = GetEntProp(iWeapon, Prop_Send, "m_iPrimaryReserveAmmoCount");
        iBufferValues[iClient][1] = GetEntProp(iWeapon, Prop_Send, "m_iClip1");
        iBufferValues[iClient][2] = view_as<int>(PTaH_GetEconItemViewFromWeapon(iWeapon));
        iBufferValues[iClient][3] = StringToInt(chClassName);
    }
}

public Action Timer_GiveWeapons(Handle hTimer, int iSerial)
{
    int iClient = GetClientFromSerial(iSerial);

    if (!IsValidClient(iClient)) return Plugin_Stop;

    if (!IsPlayerAlive(iClient)) return Plugin_Continue;

    int iReserveAmmo = iBufferValues[iClient][0];
    int iClipAmmo = iBufferValues[iClient][1];
    CEconItemView ceItem = view_as<CEconItemView>(iBufferValues[iClient][2]);
    char chBuffer[64];
    IntToString(iBufferValues[3], chBuffer, 64);

    if (StrEqual(chBuffer, "weapon_c4", false))
        PTaH_GivePlayerItem(iClient, "weapon_c4", ceItem);
    else
    {
        if (iReserveAmmo > -1 || iClipAmmo > -1)
            CSGOItems_GiveWeapon(iClient, chBuffer, iReserveAmmo, iClipAmmo, CSGOItems_GetActiveWeaponSlot(iClient));
        else GivePlayerItem(iClient, chBuffer);
    }

    g_bGivingWeaponsPending[iClient] = false;

    g_hGiveTimer[iClient] = null;
    return Plugin_Stop;
} 


[Peace-Maker]

You creatrle the ArrayList with a blocksize of 128, but only store arrays of size 4 in it.

The docs say, you have to use the |size| parameter when using the GetArrayArray functions with a different sized array. Otherwise it will assume the array has the same size as the block size and paper over random plugin memory, if you pass a smaller buffer.

[Miu]

lol wtf every string function requires size parameter, why is it suddenly optional there?

[Fyren]

It's not a "string function."

[Miu]

=__= yes, but they have exactgly the same problem