[micapat]

Hi everyone,

I'm trying to spawn an entity which can be destroyed ( Example: a crate, ... ).

The entity spawns, collides with players, shows the bullet impacts ( Sparks ) but can't be destroyed.

Did I miss something?

PHP Code:

public void Crate_Spawn( const float vOrigin[ 3 ], const float vAngle[ 3 ] )
{
    int iCrate = CreateEntityByName( "prop_dynamic_override" );
    
    if( IsValidEdict( iCrate ))
    {
        DispatchKeyValue( iCrate, "Model", "models/props_unique/atm01.mdl" );
        DispatchKeyValue( iCrate, "Health", "10" ); // Need something else?
        DispatchKeyValue( iCrate, "Solid", "6" );
        DispatchSpawn( iCrate );
        TeleportEntity( iCrate, vOrigin, vAngle, NULL_VECTOR );
        
        HookSingleEntityOutput( iCrate, "OnBreak", Crate_Break, true );
    }
}

public void Crate_Break( const char[ ] szOutput, int iCaller, int iActivator, float flDelay )
{
    PrintToChatAll( "Check OK" );
} 


Thanks you

[micapat]

Bump.

Even by setting the health after the DispatchSpawn ( With SetEntityHealth ), nothing happen. Is there a flag / bool that I missed ..?

Valve wiki for this entity: https://developer.valvesoftware.com/...namic_override ( "It can also be configured to break when it takes enough damage" ? ).

[VoiDeD]

Have you tried the m_takedamage sendprop?

https://mxr.alliedmods.net/hl2sdk-sd...areddefs.h#447

[micapat]

Thank you VoiDeD, it works now .

/!\ "Prop_Data" must be used!

PHP Code:

public void Crate_Spawn( const float vOrigin[ 3 ], const float vAngle[ 3 ] )
{
    int iCrate = CreateEntityByName( "prop_dynamic_override" );
    
    if( IsValidEdict( iCrate ))
    {
        DispatchKeyValue( iCrate, "Model", "models/props_unique/atm01.mdl" );
        DispatchKeyValue( iCrate, "Solid", "6" );
        DispatchSpawn( iCrate );
        
        SetEntProp( iCrate, Prop_Data, "m_iHealth", 100 );
        SetEntProp( iCrate, Prop_Data, "m_takedamage", 2 );
        
        TeleportEntity( iCrate, vOrigin, vAngle, NULL_VECTOR );
        
        HookSingleEntityOutput( iCrate, "OnBreak", Crate_Break, true );
    }
}