[wwahgnerbp]

Hello I'm trying to transfer this to the new syntax:

stock ZMarketCookiesToArray(client, String:rebuyweapons[WeaponsSlot][], maxweapons, maxlen)

becoming:

stock void ZMarketCookiesToArray(int client, String:rebuyweapons[WeaponsSlot][], int maxweapons, int maxlen)

the problem is that I have no idea how to convert the String: tagging thing. The transitional API says that we need to specify the size if the brackets come after the variable then I try this:

stock void ZMarketCookiesToArray(int client, char rebuyweapons[WeaponsSlot][], int maxweapons, int maxlen)

where WeaponsSlot is an enum:

/**
 * Weapon slots.
 */
enum WeaponsSlot
{
	Slot_Invalid		= -1,   /** Invalid weapon (slot). */
	Slot_Primary		= 0,	/** Primary weapon slot. */
	Slot_Secondary	  = 1,	/** Secondary weapon slot. */
	Slot_Melee		  = 2,	/** Melee (knife) weapon slot. */
	Slot_Projectile	 = 3,	/** Projectile (grenades, flashbangs, etc) weapon slot. */
	Slot_Explosive	  = 4,	/** Explosive (c4) weapon slot. */
	Slot_NVGs		   = 5,	/** NVGs (fake) equipment slot. */
}

but the compiler gives me this:

error 159: brackets after variable name indicate a fixed-size array, but size could not be determined - either specify sizes, an array initializer, or use dynamic syntax (such as 'char[] x')

Is there a possibility to solve that?

Also I have another doubt.

Usually when we want to declare multiple variables with the same value we do:

int a, b, c, d; (all initialized as 0)

in the old syntax we could do this:

new targets[MAXPLAYERS], bool:tn_is_ml, result;

how can I do the same thing in the new syntax?

If I try to make it like:

int targets[MAXPLAYERS], bool tn_is_ml, result;

it won't work and the compiler suggest to use the operator view_as

I use that here:

result = ProcessTargetString(target, client, targets, sizeof(targets), COMMAND_FILTER_ALIVE, targetname, sizeof(targetname), tn_is_ml);

Any help will be appreciated.

[Chaosxk]

You don't have to define a size (WeaponsSlot), you can do this:

PHP Code:

stock void ZMarketCookiesToArray(int client, char[][] rebuyweapons, int maxweapons, int maxlen) 


and for your 2nd question you can do this:

PHP Code:

int targets[MAXPLAYERS]; bool tn_is_ml; int result;
result = ProcessTargetString(target, client, targets, sizeof(targets), COMMAND_FILTER_ALIVE, targetname, sizeof(targetname), tn_is_ml); 


or

PHP Code:

int targets[MAXPLAYERS], tn_is_ml, result;
result = ProcessTargetString(target, client, targets, sizeof(targets), COMMAND_FILTER_ALIVE, targetname, sizeof(targetname), view_as<bool>(tn_is_ml)); 


[wwahgnerbp]

I forgot to mention that rebuyweapons is declared like this:

char rebuyweapons[WeaponsSlot][WEAPONS_MAX_LENGTH];

Here's the full code

/**
 * Force a client to rebuy their weapons.
 * 
 * @param client	The client index.
 */
void ZMarketRebuy(int client, bool autorebuy = false)
{
	// If client is dead, then stop.
	if (!IsPlayerAlive(client))
	{
		TranslationPrintToChat(client, "Must be alive");
		return;
	}
	
	// If client is a zombie, then stop.
	if (InfectIsClientInfected(client))
	{
		TranslationPrintToChat(client, "Must be human");
		return;
	}
	
	bool zmarketbuyzone = GetConVarBool(g_hCvarsList[CVAR_WEAPONS_ZMARKET_BUYZONE]);
	if (!autorebuy && zmarketbuyzone && !WeaponsIsClientInBuyZone(client))
	{
		TranslationPrintToChat(client, "Weapons zmarket buyzone");
		return;
	}
	
	// Transfer cookie values into an array.
	char rebuyweapons[WeaponsSlot][WEAPONS_MAX_LENGTH];
	ZMarketCookiesToArray(client, rebuyweapons, WEAPONS_SLOTS_MAX + 1, sizeof(rebuyweapons[]));
	
	
	// x = Weapon slot.
	for (int x = 0; x < WEAPONS_SLOTS_MAX + 1; x++)
	{
		// If slot is empty, then stop.
		if (!rebuyweapons[x][0])
		{
			continue;
		}
		
		ZMarketEquip(client, rebuyweapons[x], true);
	}
}

stock void ZMarketCookiesToArray(int client, char[][] rebuyweapons, int maxweapons, int maxlen)
{
	char rebuycookiename[32];
	Handle rebuycookie;
	
	// x = Weapon slot.
	for (int x = 0; x < maxweapons; x++)
	{
		// Format cookie name.
		Format(rebuycookiename, sizeof(rebuycookiename), "%s_%d", ZMARKET_COOKIE_REBUY, x);
		
		// Find cookie handle, and retrieve its value.
		rebuycookie = FindClientCookie(rebuycookiename);
		GetClientCookie(client, rebuycookie, rebuyweapons[x], maxlen);
		CloseHandle(rebuycookie);
	}
}

When I try as you suggested the compiler gives me two errors but it manages to generate the binary

// zr/weapons/zmarket.inc(116 : warning 213: tag mismatch
// zr/weapons/zmarket.inc(116 : warning 229: index tag mismatch (symbol "rebuyweapons")

What does these errors means? How can I solve that?

[WildCard65]

PHP Code:

char rebuyweapons[WeaponsSlot][WEAPONS_MAX_LENGTH] 


in param definition, but anything passed to that param must match array size (or greater?)

[Chaosxk]

Dynamic array so gotta convert it to this:

PHP Code:

char[][] rebuyweapons = new char[WeaponsSlot][WEAPONS_MAX_LENGTH];
ZMarketCookiesToArray(1, rebuyweapons, WEAPONS_SLOTS_MAX + 1, WEAPONS_MAX_LENGTH); 


[wwahgnerbp]

that makes sense now. And I have a last question I promise

let's say we have this

KnockbackSetVelocity(client, const Float:startpoint[3], const Float:endpoint[3], Float:magnitude)

if I convert the float variables to this

void KnockbackSetVelocity(int client, const float startpoint[3], const float endpoint[3], float magnitude)

can it be also expressed like this?:

void KnockbackSetVelocity(int client, const float[3] startpoint, const float[3] endpoint, float magnitude)

Is float[3] endpoint and float endpoint[3] the same thing?

I ended up having this doubt too after reading BAILOPAN's first post from 2014 where he demonstrates us how weird would it be if we try to express this using the tagging system and the declaration rules of chars also contributed to increase my doubts

his example:

native float[3] GetEntOrigin();

[Chaosxk]

Yes, they seem to work the same way.

[wwahgnerbp]

Originally Posted by Chaosxk Yes, they seem to work the same way.

Alright thank you very much!

[asherkin]

No, they're different - but the difference is immaterial until SourcePawn moves further along.

float[3] foo = type is float[3], a fixed array of 3 floats, foo is a single float[3].
float bar[3] = type is float, bar is a dynamic array of 3 floats.

You almost always want the former, especially for vectors.

[wwahgnerbp]

Originally Posted by asherkin No, they're different - but the difference is immaterial until SourcePawn moves further along. float[3] foo = type is float[3], a fixed array of 3 floats, foo is a single float[3]. float bar[3] = type is float, bar is a dynamic array of 3 floats. You almost always want the former, especially for vectors.

Alright Mr. Asher I can see now. Thank you for clarifying this.