Alongub, does this look correct to you? (TF2 Event question)

404UserNotFound · **Author**

(I'm currently out driving around town, but I'll be back in a short while!)

So I've recently gotten into the teamplay_point_capture event, and getting it set up to work properly. Here's what I've got going on in the code below:

To begin, if the "team bonus credits" CVAR is enabled, when the point is captured, the entire team gets a credit bonus, the amount of which is determined by the team bonus credits CVAR.

If that CVAR isn't enabled, we continue on anyway, and check to see how many players had just captured the point, then we give those players an amount of credits, determined by the respective CVAR.

The only reason I'm having trouble with this in particular is that i<x stuff, and the way it's set up. By using "client" in the latter part of the code, will that just make the plugin give ONE player credits? The way I'm 'reading' the code, I think in the end, "client" actually ends up "=" that "x" thing.

Does this look correct? I *think* it looks correct, I'm just not 100% sure. This is by far the most advanced thing I've ever coded

PHP Code:


			
public Event_CapturedPoint(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (g_bIsCreditsActive && g_bIsCreditsEnabled)
    {
        if (g_bTeamPointCapBonus)
        {
            new team = GetEventInt(event, "team");
            new String:teamname[MAX_LINE_WIDTH];
            GetTeamName(team, teamname, sizeof(teamname));
            
            for (new i=1; i<=MaxClients; i++)
            {
                if (IsClientInGame[i] == true)
                {
                    new teamcredits = GetConVarInt(Credits_CapturePointTeam);
                    Store_GiveCreditsToUsers(Store_GetClientAccountID(i), teamcredits);
            
                    if (GetConVarInt(Credits_CapturePointTeam) > 1)
                    {
                        PrintToChat(i, "%s%t", STORE_PREFIX, "Capture  Point Team Bonus", teamname, teamcredits, g_strCurrencyName);
                    }
                }
            }
        }
        
        decl String:g_strPointCappers[MAXPLAYERS+1] = "";
        GetEventString(event, "cappers", g_strPointCappers, MAXPLAYERS);
        new x = strlen(g_strPointCappers);
        //PrintToChatAll("Point capped by %i total players!", x);

        for(new i=0; i<x; i++)
        {
            new client = g_strPointCappers{i}; //Is the "i" supposed to be in brackets, or parenthesis?
            if (IsClientInGame[client] == true)
            {
                new credits = GetConVarInt(Credits_CapturePointPlayer);
                Store_GiveCreditsToUsers(Store_GetClientAccountID(client), credits);
                
                if (GetConVarInt(Credits_CapturePointPlayer) > 1)
                {
                    PrintToChat(client, "%s%t", STORE_PREFIX, "Capture Point Player", credits, g_strCurrencyName);
                }
            }
        }
    }
}

eXemplar · *Last edited by eXemplar; 03-12-2013 at 23:23.*

Something similar to this might be better

Code:

new team = GetEventInt(event, "team");
new accountIds[MaxClients];
new count = 0;
for (new client = 1; client <= MaxClients; client++) 
{
	if (GetClientTeam(client) == team && IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client))
	{
		accountIds[count] = Store_GetClientAccountID(client);
		count++;
	}
}
Store_GiveCreditsToUsers(accountIds, count, GetConVarInt(Credits_CapturePointTeam));

count = 0;
decl String:cappers[MAXPLAYERS+1];
if (GetEventString(event, "cappers", cappers, MAXPLAYERS) > 0)
{
	new len = strlen(cappers);
	for(new i = 0; i < len; i++)
	{
		new client = cappers{i};
		if (IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client))
		{
			accountIds[count] = Store_GetClientAccountID(client);
			count++;
		}
	}
	Store_GiveCreditsToUsers(accountIds, count, GetConVarInt(Credits_CapturePointPlayer));
}

404UserNotFound

Quote:

Originally Posted by eXemplar

Something similar to this might be better

Code:

new team = GetEventInt(event, "team");
new accountIds[MaxClients];
new count = 0;
for (new client = 1; client <= MaxClients; client++) 
{
    if (GetClientTeam(client) == team && IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client))
    {
        accountIds[count] = Store_GetClientAccountID(client);
        count++;
    }
}
Store_GiveCreditsToUsers(accountIds, count, GetConVarInt(Credits_CapturePointTeam));

count = 0;
decl String:cappers[MAXPLAYERS+1];
if (GetEventString(event, "cappers", cappers, MAXPLAYERS) > 0)
{
    new len = strlen(cappers);
    for(new i = 0; i < len; i++)
    {
        new client = cappers{i};
        if (IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client))
        {
            accountIds[count] = Store_GetClientAccountID(client);
            count++;
        }
    }
    Store_GiveCreditsToUsers(accountIds, count, GetConVarInt(Credits_CapturePointPlayer));
}

Beautiful. This shall be added right away. Thank you

I think I'lll modify the "if (IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client))" line because I've got that "new IsClientInGame[client]" thing that I'm using...either that, or I'll just remove my method, and switch every instance of my "IsClientInGame" over to the one you've put.

eXemplar

If you have a few instances of where you check for the same stuff you could try something along the lines of,

Code:

bool:IsValidClient(client)
{
	return IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client);
}

404UserNotFound · *Last edited by 404UserNotFound; 03-13-2013 at 01:10.*

Quote:

Originally Posted by eXemplar

If you have a few instances of where you check for the same stuff you could try something along the lines of,

Code:

bool:IsValidClient(client)
{
    return IsClientInGame(client) && !IsFakeClient(client) && !IsClientObserver(client);
}

Ooh, I'll definitely use that. I'm surprised I didn't think of that o_o

I've got like 20 different iterations of IsValidClient saved in a text file. Here's a good example that checks for things like if a player is coaching, or if they are the Replay thing, or if they are a Source TV client.

PHP Code:


			
stock bool:IsValidClient(i, bool:replay = true)
{
    if (i <= 0 || i > MaxClients || !IsClientInGame(i) || GetEntProp(i, Prop_Send, "m_bIsCoaching"))
    {
        return false;
    }
    if (replay && (IsClientSourceTV(i) || IsClientReplay(i)))
    {
        return false;
    }
    return true;
}

404UserNotFound

So I just ran a test compile to make sure everything I've done so far doesn't cause any issues, and to make sure I've not made any typos.

I got everything fixed up except for this one tricky little S.O.B. of an error that I can't fix.

In the code below, I've gotten 3 errors about this: "Local variable "client" shadows a variable at a preceding level". I've marked them with comments. I have no clue how to fix this and I've been googling around now for awhile and could not find any results.

PHP Code:


			
public Event_CapturedPoint(Handle:event, const String:name[], bool:dontBroadcast)
{    
    if (g_bIsCreditsActive && g_bIsCreditsEnabled)
    {
        new client = GetEventInt(event, "player");
        new team = GetEventInt(event, "team");
        new String:teamname[MAX_LINE_WIDTH];
        GetTeamName(team, teamname, sizeof(teamname));
        new accountIds[MaxClients];
        new count = 0;
        new credits_player = GetConVarInt(Credits_CapturePointPlayer);
        new credits_team = GetConVarInt(Credits_CapturePointTeam);
        new displaymsg = GetConVarInt(Credits_DisplayMessages);
        
        if (credits_team > 1)
        {
            for (new client = 1; client <= MaxClients; client++) // Foreshadows here.
            {
                if (GetClientTeam(client) == team && IsValidClient(client))
                {
                    accountIds[count] = Store_GetClientAccountID(client);
                    count++;
                }
            }
            Store_GiveCreditsToUsers(accountIds, count, credits_team);
            
            if (displaymsg == 1)
            {
                PrintToChat(team, "%s%t", STORE_PREFIX, "Capture Point Team Bonus", teamname, credits_team, g_strCurrencyName);
            }
        }

        if (credits_player > 1)
        {
            count = 0;
            decl String:cappers[MAXPLAYERS+1];
            if (GetEventString(event, "cappers", cappers, MAXPLAYERS) > 0)
            {
                new len = strlen(cappers);
                for(new i = 0; i < len; i++)
                {
                    new client = cappers{i}; // Foreshadows here.
                
                    if (IsValidClient(client))
                    {
                        accountIds[count] = Store_GetClientAccountID(client);
                        count++;
                    }
                }
                Store_GiveCreditsToUsers(accountIds, count, credits_player);
                
                if (displaymsg == 1)
                {
                    PrintToChat(client, "%s%t", STORE_PREFIX, "Capture Point Player", credits_player, g_strCurrencyName);
                }
            }
        }
    }
}


public Event_CapturedFlag(Handle:event, const String:name[], bool:dontBroadcast)
{
    if (g_bIsCreditsActive && g_bIsCreditsEnabled)
    {
        new client = GetEventInt(event, "player");
        new carrier = GetEventInt(event, "carrier");
        new team = GetEventInt(event, "team");
        new carrierid = GetClientOfUserId(carrier);
        new String:carriername[MAX_LINE_WIDTH];
        new String:teamname[MAX_LINE_WIDTH];
        GetClientName(carrierid, carriername, sizeof(carriername));
        GetTeamName(team, teamname, sizeof(teamname));

        new count = 0;
        new accountIds[MaxClients];
        
        new credits_grabbed = GetConVarInt(Credits_FlagGrabbed);
        new credits_defended = GetConVarInt(Credits_FlagDefended);
        new credits_player = GetConVarInt(Credits_FlagCapturedPlayer);
        new credits_team = GetConVarInt(Credits_FlagCapturedTeam);
        new displaymsg = GetConVarInt(Credits_DisplayMessages);
        new displaynames = GetConVarInt(Credits_DisplayNames);
        
        switch(GetEventInt(event, "eventtype"))
        {
            case 1:
            {
                if (credits_grabbed > 1)
                {
                    if (IsValidClient(client))
                    {
                        Store_GiveCredits(Store_GetClientAccountID(client), credits_grabbed);
                        
                        if (displaymsg == 1)
                        {
                            PrintToChat(client, "%s%t", STORE_PREFIX, "Flag Grabbed", credits_grabbed, g_strCurrencyName);
                        }
                    }
                }
            }
            case 2:
            {
                if (credits_player > 1)
                {
                    Store_GiveCredits(Store_GetClientAccountID(client), credits_player);
                    
                    if (displaymsg == 1)
                    {
                        PrintToChat(client, "%s%t", STORE_PREFIX, "Flag Captured Player", credits_player, g_strCurrencyName);
                    }
                }
                
                if (credits_team > 1)
                {
                    for (new client = 1; client <= MaxClients; client++) // Foreshadows here.
                    {
                        if (GetClientTeam(client) == team && IsValidClient(client))
                        {
                            accountIds[count] = Store_GetClientAccountID(client);
                            count++;
                        }
                    }
                    Store_GiveCreditsToUsers(accountIds, count, GetConVarInt(Credits_CapturePointTeam));
                    
                    if (displaymsg == 1)
                    {
                        PrintToChat(team, "%s%t", STORE_PREFIX, "Flag Captured Team Bonus", teamname, credits_team, g_strCurrencyName);
                    }
                }
            }
            case 3:
            {
                if (credits_defended > 1)
                {
                    Store_GiveCredits(Store_GetClientAccountID(client), credits_defended);
                    
                    if (displaymsg == 1)
                    {
                        if (displaynames == 1)
                        {
                            PrintToChat(client, "%s%t", STORE_PREFIX, "Flag Defended Named", credits_grabbed, g_strCurrencyName, carriername);
                        }
                        else
                        {
                            PrintToChat(client, "%s%t", STORE_PREFIX, "Flag Defended", credits_grabbed, g_strCurrencyName);
                        }
                    }
                }
            }
        }
    }
    return;
}

eXemplar · *Last edited by eXemplar; 03-15-2013 at 20:53.*

You shouldn't use two variables named "client" in the same scope.
new client = GetEventInt(event, "player");
for (new client = 1; client <= MaxClients; client++) // Foreshadows here.
Make the for loop client variable i or something

404UserNotFound

Quote:

Originally Posted by eXemplar

You shouldn't use two variables named "client" in the same scope.
new client = GetEventInt(event, "player");
for (new client = 1; client <= MaxClients; client++) // Foreshadows here.
Make the for loop client variable i or something

Good idea!