[Silvsilver]

Hello, I request a plugin wich make you stick to a ladder without holding any movement key (CSGO).
Also some ladders you can't just walk up to, you need to jump on them.

Another guy request the same thing, and he got no respone, is it possible?
https://forums.alliedmods.net/showthread.php?t=289599

Tested this command:
https://forums.alliedmods.net/showthread.php?t=271610

[lazarev]

I've been trying to bring back some of movement from 1.6 (sticky ladders, doubleducking, stand-up bhop, etc.) Here is the sticky ladder part from my plugin. There must be another, concrete way to have sticky ladders, but hey, it works!

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

#define PLUGIN_VERSION "1.01"

#pragma semicolon 1
#pragma newdecls required

float frametime;

public Plugin myinfo = 
{
    name = "Sticky ladders", 
    author = "juice", 
    description = "Make players stick to ladders without holding any movement key", 
    version = PLUGIN_VERSION, 
    url = "https://github.com/juicejuicejuice"
};

public void OnPluginStart()
{
    frametime = GetTickInterval();
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_PreThink, OnPlayerPreThink_Pre);
}

public void OnClientDisconnect(int client)
{
    SDKUnhook(client, SDKHook_PreThink, OnPlayerPreThink_Pre);
}

public Action OnPlayerPreThink_Pre(int client)
{
    if (!IsPlayerAlive(client))
    {
        return;
    }
    
    if (GetEntityMoveType(client) == MOVETYPE_WALK)
    {
        float velocity[3];
        GetEntPropVector(client, Prop_Data, "m_vecAbsVelocity", velocity);
        
        if (!velocity[0] && !velocity[1] && !velocity[2])
        {
            return;
        }
        
        float origin[3];
        GetClientAbsOrigin(client, origin);
        
        float mins[3], maxs[3];
        GetEntPropVector(client, Prop_Send, "m_vecMins", mins);
        GetEntPropVector(client, Prop_Send, "m_vecMaxs", maxs);
        
        float wishpos[3];
        wishpos[0] = origin[0] + velocity[0] * frametime;
        wishpos[1] = origin[1] + velocity[1] * frametime;
        wishpos[2] = origin[2] + velocity[2] * frametime;
        
        Handle tr = TR_TraceHullFilterEx(origin, wishpos, mins, maxs, MASK_PLAYERSOLID, TraceFilter_IgnoreSelf, client);
        
        if (TR_DidHit(tr))
        {
            float planeNormal[3];
            TR_GetPlaneNormal(tr, planeNormal);
            SetEntityMoveType(client, MOVETYPE_LADDER);
            SetEntPropVector(client, Prop_Send, "m_vecLadderNormal", planeNormal);
        }
        
        CloseHandle(tr);
    }
}

public bool TraceFilter_IgnoreSelf(int ent, int mask, any data)
{
    return (ent != data);
} 


[Silvsilver]

Work most of the time, but some times you just don't stick to a ladder. Is the a away to be able to stick to it 99% of the time.

BTW thanxs. I think the hide n seek no block community will thanx your for this!

[hmmmmm]

Nice plugin, I would've thought it messes with other situations when you hit a wall without a ladder but it works great. I modified it slightly to use m_vecAbsVelocity instead of m_vecVelocity and also added a check to see if the vel was 0, so as not to waste time doing traceray if they aren't moving. Other than that I couldn't find any situations where it doesn't stick.

[Silvsilver]

Originally Posted by hmmmmm Nice plugin, I would've thought it messes with other situations when you hit a wall without a ladder but it works great. I modified it slightly to use m_vecAbsVelocity instead of m_vecVelocity and also added a check to see if the vel was 0, so as not to waste time doing traceray if they aren't moving. Other than that I couldn't find any situations where it doesn't stick.

Can you send me your code?

[hmmmmm]

Can you tell me in what situations it doesnt stick? Pretty much only change I made is change m_vecVelocity to m_vecAbsVelocity, but I'm not sure if that would fix your issues. If you have a specific map where it doesn't work I', happy to investigate it further, and maybe work on other ladder issues.

[lazarev]

There's simpler solution:

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

#define PLUGIN_VERSION "2.0"

public Plugin myinfo = 
{
    name = "Sticky ladders", 
    author = "juice", 
    description = "Stick to ladders without holding strafe keys", 
    version = PLUGIN_VERSION, 
    url = "https://github.com/juicejuicejuice"
};

ConVar sm_sticky_ladders;

public void OnPluginStart()
{
    sm_sticky_ladders = CreateConVar("sm_sticky_ladders", "1", "Enable sticky ladders");
}

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float move[3], float angles[3], int &weapon, int &subtype, int &cmdnum, int &tickcount, int &seed, int mouse[2])
{
    if (!sm_sticky_ladders.BoolValue || !IsPlayerAlive(client) || GetEntityMoveType(client) != MOVETYPE_WALK)
    {
        return Plugin_Continue;
    }
    
    if (!move[0] && !move[1])
    {
        float wishdir[3];
        GetEntPropVector(client, Prop_Data, "m_vecAbsVelocity", wishdir);
        
        if (wishdir[0] || wishdir[1] || wishdir[2])
        {
            NormalizeVector(wishdir, wishdir);
            NegateVector(wishdir);
            SetEntPropVector(client, Prop_Data, "m_vecLadderNormal", wishdir);
            SetEntityMoveType(client, MOVETYPE_LADDER);
        }
    }
    
    return Plugin_Continue;
} 


[LenHard]

Originally Posted by lazarev There's simpler solution: PHP Code: #include <sourcemod> #include <sdktools> #pragma semicolon 1 #pragma newdecls required #define PLUGIN_VERSION "2.0" public Plugin myinfo =  {     name = "Sticky ladders",      author = "juice",      description = "Stick to ladders without holding strafe keys",      version = PLUGIN_VERSION,      url = "https://github.com/juicejuicejuice" }; ConVar sm_sticky_ladders; public void OnPluginStart() {     sm_sticky_ladders = CreateConVar("sm_sticky_ladders", "1", "Enable sticky ladders"); } public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float move[3], float angles[3], int &weapon, int &subtype, int &cmdnum, int &tickcount, int &seed, int mouse[2]) {     if (!sm_sticky_ladders.BoolValue || !IsPlayerAlive(client) || GetEntityMoveType(client) != MOVETYPE_WALK)     {         return Plugin_Continue;     }          if (!move[0] && !move[1])     {         float wishdir[3];         GetEntPropVector(client, Prop_Data, "m_vecAbsVelocity", wishdir);                  if (wishdir[0] || wishdir[1] || wishdir[2])         {             NormalizeVector(wishdir, wishdir);             NegateVector(wishdir);             SetEntPropVector(client, Prop_Data, "m_vecLadderNormal", wishdir);             SetEntityMoveType(client, MOVETYPE_LADDER);         }     }          return Plugin_Continue; }

This generates unexpected ladder sounds when I'm not on a ladder.

Edit: I made a 0.1 repeating timer and it seems to remove the sound bug.

[waylander3]

Is there any way to make doubleduck like in cs16?