[Remas]

Hello there. I am messing around with bl4nk's source code he came up with. Basically the plugin is supposed to hide Source TV so no one can see it. I am a total newbie when it comes to Sourcepawn and programming itself but I'm slowly starting to understand a tiny bit of it so please don't hate on me . I changed one bit from his original code so it detects Source TV now (his original plugin detects and hides all BOTs including bot players which i dont want)

It does the job, kind of. When you type "status" into your console you can still see that SourceTV is there. Now, after all this reading you are coming up to my question. I am wondering if there is a way and if any of you could help me get rid of it showing up when typing "status" into the console.

I am also wondering what ServerClass is and if there is a list of these classes or something? The reason i am asking is because in one of the commands he used in his code (FindSendPropOffs) the note from docs.sourcemod.net website says "Given a ServerClass name".

Here is the source code for that plugin:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

public Plugin:myinfo = {
    name = "Hide SourceTV",
    author = "bl4nk",
    description = "Hides SourceTV from the scoreboard",
    version = "1.0.0",
    url = "http://forums.alliedmods.net/"
};

public OnMapStart() {
    new iIndex = FindEntityByClassname(MaxClients+1, "cs_player_manager");
    if (iIndex == -1) {
        SetFailState("Unable to find player manager entity");
    }
    
    SDKHook(iIndex, SDKHook_ThinkPost, Hook_OnThinkPost);
}

public Hook_OnThinkPost(iEnt) {
    static iConnectedOffset = -1;
    if (iConnectedOffset == -1) 
		{
			iConnectedOffset = FindSendPropInfo("CCSPlayerResource", "m_bConnected");
		}
    
    new iConnected[35];
    GetEntDataArray(iEnt, iConnectedOffset, iConnected, 35);
    
    for (new i = 1; i < 35; i++) 
	{
        if (iConnected[i] && IsClientSourceTV(i)) 
			{
				iConnected[i] = 0;
			}
    }
    
    SetEntDataArray(iEnt, iConnectedOffset, iConnected, 35);
}

[Remas]

Anyone?

[Powerlord]

You're better off in this case using SetEntProp instead, which doesn't require you to know the ServerClass:

PHP Code:

SetEntProp(iEnt, Prop_Send, "m_bConnected", iConnected[i], i); 


Having said that, server classes are listed in netprops or datamaps dumps. Having said that, there are a lot of them.

Edit: That code's not quite right, as you need the client index for iConnected[i] and i

Incidentally, i < 35 should be i <= MaxClients

[Powerlord]

Ah hell, it's just easier if I redo all the code

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

public Plugin:myinfo = {
    name = "Hide SourceTV",
    author = "bl4nk",
    description = "Hides SourceTV from the scoreboard",
    version = "1.0.0",
    url = "http://forums.alliedmods.net/"
};

public OnMapStart() {
    new iIndex = FindEntityByClassname(MaxClients+1, "cs_player_manager");
    if (iIndex == -1) {
        SetFailState("Unable to find player manager entity");
    }
    
    SDKHook(iIndex, SDKHook_ThinkPost, Hook_OnThinkPost);
}

public Hook_OnThinkPost(iEnt) {
    for (new i = 1; i <= MaxClients; i++) 
    {
        if (IsClientSourceTV(i))
        {
            if (GetEntProp(iEnt, Prop_Send, "m_bConnected", i) != 0) 
            {
                SetEntProp(iEnt, Prop_Send, "m_bConnected", 0, i);
            }
            break;
        }
    }
} 


[Remas]

Will that remove STV from scoreboard and "status" command in the console?

[Powerlord]

Originally Posted by Remas Will that remove STV from scoreboard and "status" command in the console?

I don't know, this code just does what it appeared you were trying to do. Looking at the code, it just makes the SourceTV client's index appear to be unconnected to the server and players.

[Remas]

It works as it should, just checked it. One thing is missing though. I am not sure if it is possible but as i mentioned above is it possible to remove STV from the "status" list in the console?

@edit

[mcpan313]

Originally Posted by Remas It works as it should, just checked it. One thing is missing though. I am not sure if it is possible but as i mentioned above is it possible to remove STV from the "status" list in the console?

Change SourceTV name?

[Remas]

I could try it and i will if i have to but it will look suspicious if someone sees it. Is there a way to remove it completely from that list?

[ddhoward]

As far as I know, you'd have to completely redo the STATUS command. I know that something similar is done in the Admin Stealth plugin.