[klew]

is there anybody who is able/willing to help me with me making a 5 second knife delay ?

[shanapu]

what do you mean with "knife delay"? spawn a knife on round begin with 5 sec delay or deal the damage with 5 sec delay or what?

[klew]

a 5 second delay after knifing someone, so you cant knife them again for 5 seconds. but still able to knife somebody you have not already hurt..

[thedudeguy1]

I'm interested in a plugin like this as well. I searched around but I couldn't find any uncompiled scripts or compiled plugins. If somebody could point me in the right direction with a snippet of code I might be able to do the rest.

[Arkarr]

You might want to try this quicks script :

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <multicolors>

#define PLUGIN_AUTHOR     "Arkarr"
#define PLUGIN_VERSION     "1.00"

bool Marked[MAXPLAYERS + 1];

public Plugin myinfo = 
{
    name = "[ANY] Knife Attack Delay", 
    author = PLUGIN_AUTHOR, 
    description = "Set a delay between each attack on the same player.", 
    version = PLUGIN_VERSION, 
    url = "http://www.sourcemod.net"
};

public void OnPluginStart()
{
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
            SDKHook(i, SDKHook_OnTakeDamage, OnTakeDamage);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)
{
    char sWeapon[32];
    GetEdictClassname(inflictor, sWeapon, sizeof(sWeapon));
    
    if (StrContains(sWeapon, "knife"))
    {
        if(!Marked[victim])
        {
            ImmunePlayer(victim);    
        }            
        else
        {
            CPrintToChat(attacker, "{fullred}This player can't be knifed now !");
            return Plugin_Handled;
        }
    }
    
    return Plugin_Continue;
}

public void ImmunePlayer(int client)
{
    Marked[client] = true;
    SetEntityRenderMode(client, RENDER_TRANSCOLOR);
    SetEntityRenderColor(client, 100, 255, 100, 200);
    
    CreateTimer(5.0, TMR_Unmark, client);
}

public Action TMR_Unmark(Handle tmr, any client)
{
    Marked[client] = false;
    SetEntityRenderMode(client, RENDER_TRANSCOLOR);
    SetEntityRenderColor(client, 255, 255, 255, 255);
} 


Donate if you enjoy my work (I need DOOM so bad)

[thedudeguy1]

Originally Posted by Arkarr You might want to try this quicks script

I tried it and I made a few fixes. First of all, the damage hooking was a bit off such that if a player took damage from the world, they would be invulnerable to all attacks. I used a different hook. After that, the long test inside the if statement at the start of OnTakeDamage is to ignore if the damage came from the world which would be client index zero. Without this handling, there would be errors about how the zero index doesn't represent a player or something along those lines.

PHP Code:

#include <sourcemod> 
#include <sdktools> 
#include <sdkhooks> 

#define PLUGIN_AUTHOR     "Arkarr, thedudeguy1" 
#define PLUGIN_VERSION     "1.3" 

bool Marked[MAXPLAYERS + 1]; 

public Plugin myinfo =  
{ 
    name = "[ANY] Knife Attack Delay",  
    author = PLUGIN_AUTHOR,  
    description = "Set a delay between each attack on the same player.",  
    version = PLUGIN_VERSION,  
    url = "https://forums.alliedmods.net/showpost.php?p=2499248&postcount=6" 
}; 

public void OnPluginStart() 
{ 
    for (new i = 1; i <= MaxClients; i++) 
    { 
        if (IsClientInGame(i)) 
            SDKHook(i, SDKHook_OnTakeDamage, OnTakeDamage); 
    } 
} 

public void OnClientPutInServer(int client) 
{ 
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); 
} 

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype) 
{ 
    if (victim < 1 || victim > MaxClients || attacker < 1 || attacker > MaxClients) 
        return Plugin_Continue; 
        
    char weapon[64]; 
    GetClientWeapon(attacker, weapon, sizeof(weapon)); 
     
    if (StrEqual(weapon, "weapon_knife", false)) 
    { 
        if (!Marked[victim]) 
        { 
            ImmunePlayer(victim);     
        }             
        else 
        { 
            return Plugin_Handled; 
        } 
    } 
     
    return Plugin_Continue; 
} 

public void ImmunePlayer(int client) 
{ 
    Marked[client] = true; 
    SetEntityRenderMode(client, RENDER_TRANSCOLOR); 
    SetEntityRenderColor(client, 100, 255, 100, 200); 
     
    CreateTimer(3.0, TMR_Unmark, client); 
} 

public Action TMR_Unmark(Handle tmr, any client) 
{ 
    Marked[client] = false; 
    SetEntityRenderMode(client, RENDER_TRANSCOLOR); 
    SetEntityRenderColor(client, 255, 255, 255, 255); 
} 


[Arkarr]

Damn that necro-bump hahaha. But you did well. I mean, I quickly wrote the code, without having any return from the original author (wich mad me very sad) I gave up on it.

[thedudeguy1]

Yeah sorry about the necro. I haven't had a real chance to actually try and make sure the plugin worked until recently. Mods pls have mercy . Anyways, thanks for your work. You might want to see if you can make a plugin thread for it.

[sdz]

Originally Posted by Arkarr Damn that necro-bump hahaha. But you did well. I mean, I quickly wrote the code, without having any return from the original author (wich mad me very sad) I gave up on it.

sorry to chime in my two cents but

PHP Code:

if (StrContains(sWeapon, "knife") != -1) 


is what you'd want

although anything below 1 will technically be false; on the contrary to true.

[Arkarr]

That's actually completly true. I should fix that.