[phoenix0001]

Plug-in function
Can automatically adjust the difficulty according to the number of people
4 = Easy 8 = Normal 12 = Hard 16 = Impossible [z_difficulty]

Plug-in does not work after running for some time, very strange.

PHP Code:

#include <sourcemod>

#pragma semicolon 1
#define PLUGIN_VERSION "1.0"
#pragma newdecls required

int g_iClientCount;
ConVar g_cDifficulty;

public Plugin myinfo =
{
    name = "[L4D2] Difficulty Adjuster",
    author = "Tak (Chaosxk)",
    description = "Adjusts difficulty based on number of clients in server.",
    version = PLUGIN_VERSION,
    url = "https://forums.alliedmods.net/showthread.php?t=297009"
}

public void OnPluginStart()
{
    if ((g_cDifficulty = FindConVar("z_difficulty")) == null)
    {
        LogError("[SM] Can not find convar z_difficulty");
        SetFailState("Can not find convar z_difficulty");
    }
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (!IsClientInGame(i) || IsFakeClient(i))
            continue;
        
        UpdateClientCount(++g_iClientCount);
    }
}

public void OnClientPostAdminCheck(int client)
{
    if (IsFakeClient(client))
        return;
        
    UpdateClientCount(++g_iClientCount);
}

public void OnClientDisconnect(int client)
{
    if (IsFakeClient(client))
        return;
        
    UpdateClientCount(--g_iClientCount);
}

public void UpdateClientCount(int count)
{
    switch (count)
    {
        case 4:
            g_cDifficulty.SetString("easy");
        case 8:
            g_cDifficulty.SetString("normal");
        case 12:
            g_cDifficulty.SetString("hard");
        case 16:
            g_cDifficulty.SetString("impossible");
    }
} 


[midnight9]

Maybe because not always OnClientDisconnect is being called when client leaves and that results Client Count having wrong value after a while.
Maybe its worth trying reset the Client Count, OnMapStart or something like that

[Psyk0tik]

Originally Posted by midnight9 Maybe because not always OnClientDisconnect is being called when client leaves and that results Client Count having wrong value after a while. Maybe its worth trying reset the Client Count, OnMapStart or something like that

Yeah, and maybe OnMapStart there should be a check for client count. Looking at the source code, it just seems like the plugin only adds to the current client count when a player connects but, as you said, the value isn't always being reduced since OnClientDisconnect isn't being called all the time. This could happen when a client leaves during map transition or campaign change.

[midnight9]

Originally Posted by Crasher_3637 Yeah, and maybe OnMapStart there should be a check for client count. Looking at the source code, it just seems like the plugin only adds to the current client count when a player connects but, as you said, the value isn't always being reduced since OnClientDisconnect isn't being called all the time. This could happen when a client leaves during map transition or campaign change.

Yea the map change is exactly what i meant, because i've tested it myself and neither OnclientDisconnect or player_disconnect are being called when client leaves during map change.

[phoenix0001]

Originally Posted by midnight9 Maybe because not always OnClientDisconnect is being called when client leaves and that results Client Count having wrong value after a while. Maybe its worth trying reset the Client Count, OnMapStart or something like that

Can you fix him for me? thank you

[phoenix0001]

Originally Posted by Crasher_3637 Yeah, and maybe OnMapStart there should be a check for client count. Looking at the source code, it just seems like the plugin only adds to the current client count when a player connects but, as you said, the value isn't always being reduced since OnClientDisconnect isn't being called all the time. This could happen when a client leaves during map transition or campaign change.

Can you fix him for me? thank you

[Psyk0tik]

Originally Posted by phoenix0001 Can you fix him for me? thank you

The problem I'm seeing is that when a client disconnects, regardless of whether a check is called for any disconnect type, the g_iClientCount doesn't reduce.

For example: When a player leaves during a game, if we were already on Expert difficulty and the 13-16th player leaves, we're still gonna be stuck on Expert difficulty.


Side note:

According to the wiki, "++g_iClientCount" would add 2 per client. Use "g_iClientCount++" instead. Same thing for "--g_iClientCount", change to "g_iClientCount--".

[8guawong]

add

PHP Code:

public void OnMapStart() 
{ 
    g_iClientCount = 0;
} 


[Lux]

PHP Code:

#include <sourcemod>

#pragma semicolon 1
#define PLUGIN_VERSION "1.0"
#pragma newdecls required

ConVar g_cDifficulty;

public Plugin myinfo =
{
    name = "[L4D2] Difficulty Adjuster",
    author = "Tak (Chaosxk)",
    description = "Adjusts difficulty based on number of clients in server.",
    version = PLUGIN_VERSION,
    url = "https://forums.alliedmods.net/showthread.php?t=297009"
}

public void OnPluginStart()
{
    if ((g_cDifficulty = FindConVar("z_difficulty")) == null)
    {
        LogError("[SM] Can not find convar z_difficulty");
        SetFailState("Can not find convar z_difficulty");
    }
    UpdateClientCount(GetSurvivorCount());
}

public void OnClientPostAdminCheck(int client)
{
    if (IsFakeClient(client))
        return;
    
    UpdateClientCount(GetSurvivorCount());
}

public void OnClientDisconnect(int client)
{
    if (IsFakeClient(client))
        return;
    
    UpdateClientCount(GetSurvivorCount());
}

void UpdateClientCount(int count)
{
    switch (count)
    {
        case 4:
        g_cDifficulty.SetString("easy");
        case 8:
        g_cDifficulty.SetString("normal");
        case 12:
        g_cDifficulty.SetString("hard");
        case 16:
        g_cDifficulty.SetString("impossible");
    }
}

int GetSurvivorCount()
{
    int iCount = 0;
    
    for(int iClient = 1; iClient <= MaxClients; iClient++) {
        if(!IsClientInGame(iClient) || IsFakeClient(iClient) || GetClientTeam(iClient) != 2)
            continue;
        
        iCount++;
    }
    return iCount;
} 


Maybe work? :O

[Psyk0tik]

Originally Posted by Lux PHP Code: #include <sourcemod> #pragma semicolon 1 #define PLUGIN_VERSION "1.0" #pragma newdecls required ConVar g_cDifficulty; public Plugin myinfo = {     name = "[L4D2] Difficulty Adjuster",     author = "Tak (Chaosxk)",     description = "Adjusts difficulty based on number of clients in server.",     version = PLUGIN_VERSION,     url = "https://forums.alliedmods.net/showthread.php?t=297009" } public void OnPluginStart() {     if ((g_cDifficulty = FindConVar("z_difficulty")) == null)     {         LogError("[SM] Can not find convar z_difficulty");         SetFailState("Can not find convar z_difficulty");     }     UpdateClientCount(GetSurvivorCount()); } public void OnClientPostAdminCheck(int client) {     if (IsFakeClient(client))         return;          UpdateClientCount(GetSurvivorCount()); } public void OnClientDisconnect(int client) {     if (IsFakeClient(client))         return;          UpdateClientCount(GetSurvivorCount()); } void UpdateClientCount(int count) {     switch (count)     {         case 4:         g_cDifficulty.SetString("easy");         case 8:         g_cDifficulty.SetString("normal");         case 12:         g_cDifficulty.SetString("hard");         case 16:         g_cDifficulty.SetString("impossible");     } } int GetSurvivorCount() {     int iCount = 0;          for(int iClient = 1; iClient <= MaxClients; iClient++) {         if(!IsClientInGame(iClient) || IsFakeClient(iClient) || GetClientTeam(iClient) != 2)             continue;                  iCount++;     }     return iCount; }  Maybe work? :O

That seems to work.

Is it possible to change the required values by cvars?

Ex: To switch to Expert, the default amount of players needed is 16. If there was a cvar to change that, one could lower the requirement to 8, etc.