[Obada]

I have a simple question.

If I have a plugin which uses MySQL to store data, Can I make the plugin use SQLite instead of MySQL without rewriting it?

If Yes, what should I do so I can make it run using SQLite.
If No, How should I make a plugin using MySQL, use SQLite instead of MySQL.


I know it may seem stupid question, but I'm dying on finding an answer, I've searching many times on MySQL and SQLite but couldn't find the answer that I want.

Thank you.

[Arkshine]

Just a matter to select the wanted driver. API is the same.

SQL_SetAffinity("sqlite") or SQL_SetAffinity("mysql")

Now about autoloading module, depending what you want to do.
If you want to load only sqlite module, you need to do:

#pragma defclasslib sqlx sqlite
#include <sqlx>

if you want to load both module mysql and sqlite, so to change driver anytime, then:

#include "sqlx"
#pragma defclasslib sqlite sqlite

[Obada]

What will happen if both modules ran at the same time?

I mean will there be a higher CPU Usage?

And By the way, I should edit the plugin and write SQL_SetAffinity("sqlite") instead of SQL_SetAffinity("mysql")?

And as I know, SQLite doesn't require a external database. Am I right?

[Arkshine]

Nothing happens until you use natives in a plugin, and depending affinity, it will do stuff either in mysql or sqlite module. Both modules share the same API, and SQL_SetAffinity basically just allows you to switch module.

You don't explain really what you want to do, but if you want to change "mysql" to "sqlite", yes, just a matter to change what you say, and adding #pragma (the first) to make sqlite be autoloaded.

Yes, SQLite is local.

[Obada]

Here is the plugin that is using MySQL

Spoiler

PHP Code:

#include <amxmodx>  
#include <amxmisc>  
#include <sqlx>  

#define PLUGIN "Played Time"  
#define VERSION "0.1"  
#define AUTHOR "DIS"  

#define host "127.0.0.1"  
#define user "root"  
#define pass ""  
#define db "played_time"  

new Handle:sql, g_query[512]  

new PlayedTime[33]  

new showpt;  
new g_iMaxPlayers

#define IsPlayer(%0) ( 1 <= %0 <= g_iMaxPlayers )

public plugin_init()   
{  
    register_plugin(PLUGIN, VERSION, AUTHOR );  
    
    register_clcmd("say", "handle_say");  
    register_concmd("amx_playedtime", "admin_showptime", ADMIN_RCON," <#Player Name> - Details about playedtime.");  
    
    showpt = register_cvar("amx_pt_mod","1");  
    
    g_iMaxPlayers = get_maxplayers()
    
}  

public plugin_natives()
{
    register_library("played_time")
    
    register_native("get_user_playedtime", "_get_user_playedtime")
    register_native("set_user_playedtime", "_set_user_playedtime")
}

public _get_user_playedtime(iPlugin, iParams)
{
    if(iParams != 1)
        return -1
    
    new id = get_param(1)
    
    if(!IsPlayer(id))
        return -1
    
    if(!is_user_connected(id))
        return -1
    
    return PlayedTime[id]
}

public _set_user_playedtime(iPlugin, iParams)
{
    if(iParams != 2)
        return 0
    
    new id = get_param(1)
    
    if(!IsPlayer(id))
    {
        log_error(AMX_ERR_NATIVE, "Index out of bounds %d", id)
        return 0
    }
    
    if(!is_user_connected(id))
    {
        log_error(AMX_ERR_NATIVE, "User not connected %d", id)
        return 0
    }
    
    new iTime = get_param(2)
    
    if(iTime < 0)
        iTime = 0
    
    PlayedTime[id] = iTime
    return 1
}


public plugin_cfg(){  
    sql = SQL_MakeDbTuple(host,user,pass,db)  
    formatex(g_query,511,"CREATE TABLE IF NOT EXISTS `played_time` (name VARCHAR(32), playedtime INT, date TIMESTAMP NOT NULL DEFAULT CURRENT_TIMESTAMP ON UPDATE CURRENT_TIMESTAMP)")  
    SQL_ThreadQuery(sql,"query",g_query)  
}  

public handle_say(id)   
{  
    static said[12]  
    read_argv(1, said, 11)  
    
    if(equali(said, "/mytime"))  
    {  
        static ctime[64], timep;  
        
        timep = get_user_time(id, 1) / 60;  
        get_time("%H:%M:%S", ctime, 63);  
        
        switch(get_pcvar_num(showpt))  
        {  
            case 0: return PLUGIN_HANDLED;  
                
            case 1 :  
            {  
                client_print(id, print_chat, "[Played Time] You have been playing on the server for: %d minute%s.", timep, timep == 1 ? "" : "s");   
                client_print(id, print_chat, "[Played Time] Your total played time on the server: %d minute%s.", timep+PlayedTime[id], timep+PlayedTime[id] == 1 ? "" : "s");  
            }  
            case 2 :  
            {  
                set_hudmessage(255, 50, 50, 0.34, 0.50, 0, 6.0, 4.0, 0.1, 0.2, -1);  
                show_hudmessage(id, "[Played Time] You have been playing on the server for: %d minute%s.^n[AMXX]Current time: %s", timep, timep == 1 ? "" : "s", ctime);  
            }  
        }  
        return PLUGIN_HANDLED;  
    }  
    else if(equal(said,"/top15_time")){  
        new data[1];data[0]=id  
        
        formatex(g_query,511,"SELECT * FROM played_time ORDER BY playedtime DESC LIMIT 15")  
        SQL_ThreadQuery(sql,"show_top15",g_query,data,1)  
        
    }  
    return PLUGIN_CONTINUE;  
}  

public admin_showptime(id,level,cid)   
{  
    if(!cmd_access(id, level, cid, 2))  
        return PLUGIN_HANDLED;  
    
    static arg[32];  
    read_argv(1, arg, 31);  
    
    new player = cmd_target(id, arg, 2);  
    
    if(!player)  
        return PLUGIN_HANDLED;  
    
    static name[32];  
    get_user_name(player, name, 31);  
    
    static timep, ctime[64];  
    
    timep = get_user_time(player, 1) / 60;  
    get_time("%H:%M:%S", ctime, 63);  
    
    console_print(id, "-----------------------(#PlayedTime#)-----------------------");  
    console_print(id, "[Played Time] %s have been playing on the server for %d minute%s.",name, timep, timep == 1 ? "" : "s");  
    console_print(id, "[Played Time] %s's total played time on the server %d minute%s.",name, timep+PlayedTime[player], timep == 1 ? "" : "s"); // new  
    console_print(id, "-----------------------------------------------------------------");  
    
    return PLUGIN_HANDLED;  
}  

public client_disconnect(id){  
    new name[32]  
    
    get_user_name(id,name,31)      
    replace_all(name,32,"'","")  
    replace_all(name,32,"^"","")  
    
    PlayedTime[id] = get_playedtime(id)  
    
    formatex(g_query,511,"UPDATE played_time SET playedtime='%d' WHERE name='%s'",PlayedTime[id],name)  
    SQL_ThreadQuery(sql,"query",g_query)  
    
    PlayedTime[id] = 0  
}  

public client_putinserver(id){  
    PlayedTime[id] = get_playedtime(id)  
    log_amx("--> Got %d",PlayedTime[id])  
}  

public plugin_end(){  
    SQL_FreeHandle(sql)  
}  


get_playedtime(id){  
    new err,error[128]  
    
    new Handle:connect = SQL_Connect(sql,err,error,127)  
    
    if(err){  
        log_amx("--> MySQL Connection Failed - [%d][%s]",err,error)  
        set_fail_state("mysql connection failed")  
    }  
    
    new name[32],Handle:query,pt  
    get_user_name(id,name,31)  
    replace_all(name,32,"'","")  
    replace_all(name,32,"^"","")  
    
    query = SQL_PrepareQuery(connect,"SELECT playedtime FROM played_time WHERE name='%s'",name)  
    SQL_Execute(query)  
    
    if(!SQL_MoreResults(query)){  
        formatex(g_query,511,"INSERT INTO played_time (name,playedtime) VALUES('%s','%d')",name,get_user_time(id,1)/60)  
        SQL_ThreadQuery(sql,"query",g_query)  
        
        pt = (get_user_time(id,1)/60)  
        }else{  
        pt = SQL_ReadResult(query,0)+(get_user_time(id,1)/60)  
    }  
    
    log_amx("--> Get %d minutes for %s",pt,name)  
    
    SQL_FreeHandle(connect)  
    SQL_FreeHandle(query)  
    
    return pt  
}  

public show_top15(FailState, Handle:Query, Error[], Errcode,Data[], DataSize){  
    static name[32]  
    
    new id=Data[0]  
    new good,motd[1024],len,place  
    
    if(!SQL_MoreResults(Query)){  
        client_print(id,print_chat,"[PT] No entryes")  
        return PLUGIN_HANDLED  
    }  
    
    len = format(motd, 1023,"<body bgcolor=#000000><font color=#FFB000><pre>")  
    len += format(motd[len], 1023-len,"%s %-22.22s %3s^n", "#", "Name", "Time")  
    
    while(SQL_MoreResults(Query)){  
        place++  
        
        SQL_ReadResult(Query,0,name, 32)  
        good = SQL_ReadResult(Query,1)  
        
        replace_all(name, 32,"<","")  
        replace_all(name, 32,">","")  
        
        len += format(motd[len], 1023-len,"%d %-22.22s %d minute%s^n",place,name,good,good == 1 ? "" : "s")  
        
        SQL_NextRow(Query)  
    }  
    
    len += format(motd[len], 1023-len,"</body></font></pre>")  
    show_motd(id, motd,"Top 15 Players By Time")  
    
    return PLUGIN_CONTINUE  
}  

public query(FailState, Handle:Query, Error[], Errcode){  
    
}  
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/ 


Like if I switched to SQLite, I don't need a mysql database no more?

If so, I have some data on my mysql database, is there any possible way to transfer it to sqlite database?

Thank you!

[Arkshine]

Database will be stored locally, probably in amxmodx/data/sqlite/.

About your datas, no idea, maybe you need a converter, such as : http://www.sqlite.org/cvstrac/wiki?p=ConverterTools