[renancavalieri]

Hello, i trying to play a "MvM Sound" each time the round start on my server, but sometimes i can't heard that.

PHP Code:

#include <sourcemod>
#include <sdktools>

#define SOUND_MVM       "music/mvm_start_wave.wav"

public OnPluginStart()
{
    HookEvent("teamplay_round_start", playSound_MvM);
}

public OnMapStart()
{
    PrecacheSound(SOUND_MVM);
}

public Action:playSound_MvM(Handle:event, const String:name[], bool:dontBroadcast){
    for(new i=1; i<= MaxClients; i++)
    {
        if(IsClientInGame(i) && IsPlayerAlive(i))
        {
            EmitSoundToClient(i,SOUND_MVM);
        }
        
    }
    return Plugin_Handled
} 


Client is on the game (TRUE) and is alive (TRUE) and round has started, but sometimes sound fails (not for all).

When i reload the plugin, it works again, but when clients disconnect or connect, fails sometimes.

What happened?

[Powerlord]

Out of curiosity, does it exhibit these problems if you use EmitSoundToAll instead?

Incidentally, I wrote a plugin that did something like this for April Fools one year, I should dig around an see if I still have it.

Edit: I don't have said plugin any more, at least not on this computer or in any of my regular GitHub repos.

[renancavalieri]

Thanks for the reply Powerlord.

I used "EmitSoundToAll", it works but create a huge spam, the sound was emited from every player on the server lol.

Edit: I used EmitSoundToAll in another plugin to create "say sounds", it works fine, the main problem is emit for each client without causing spam.

[Powerlord]

As long as the entity argument is SOUND_FROM_PLAYER and has no position, it should just emit from the player themselves. Not sure why it would do something differently.

Anyway, if it's working with EmitSoundToAll and not EmitSoundToClient, it sounds like it doesn't like something that's being done.

Does this still happen if you do something like this?

PHP Code:

public Action:playSound_MvM(Handle:event, const String:name[], bool:dontBroadcast){
    new clients[MaxClients];
    new count = 0;
    for(new i=1; i<= MaxClients; i++)
    {
        if(IsClientInGame(i) && IsPlayerAlive(i))
        {
            clients[count] = i;
            count++;
        }
        
    }
    EmitSound(clients, count, SOUND_MVM);
    return Plugin_Handled;
} 


Granted, the only different between this and EmitSoundToAll is that it won't emit to dead players.

[renancavalieri]

This is new for me, i never understood the "EmitSound" functions, hehe. I'll try.

Thanks Again Powerlord.

[Powerlord]

Originally Posted by renancavalieri This is new for me, i never understood the "EmitSound" functions, hehe. I'll try. Thanks Again Powerlord.

EmitSoundToAll and EmitSoundToClient are both stocks that act as wrappers for EmitSound.

EmitAmbientSound is its own thing for emitting a sound in the environment itself, usually from a fixed position.

OK, so those are the basic sound commands.

However, there are two more advanced sound commands present: PrecacheScriptSound and GetGameSoundParams.

These functions deal with the game's game_sounds files.

As a quick example for TF2:

PHP Code:

new channel;
new soundLevel;
new Float:volume;
new pitch;
new String:sample[PLATFORM_MAX_PATH];

GetGameSoundParams("Game.Overtime", channel, soundLevel, volume, pitch, sample, sizeof(sample)); 


would leave you with:

• channel = 7 (the VOICE2 / Announcer channel in TF2)
• soundLevel = 140
• volume = 1.0
• pitch = PITCH_NORM (I forgot what value this is)
• and sample = one of these values (at random):
  • "vo/announcer_overtime.wav"
  • "vo/announcer_overtime2.wav"
  • "vo/announcer_overtime3.wav"
  • "vo/announcer_overtime4.wav"

Of course, it's a lot of work to do that, so I could just do EmitGameSoundToAll("Game.Overtime"); instead. That's because EmitGameSound* is a wrapper around GetGameSoundParams and EmitSound.

PrecacheScriptSound is to make sure all the sounds for GetGameSoundParams are precached. It shouldn't be necessary as the game usually does this up front. It may have more of a use in the future.

[renancavalieri]

Powerlord, you solved my problem, thanks!