[sim242]

Hey guys, I just wanted to know exactly how to use this function. It has MenuEnd_ExitBack and I thought I knew how to use it but apparently not.

I've set up a menu that when you select an item it opens a new menu. On the new menu I want a back button that would take the user back to the previous menu but I'm not sure how to do this.

Any help is appreciated, thanks.

[ici]

PHP Code:

FirstMenu(client)
{
    new Handle:menu = CreateMenu(FirstMenu_Handler);
    SetMenuTitle(menu, "My First Menu");
    AddMenuItem(menu, "1", "Go to the second menu");
    SetMenuOptionFlags(menu, MENUFLAG_BUTTON_EXIT|MENUFLAG_NO_SOUND);
    DisplayMenu(menu, client, MENU_TIME_FOREVER);
}

public FirstMenu_Handler(Handle:menu, MenuAction:action, param1, param2)
{
    switch (action)
    {
        case MenuAction_Select:
        {
            decl String:info[4];
            GetMenuItem(menu, param2, info, sizeof(info));
            new key = StringToInt(info);
            if (key == 1) {
                SecondMenu(param1);
            }
        }
        case MenuAction_End: CloseHandle(menu);
    }
}

SecondMenu(client)
{
    new Handle:menu = CreateMenu(SecondMenu_Handler);
    SetMenuTitle(menu, "My Second Menu");
    AddMenuItem(menu, "1", "Test 1");
    AddMenuItem(menu, "2", "Test 2");
    SetMenuOptionFlags(menu, MENUFLAG_BUTTON_EXIT|MENUFLAG_BUTTON_EXITBACK|MENUFLAG_NO_SOUND);
    DisplayMenu(menu, client, MENU_TIME_FOREVER);
}

public SecondMenu_Handler(Handle:menu, MenuAction:action, param1, param2)
{
    switch (action)
    {
        case MenuAction_Select:
        {
            decl String:info[4];
            GetMenuItem(menu, param2, info, sizeof(info));
            new key = StringToInt(info);
            switch (key)
            {
                case 1: PrintToChat(param1, "You selected Test 1");
                case 2: PrintToChat(param1, "You selected Test 2");
            }
        }
        case MenuAction_Cancel:
        {
            if (param2 == MenuCancel_ExitBack) {
                FirstMenu(param1);
            }
        }
        case MenuAction_End: CloseHandle(menu);
    }
} 


[sim242]

Thanks ici, I got it working now, much appreciated