[ThatKidWhoGames]

The issue has been resolved. Thanks anyways!

If you want to know how to accomplish this, I won't go into detail since it is evident from the code. Here is the modified code:

PHP Code:

#pragma semicolon 1
#define PLUGIN_VERSION "1.1"
#define CONFIG "addons/sourcemod/configs/messagefilter.cfg"

#include <sourcemod>
#include <scp>

StringMap hHashMap;

public Plugin myinfo = {
    name        = "Message Filter",
    author      = "Sgt. Gremulock",
    description = "Allows server operators to modify messages that are said in chat to include different text (configured via a config file).",
    version     = PLUGIN_VERSION,
    url         = "grem-co.com"
};

public void OnPluginStart()
{
    CreateConVar("sm_messagefilter_version", PLUGIN_VERSION, "Plugin's version.", FCVAR_NOTIFY);
}

public void OnMapStart()
{
    BrowseKeyValues();
}

public Action OnChatMessage(int &author, ArrayList recipients, char[] name, char[] message)
{
    char buffer[2][256];
    strcopy(buffer[0], 256, message);
    RemoveCapitalLetters(buffer[0], 256);
    if (hHashMap.GetString(buffer[0], buffer[1], 256))
    {
        ReplaceString(message, 256, message, buffer[1]);
        return Plugin_Changed;
    }

    return Plugin_Continue;
}

void RemoveCapitalLetters(char[] buffer, int max)
{
    ReplaceString(buffer, max, "A", "a");
    ReplaceString(buffer, max, "B", "b");
    ReplaceString(buffer, max, "C", "c");
    ReplaceString(buffer, max, "D", "d");
    ReplaceString(buffer, max, "E", "e");
    ReplaceString(buffer, max, "F", "f");
    ReplaceString(buffer, max, "G", "g");
    ReplaceString(buffer, max, "H", "h");
    ReplaceString(buffer, max, "I", "i");
    ReplaceString(buffer, max, "J", "j");
    ReplaceString(buffer, max, "K", "k");
    ReplaceString(buffer, max, "L", "l");
    ReplaceString(buffer, max, "M", "m");
    ReplaceString(buffer, max, "N", "n");
    ReplaceString(buffer, max, "O", "o");
    ReplaceString(buffer, max, "P", "p");
    ReplaceString(buffer, max, "Q", "q");
    ReplaceString(buffer, max, "R", "r");
    ReplaceString(buffer, max, "S", "s");
    ReplaceString(buffer, max, "T", "t");
    ReplaceString(buffer, max, "U", "u");
    ReplaceString(buffer, max, "V", "v");
    ReplaceString(buffer, max, "W", "w");
    ReplaceString(buffer, max, "X", "x");
    ReplaceString(buffer, max, "Y", "y");
    ReplaceString(buffer, max, "Z", "z");
}

void BrowseKeyValues()
{
    KeyValues kv = new KeyValues("Message Filter");
    if (!FileExists(CONFIG))
    {
        kv.JumpToKey("Example", true);
        kv.SetString("replacement", "guy");
        kv.Rewind();
        kv.ExportToFile(CONFIG);
        LogMessage("Generated config file: %s\nEdit the file to your liking and then reload the plugin!", CONFIG);
        kv.Close();
        return;
    }

    if (!kv.ImportFromFile(CONFIG))
        SetFailState("Cannot load the config file (%s)!", CONFIG);
    if (!kv.GotoFirstSubKey())
        SetFailState("Failure navigating to the first key in the config file (%s)!", CONFIG);

    if (hHashMap != null && hHashMap.Size > 0)
    {
        hHashMap.Clear();
        hHashMap = null;
    }

    hHashMap = new StringMap();
    char buffer[2][256];
    do {
        kv.GetSectionName(buffer[0], 256);
        kv.GetString("replacement", buffer[1], 256);
        LogMessage("Successfully added replacement for message: '%s' (Replacement: '%s').", buffer[0], buffer[1]);
        RemoveCapitalLetters(buffer[0], 256);
        hHashMap.SetString(buffer[0], buffer[1]);
    } while kv.GotoNextKey();
    kv.Close();
} 


Cheers,
Grant

Spoiler

Hey all!

Basically, I am coding this plugin. Here is the code. You can probably guess what it does by looking at the code:

PHP Code:

#pragma semicolon 1
#define PLUGIN_VERSION "1.0"
#define CONFIG "addons/sourcemod/configs/messagefilter.cfg"

#include <sourcemod>
#include <scp>

StringMap hHashMap;

public Plugin myinfo = {
    name        = "Message Filter",
    author      = "Sgt. Gremulock",
    description = "Allows server operators to modify messages that are said in chat to include different text (configured via a config file).",
    version     = PLUGIN_VERSION,
    url         = "sourcemod.net"
};

public void OnPluginStart()
{
    CreateConVar("sm_messagefilter_version", PLUGIN_VERSION, "Plugin's version.", FCVAR_NOTIFY);
}

public void OnMapStart()
{
    BrowseKeyValues();
}

public Action OnChatMessage(int &author, ArrayList recipients, char[] name, char[] message)
{
    char buffer[256];
    if (hHashMap.GetString(message, buffer, sizeof(buffer)))
    {
        ReplaceString(message, MAXLENGTH_MESSAGE, message, buffer);
        return Plugin_Changed;
    }

    return Plugin_Continue;
}

void BrowseKeyValues()
{
    KeyValues kv = new KeyValues("Message Filter");
    if (!FileExists(CONFIG))
    {
        kv.JumpToKey("Example", true);
        kv.SetString("replacement", "guy");
        kv.Rewind();
        kv.ExportToFile(CONFIG);
        LogMessage("Generated config file: %s\nEdit the file to your liking and then reload the plugin!", CONFIG);
        kv.Close();
        return;
    }

    if (!kv.ImportFromFile(CONFIG))
        SetFailState("Cannot load the config file (%s)!", CONFIG);
    if (!kv.GotoFirstSubKey())
        SetFailState("Failure navigating to the first key in the config file (%s)!", CONFIG);

    if (hHashMap != null && hHashMap.Size > 0) // Idk if this part is necessary but I did it anyway.
    {
        hHashMap.Clear();
        hHashMap = null;
    }

    hHashMap = new StringMap();
    char buffer[2][256];
    do {
        kv.GetSectionName(buffer[0], 256);
        kv.GetString("replacement", buffer[1], 256);
        hHashMap.SetString(buffer[0], buffer[1]);
        LogMessage("Successfully added replacement for message: '%s' (Replacement: '%s').", buffer[0], buffer[1]);
    } while kv.GotoNextKey();
    kv.Close();
} 


If you still don't understand what this plugin is supposed to do, it basically replaces words or phrases in certain chat messages. However, this is where the trouble comes in...

StringMap.GetString is case sensitive. Does anybody have a work around for making it case insensitive?

Is one way to do it to just simply add every possible (capital letter and non-capital letter) combination for a phrase into the StringMap and have it set as multiple keys for the replacement message? I feel like that would definitely be a poor decision performance wise.

Or, would I have to (not preferred) format the message buffer (in the config) to be all lowercase?

Thanks,
Grant

[headline]

don't do repeated calls to ReplaceString to just handle lowercase-ing your string.

PHP Code:

char[] str = "test";
for (int i = 0; i < strlen(str); i++)
{
    str[i] = CharToLower(str[i]);
} 


[psychonic]

Originally Posted by Headline don't do repeated calls to ReplaceString to just handle lowercase-ing your string. PHP Code: char[] str = "test"; for (int i = 0; i < strlen(str); i++) {     str[i] = CharToLower(str[i]); }

don't do repeated calls to strlen to just handle getting the length of your string.

PHP Code:

char[] str = "test";
int len = strlen(str);
for (int i = 0; i < len; i++)
{
    str[i] = CharToLower(str[i]);
} 


[headline]

Originally Posted by psychonic don't do repeated calls to strlen to just handle getting the length of your string. PHP Code: char[] str = "test"; int len = strlen(str); for (int i = 0; i < len; i++) {     str[i] = CharToLower(str[i]); }

don't do repeated calls to CharToLower and assume that every char is a multi-byte character

PHP Code:

char[] str = "test"; 
int len = strlen(str);
int bytes = 0;
for (int i = 0; i < len; i++) 
{
    bytes = IsCharMB(str[i]);
    if (bytes == 0)
    {
        str[i] = CharToLower(str[i]);
    }
    else
    {
        i += (bytes -1);
    }
} 


😎

[psychonic]

Originally Posted by Headline don't do repeated calls to CharToLower and assume that every char is a multi-byte character

Just copy/pasting from you/above.

Also, *isn't. "isn't a multi-byte character". FTFY brotato chip.