[Synchroneyes]

Hi,
So i'm trying to keep a panel opened as long as another one is opened, and open this one back when the old one is closed.

For example;
I have InfoPanel that needs to be opened all time, can't be closes
If i want to open xPanel then xPanel shows up, InfoPanel get closed, and when xPanel get closed then InfoPanel get opened back

At the moment, i'm doing this

PHP Code:

public void OnPluginStart()
{
    HookEvent("player_spawn", TimerAfficherHubSpawn);
}

public Action:TimerAfficherHubSpawn(Handle:hEvent, const String:szName[], bool:bDontBroadcast)
{
    new iClient = GetClientOfUserId(GetEventInt(hEvent, "userid"));
    CreateTimer(0.5, afficherHUBRespawn, iClient, TIMER_REPEAT);
} 
public Action:afficherHUBRespawn(Handle timer, client)
{
    new Handle:WPanel = CreatePanel(INVALID_HANDLE);
    SetPanelTitle(WPanel, "title");
    DrawPanelText(WPanel, "text: ?");
    DrawPanelText(WPanel, "text: ?");
    DrawPanelText(WPanel, "text: ?");
    DrawPanelText(WPanel, "text: ?");
    DrawPanelText(WPanel, "text: ?");
    DrawPanelText(WPanel, "text: ?");
    SendPanelToClient(WPanel, client, NullMenuHandler, 20);
    //CloseHandle(WPanel);
}
public NullMenuHandler(Handle:WPanel, MenuAction:action, param1, param2) 
{
    CloseHandle(WPanel);
} 


but, thing is if i do a command like /admin, the admin menu doesn't show up. It does but get insta closed...
Any idea on how i need to do this ?

[adma]

At the top of the timer callback, check if client is in a menu using GetClientMenu(client) == MenuSource_None. The idea is you only draw the panel if the client is not in a menu. When the client closes the menu, the timer will see they are not in a menu and display your panel. When dealing with clients and timers, ALWAYS pass a serial / userid instead of the client index, because the client may not be valid by the timer fires. You should also be consistent with your syntax i.e. either use old syntax or new syntax, not both.

PHP Code:

public void OnPluginStart() 
{ 
  HookEvent("player_spawn", TimerAfficherHubSpawn); 
} 

public Action TimerAfficherHubSpawn(Event hEvent, const char[] szName, bool bDontBroadcast) 
{
  // Use userid because client will be invalid if they disconnect before the timer callback is invoked
  int iUserId = hEvent.GetInt("userid"); 
  CreateTimer(0.5, afficherHUBRespawn, iUserId, TIMER_REPEAT); 
}  

public Action afficherHUBRespawn(Handle hTimer, int iUserId) 
{
  int iClient = GetClientOfUserId(iUserId);

  // This guarantees the timer will stop when they disconnect, including map change disconnects
  if (iClient == 0 || !IsClientInGame(iClient)) return Plugin_Stop;

  // If the client is in a menu already, do not continue but keep the timer going
  if (GetClientMenu(iClient) != MenuSource_None) return Plugin_Continue;

  Panel WPanel = new Panel(null);

  WPanel.SetTitle("title");

  WPanel.DrawText("text: ?");
  WPanel.DrawText("text: ?");
  WPanel.DrawText("text: ?");
  WPanel.DrawText("text: ?");
  WPanel.DrawText("text: ?");
  WPanel.DrawText("text: ?");

  WPanel.Send(iClient, NullMenuHandler, 20);

  delete WPanel; // Free the memory here because the handle is useless in the callback anyway
}

public int NullMenuHandler(Menu hMenu, MenuAction action, int iParam1, int iParam2)  
{
  /* You can check MenuAction_Select and MenuAction_Cancel in here */
  return 0;
} 


[Synchroneyes]

Thank you, it's working fine !

[adma]

No worries, its also worth noting you probably want to track the timer handle and stop it each round because this will create multiple timers if a player spawns in more than once more map.