[ronmelkhior]

I'm trying to do a cooldown rate, but I also want to display in the cooldown message how much time they have left until they have.

[ecca]

I usually do like this , not sure if another way exists , and ofc if you have clients you need to put it in the int and so on. Also you have to reset it to 20 when it expires and so on.

PHP Code:

new TimeLeftOnTimer = 20; //If you start it on 20

timer function()
{
       TimeLeftOnTimer--;
       PrintToChat(client, "Time left on timer is , %i", TimeLeftOnTimer);
} 


[11530]

For a cooldown convar, you'll probably want something like this. I've included almost everything you'd need to implement it.

PHP Code:

new Handle:g_hCooldown = INVALID_HANDLE;
new g_iLastUsed[MAXPLAYERS+1];

public OnPluginStart()
{
    g_hCooldown = CreateConVar("sm_test_cooldown", "10", "Cooldown in seconds.", 0, true, 0.0);
    
    RegConsoleCmd("sm_test", Command_Test, "Test...");
}

public Action:Command_Test(client, args)
{
    new iNow = GetTime(), iCooldown = GetConVarInt(g_hCooldown);
    if (iCooldown > 0)
    {
        new iTimeLeft = g_iLastUsed[client] + iCooldown - iNow;
        if (iTimeLeft > 0)
        {
            ReplyToCommand(client, "[SM] You must wait another %d second%s.", iTimeLeft, (iTimeLeft != 1 ? "s" : ""));
            return Plugin_Handled;
        }
    }
    g_iLastUsed[client] = iNow;
    
    //Other stuff.
    return Plugin_Handled;
}

public OnClientDisconnect_Post(client)
{
    g_iLastUsed[client] = 0;
} 


[Dr. Greg House]

I think GetGameTime() counts from 0 at OnMapStart, so there you'd have to go and reset everything to 0. Or just go ahead and do that OnClientConnected and/or OnClientDisconnected because those are fired on map change as well.

EDIT:
Oh 11530 already does this. (I didn't scroll down :p)