[waggel]

Hi, i'm currently getting started into writing plugins, and messing around with sourcemod (pawn) programming.

And i was wondering if it's possible to plant the bomb automatically by the server.

So for example, at the beginning of the round, the server would select a random clientid of the terrorist and plant/put down the bomb for him on fixed location on one of the 2 bomb sites.


Kind regards,
Waggel

[Potato Uno]

Create the bomb using CreateEntityByName, set the appropriate netprops, keyvalues, dispatch it, and teleport it?

And to find a bomb site on the map, use FindEntityByClassname?

(I have no idea really since I don't play csgo.)

[waggel]

Hi, thanks for reply.

So i've been on this for days now and no result.

I followed your tip and this is how far i got yet.
1 First I remove the bomb that has been given to one of the terrorists
2 I create an entity "planted_c4" (that's the one that gets created when a bomb is planted)
3 I teleport it to the bomb location, this works, i see it laying on the bombsite.

So next step is to fire of the event "bomb_planted", which triggers the beeping and bomb has been planted message, roundtimer stops, but it keeps beeping forever, even past the mp_c4timer seconds and never explodes. Also the bomb doesn't bling, just looks static.

Anyone who can help me a bit further?!

muchos gracias

[Chdata]

sm_dump_netprops file.txt
sm_dump_datamaps file.txt

Look at its netprops and see if there's one you should probably be setting.

[waggel]

Thanks, netprops generated a giant list, looking into it now

[waggel]

You saved my life! I literally was hunting this question for like 10 hours already now and i feel like an idiot.

Here is a reference to help other people:

What you do first is:
Create the entity "planted_c4"
DispatchSpawn the entity
Teleport the entity to the location of a bombsite.

Then you have to change the prop called m_bBombTicking to the value 1; but the SetEntProp doesn't work so you have to use SetEntData with offset 1216, bytelength 1 (8bits) and value to 1, this will starts the countdown of the bomb, blinking, and explossion after the c4timer. Also triggers the round end after.

[r3v]

I want to make working with CS:Source Retakes server, but planted bomb (without model) only blinking and playing beep sound. I upload offsets, so maybe someone can fix this?

PHP Code:

#pragma semicolon 1

#include <retakes>

#pragma newdecls required

#include <sdktools>
#include <cstrike>

ConVar
    g_cvPluginEnabled,
    g_cvFreezeTime;
bool
    g_bBombDeleted;
int
    m_bBombTicking;
Bombsite
    g_bsBombsite;
float
    g_vecPosition[3];

public Plugin myinfo =
{
    name        = "[CS:S] Retakes AutoPlant",
    author        = "domino_",
    description    = "A plugin which automatically plants the bomb in Retakes",
    version        = "0.0.5 (rewritten by Grey83)",
    url            = ""
}

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max)
{
    if((m_bBombTicking = FindSendPropInfo("CPlantedC4", "m_bBombTicking")) == -1)
    {
        FormatEx(error, err_max, "Unable to find offset CPlantedC4::m_bBombTicking.");
        return APLRes_Failure;
    }
    return APLRes_Success;
}

public void OnPluginStart() 
{
    g_cvPluginEnabled = CreateConVar("b3none_ap_enabled", "1", "Enable AutoPlant?(1 Enabled | 0 Disabled)");
    g_cvFreezeTime = FindConVar("mp_freezetime");

    HookEvent("round_start", OnRoundStart, EventHookMode_PostNoCopy);
}

public void OnRoundStart(Handle event, const char[] name, bool dontBroadcast) 
{
    if(GetConVarBool(g_cvPluginEnabled))
    {
        g_bBombDeleted = false;
        for(int i = 1; i <= MaxClients; i++) if(IsClientInGame(i) && IsPlayerAlive(i) && GetPlayerWeaponSlot(i, 4) > 0)
        {
            g_bBombDeleted = SafeRemoveBomb(i);

            GetClientAbsOrigin(i, g_vecPosition);

            int iUserid = GetClientUserId(i);
            SendPlantEvent(iUserid);
            CreateTimer(GetConVarFloat(g_cvFreezeTime)+0.1, PlantBomb, iUserid, TIMER_FLAG_NO_MAPCHANGE);
            break;
        }
    }
}

public Action PlantBomb(Handle timer, int iUserid)
{
    if(g_bBombDeleted)
    {
        int ent = CreateEntityByName("planted_c4");
        if(ent != -1)
        {
            SetEntData(ent, m_bBombTicking, 1, 1, true);
            TeleportEntity(ent, g_vecPosition, NULL_VECTOR, NULL_VECTOR);
    
            if(DispatchSpawn(ent))
            {
                ActivateEntity(ent);
                SendPlantEvent(iUserid, true);
            }
        }
    }
}

stock void SendPlantEvent(int iUserid, const bool planted = false)
{
    Event event = CreateEvent(planted ? "bomb_planted" : "bomb_beginplant");
    if(event)
    {
        event.SetInt("userid", iUserid);
        event.SetInt("site", (g_bsBombsite == BombsiteA) ? 0 : 1);
        event.Fire();
    }
}

public void Retakes_OnSitePicked(Bombsite& site)
{
    g_bsBombsite = site;
}

stock bool SafeRemoveBomb(int iClient)
{
    int iWeapon = GetPlayerWeaponSlot(iClient, 4);
    if(iWeapon == -1 || !HasEntProp(iWeapon, Prop_Send, "m_hOwnerEntity"))
        return false;

    int iOwnerEntity = GetEntPropEnt(iWeapon, Prop_Send, "m_hOwnerEntity");
    if(iOwnerEntity != iClient) SetEntPropEnt(iWeapon, Prop_Send, "m_hOwnerEntity", iClient);

    CS_DropWeapon(iClient, iWeapon, false);

    if(HasEntProp(iWeapon, Prop_Send, "m_hWeaponWorldModel"))
    {
        int iWorldModel = GetEntPropEnt(iWeapon, Prop_Send, "m_hWeaponWorldModel");
        if(iWorldModel != -1 && !AcceptEntityInput(iWorldModel, "Kill"))
            return false;
    }

    return AcceptEntityInput(iWeapon, "Kill");
}