[TRUE RED]

Hi. I need plugin that will check vip online. Can someone make /vips command to check vip online. it would be good if someone will add colorchat function in this plugin. I used search and found this:

PHP Code:

#include <amxmodx>

#define VIP_ACCESS            ADMIN_KICK
#define ADMIN_ACCESS            ADMIN_RCON

new g_max_clients, gmsgSayText

public plugin_init() {
    register_plugin("Admins&Vips Online", "0.1", "Pop0N")
    
    g_max_clients = get_maxplayers()
    gmsgSayText = get_user_msgid("SayText")
    register_clcmd("say /admin", "ShowVIPs")
    register_clcmd("say_team /admin", "ShowVIPs")
    register_clcmd("say /admins", "ShowVIPs")
    register_clcmd("say_team /admins", "ShowVIPs")
    register_clcmd("say /vip", "ShowVIPs")
    register_clcmd("say_team /vip", "ShowVIPs")
}

public ShowVIPs(user)
{
    ShowAdmins(user)
    new message[256]
    new adminnames[33][32]
    new id, count, x, len
    
    for(id = 1 ; id <= g_max_clients ; id++)
        if(is_user_connected(id))
            if(get_user_flags(id) & VIP_ACCESS)
                get_user_name(id, adminnames[count++], 31)
    len = format(message, 255, "^4Vips Online:^3 ")
    if(count > 0) {
        for(x = 0 ; x < count ; x++) {
            len += format(message[len], 255-len, "%s%s ", adminnames[x], x < (count-1) ? ", ":"")
            if(len > 96) {
                print_message(user, message)
                len = format(message, 255, "^4 ")
            }
        }
        print_message(user, message)
    }
    else {
        len += format(message[len], 255-len, "^3No VIPs Online.")
        print_message(user, message)
    }
}

public ShowAdmins(user)
{
    new message[256]
    new adminnames[33][32]
    new id, count, x, len
    
    for(id = 1 ; id <= g_max_clients ; id++)
        if(is_user_connected(id))
            if(get_user_flags(id) & ADMIN_ACCESS)
                get_user_name(id, adminnames[count++], 31)
    len = format(message, 255, "^4Admins Online:^3 ")
    if(count > 0) {
        for(x = 0 ; x < count ; x++) {
            len += format(message[len], 255-len, "%s%s ", adminnames[x], x < (count-1) ? ", ":"")
            if(len > 96) {
                print_message(user, message)
                len = format(message, 255, "^4 ")
            }
        }
        print_message(user, message)
    }
    else {
        len += format(message[len], 255-len, "^3No Admins Online.")
        print_message(user, message)
    }
}

print_message(id, msg[]) {
    message_begin(MSG_ONE, gmsgSayText, {0,0,0}, id)
    write_byte(id)
    write_string(msg)
    message_end()
} 


Would be great if someone add VIP in scoreboard. I found one but doesn't work

[hleV]

PHP Code:

public ShowVIPs(user)
{
    new text[192] = "^4Vips Online:^3 ";
    new len = strlen(text);
    
    for (new i = 1; i <= g_max_players; i++)
    {
        if (!is_user_connected(i) || ~get_user_flags(i) & VIP_ACCESS)
            continue;
            
        len += get_user_name(i, text[len], charsmax(text) - len);
        len += add(text[len], charsmax(text) - len, ", ");
    }
    
    text[len - 2] = EOS;
    
    print_message(user, text);
} 


[Exolent[jNr]]

Originally Posted by TRUE RED i need it without contact message

If you leave the cvar blank, then no contact message will be shown.

Originally Posted by TRUE RED and if someone can make VIP in scoreboard would be good.

Already been made, search.

[Exolent[jNr]]

Yes, I wrote that one.

[Exolent[jNr]]

It adds "VIP" in the scoreboard for users who have the given admin flag.

[TRUE RED]

PHP Code:

#include <amxmodx>

#define PLUGIN    "Admin - VIP Status"
#define VERSION    "1.0"
#define AUTHOR    "xPaw"

public plugin_init() {
    register_plugin( PLUGIN, VERSION, AUTHOR );
    
    register_message( get_user_msgid( "ScoreAttrib" ),    "msgScoreAttrib" );
}

public msgScoreAttrib( const MsgId, const MsgType, const MsgDest ) {
    static id;
    id = get_msg_arg_int( 1 );
    
    if( ( get_user_flags( id ) & ADMIN_KICK ) && ( get_user_team( id ) == 2 ) && !get_msg_arg_int( 2 ))
        set_msg_arg_int( 2, ARG_BYTE, ( 1 << 2 ) ); 


and

PHP Code:

#include < amxmodx >
#include < amxmisc >

#define ADMIN_VIP ADMIN_IMMUNITY

enum {
    SCOREATTRIB_ARG_PLAYERID = 1,
    SCOREATTRIB_ARG_FLAGS
};

enum ( <<= 1 ) {
    SCOREATTRIB_FLAG_NONE = 0,
    SCOREATTRIB_FLAG_DEAD = 1,
    SCOREATTRIB_FLAG_BOMB,
    SCOREATTRIB_FLAG_VIP
};

new pCvar_AdminVIP;

public plugin_init( ) {
    register_plugin( "Admin VIP ScoreBoard", "0.0.1", "Exolent" );
    
    register_message( get_user_msgid( "ScoreAttrib" ), "MessageScoreAttrib" );
    
    pCvar_AdminVIP = register_cvar( "amx_adminvip", "1" );
}

public MessageScoreAttrib( iMsgId, iDest, iReceiver ) {
    if( get_pcvar_num( pCvar_AdminVIP ) ) {
        new iPlayer = get_msg_arg_int( SCOREATTRIB_ARG_PLAYERID );
        
        if( access( iPlayer, ADMIN_VIP ) ) {
            set_msg_arg_int( SCOREATTRIB_ARG_FLAGS, ARG_BYTE, SCOREATTRIB_FLAG_VIP );
        }
    }
} 


and also

PHP Code:

#include <amxmodx> 
#include <amxmisc> 

new g_szVIPMap 

public plugin_init() 
{ 
    register_plugin("Admins are VIP's", "1.0", "PHP++") 
    register_event("ResetHUD", "ResetHUD", "be") 
     
    new szMapName[32] 
    get_mapname(szMapName, 31) 
     
    if (containi(szMapName, "as_") > -1) 
        g_szVIPMap = 1 
} 

public ResetHUD(id) 
{ 
    set_task(0.5, "VIP", id + 6910) 
} 

public VIP(TaskID) 
{ 
    if (g_szVIPMap) 
        return PLUGIN_HANDLED 
         
    new id = TaskID - 6910 
     
    if (is_user_admin(id)) 
    { 
        message_begin(MSG_ALL, get_user_msgid("ScoreAttrib")) 
        write_byte(id) 
        write_byte(4) 
        message_end() 
    } 
     
    return PLUGIN_HANDLED 
} 


explain me in two words, please? different code but the same purpose?

[Exolent[jNr]]

First and second are the same, except the second has a toggling cvar as well as more readable code.

The third one is just awful.

[TRUE RED]

PHP Code:

#include < amxmodx >
#include < amxmisc >

#define ADMIN_VIP ADMIN_LEVEL_A

enum {
    SCOREATTRIB_ARG_PLAYERID = 1,
    SCOREATTRIB_ARG_FLAGS
};

enum ( <<= 1 ) {
    SCOREATTRIB_FLAG_NONE = 0,
    SCOREATTRIB_FLAG_DEAD = 1,
    SCOREATTRIB_FLAG_BOMB,
    SCOREATTRIB_FLAG_VIP
};

new pCvar_AdminVIP;

public plugin_init( ) {
    register_plugin( "Admin VIP ScoreBoard", "0.0.1", "Exolent" );
    
    register_message( get_user_msgid( "ScoreAttrib" ), "MessageScoreAttrib" );
    
    pCvar_AdminVIP = register_cvar( "amx_adminvip", "1" );
}

public MessageScoreAttrib( iMsgId, iDest, iReceiver ) {
    if( get_pcvar_num( pCvar_AdminVIP ) ) {
        new iPlayer = get_msg_arg_int( SCOREATTRIB_ARG_PLAYERID );
        
        if( access( iPlayer, ADMIN_VIP ) ) {
            set_msg_arg_int( SCOREATTRIB_ARG_FLAGS, ARG_BYTE, SCOREATTRIB_FLAG_VIP );
        }
    }
} 


Tested it and it works 100%. Thank you for your plugin and also for quick reply!

[TRUE RED]

tell me how to find /vips -> shows online vips. I'm searching now still no results.

[Exolent[jNr]]

You've had that in this thread like 3 times already.