[ConnorMcLeod]

Way to fix :

PHP Code:

#include <amxmodx>

#define VERSION "0.0.1"
#define PLUGIN "HLSW Chat Trigger"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    register_clcmd("say", "ClCmd_Say")
    register_clcmd("say_team", "ClCmd_SayTeam")
}

public ClCmd_Say( id )
{
    return Host_Say(id, 0)
}

public ClCmd_SayTeam( id )
{
    return Host_Say(id, 1)
}

Host_Say( id, teamonly )
{
    new szSaid[192]
    read_args(szSaid, charsmax(szSaid))
    remove_quotes(szSaid)
    if( IsChatValid( szSaid ) )
    {
        // UTIL_LogPrintf
        log_message("^"%s<%d><%s><%s>^" %s ^"%s^"%s",
            GETPLAYERNAME(id),
            get_user_userid(id),
            GETPLAYERAUTHID(id),
            GETPLAYERTEAM(id),
            teamonly ? "say_team" : "say",
            szSaid,
            is_user_alive(id) ? "" : " (dead)")
    }
    return PLUGIN_HANDLED_MAIN
}

GETPLAYERAUTHID( id )
{
    static szAuthid[32]
    get_user_authid(id, szAuthid, charsmax(szAuthid))
    return szAuthid
}

GETPLAYERNAME( id )
{
    static szName[32]
    get_user_name(id, szName, charsmax(szName))
    return szName
}

GETPLAYERTEAM( id )
{
    static szTeam[10]
    get_user_team(id, szTeam, charsmax(szTeam))
    if( szTeam[0] == 'U' )
    {
        szTeam[0] = EOS
    }
    return szTeam
}

IsChatValid( const szChat[] )
{
    new c, i
    while( (c = szChat[i++]) != EOS )
    {
        if( c != ' ' )
        {
            return 1
        }
    }
    return 0
} 


[Kidev]

Originally Posted by Daddy-K I tested and it does not work HLSW does not record all chat conversations

HLTV means HLTV lol, not HLSW.

Aswell, this bug is gonna be fixed tomorrow, thanks to Connor ;)

Daddy-K, try this and tell me if it works. If yes, i'll make 2/3 tests and release it.

Uhuh my bad, completly bugged! Tomorrow, i promise!

[Kidev]

Then, finally, updated ;) HLSW bug should be fixed now

[Daddy-K]

Now it works perfectly. Thanks, man. I hope to be approved.
If they will appear some problems I will come back with a publisher

[Kidev]

Originally Posted by Daddy-K Now it works perfectly. Thanks, man. I hope to be approved. If they will appear some problems I will come back with a publisher

Ok Thanks Connor too ^^

[echo_cs]

Nice plugin

[Daddy-K]

// Soon: <blue>, <red> and <grey>.

Wait for new update!

[Kidev]

Originally Posted by Daddy-K Wait for new update!

Soon, soon

[Kidev]

Updated to 1.2.0:

• Added <red>, <blue> and <grey> colors
• Added %TEAMTAG%
• Change some variables to 'const' to prevent errors

[Daddy-K]

TEAMTAG does not work