[theproperson]

Wondering if anyone could build a plugin that makes survivor bots always have god mode enabled until a human player takes over and re-enabled if that human player leaves/loses control.

I have tried various god mode plugins but they never auto enable nor do they let me target bot players.

I also understand this could be exploited by using idle but I run a non competitive server with low special respawn timers and would enjoy my bot teammates being able to survive while im doing play testing and maint runs.

Thank you for the consideration.

[cravenge]

Here you go:

PHP Code:

#pragma semicolon 1
#include <sourcemod>

bool bStop, bCannotDie[MAXPLAYERS+1];

public void OnPluginStart()
{
    HookEvent("round_start", OnRoundStart);
    
    HookEvent("round_end", OnRoundEvents);
    HookEvent("finale_win", OnRoundEvents);
    HookEvent("mission_lost", OnRoundEvents);
    HookEvent("map_transition", OnRoundEvents);
}

public void OnPluginEnd()
{
    UnhookEvent("round_start", OnRoundStart);
    
    UnhookEvent("round_end", OnRoundEvents);
    UnhookEvent("finale_win", OnRoundEvents);
    UnhookEvent("mission_lost", OnRoundEvents);
    UnhookEvent("map_transition", OnRoundEvents);
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && GetClientTeam(i) == 2 && IsFakeClient(i))
        {
            if (!bCannotDie[i])
            {
                continue;
            }
            
            bCannotDie[i] = false;
            
            SetEntProp(i, Prop_Data, "m_fFlags", GetEntProp(i, Prop_Data, "m_fFlags") & ~FL_GODMODE);
            SetEntProp(i, Prop_Data, "m_takedamage", 2, 1);
        }
    }
}

public void OnRoundStart(Event event, const char[] name, bool dontBroadcast)
{
    bStop = false;
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            bCannotDie[i] = false;
        }
    }
    
    CreateTimer(1.0, CheckForHumanPlayers, _, TIMER_REPEAT);
}

public Action CheckForHumanPlayers(Handle timer)
{
    if (bStop)
    {
        return Plugin_Stop;
    }
    
    if (GetHumanCount() < 1)
    {
        for (int i = 1; i <= MaxClients; i++)
        {
            if (IsClientInGame(i) && GetClientTeam(i) == 2 && IsFakeClient(i))
            {
                if (bCannotDie[i])
                {
                    continue;
                }
                
                bCannotDie[i] = true;
                
                SetEntProp(i, Prop_Data, "m_takedamage", 0, 1);
                SetEntProp(i, Prop_Data, "m_fFlags", GetEntProp(i, Prop_Data, "m_fFlags") | FL_GODMODE);
            }
        }
    }
    else
    {
        for (int i = 1; i <= MaxClients; i++)
        {
            if (IsClientInGame(i) && GetClientTeam(i) == 2 && IsFakeClient(i))
            {
                if (!bCannotDie[i])
                {
                    continue;
                }
                
                bCannotDie[i] = false;
                
                SetEntProp(i, Prop_Data, "m_fFlags", GetEntProp(i, Prop_Data, "m_fFlags") & ~FL_GODMODE);
                SetEntProp(i, Prop_Data, "m_takedamage", 2, 1);
            }
        }
    }
    return Plugin_Continue;
}

public void OnRoundEvents(Event event, const char[] name, bool dontBroadcast)
{
    if (!bStop)
    {
        bStop = true;
    }
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && GetClientTeam(i) == 2 && IsFakeClient(i))
        {
            if (!bCannotDie[i])
            {
                continue;
            }
            
            bCannotDie[i] = false;
            
            SetEntProp(i, Prop_Data, "m_fFlags", GetEntProp(i, Prop_Data, "m_fFlags") & ~FL_GODMODE);
            SetEntProp(i, Prop_Data, "m_takedamage", 2, 1);
        }
    }
}

int GetHumanCount()
{
    int iCount = 0;
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && !IsFakeClient(i))
        {
            iCount += 1;
        }
    }
    return iCount;
} 


[theproperson]

Sorry for the late reply but thank you very much cravenge. Been busy with some work.