[Reflex]

Hello guys maybe you could help me a bit.

I do have a method which should destroy given client's projectiles.

new ent = -1;
while ((ent = FindEntityByClassname(ent, "tf_projectile_*")) != -1) {
    if (GetEntPropEnt(ent, Prop_Send, "m_hOwnerEntity") == client) {
        AcceptEntityInput(ent, "Kill");
    }
    // WARNING: next code block will cause issues!
    if (GetEntPropEnt(ent, Prop_Send, "m_hThrower") == client) {
        AcceptEntityInput(ent, "Kill");
    }
}

I would like to write the code once and support any further game updates which may add new projectiles. The problem is that some projectiles (rockets, arrows, bolts) store their owner inside m_hOwnerEntity prop but other projectiles (pipes, stickies) uses m_hThrower prop for that.

How could I check if entity do have one of the properties that I may need without running into `Native "GetEntPropEnt" reported: Property "m_hThrower" not found` error?

[Miu]

I think FindSendPropOffs should return -1 if it's not found

edit: actually that takes classnames, but I guess FindDataMapOffs should work as long as they exist there too

[Reflex]

Miu, thank you, FindDataMapOffs did the trick. Seems I need to read the dosc more carefully next time.

I'll leave my solution here for those who care.

stock DestroyClientProjectiles(client)
{
    new offset;
    new ent = -1;
    while ((ent = FindEntityByClassname(ent, "tf_projectile_*")) != -1) {
        // destroy rockets, arrows, bolts, etc
        offset = FindDataMapOffs(ent, "m_hOwnerEntity");
        if (offset != -1 && GetEntDataEnt2(ent, offset) == client) {
            AcceptEntityInput(ent, "Kill");
            continue;
        }
        
        // destroy pipes, stickies and other throwables
        offset = FindDataMapOffs(ent, "m_hThrower");
        if (offset != -1 && GetEntDataEnt2(ent, offset) == client) {
            AcceptEntityInput(ent, "Kill");
        }
    }
}