[r3v]

Hello. I need a plugin which can block one radio console command.
This video shows what i want to block:
https://www.youtube.com/watch?v=g8Cx...l=3kliksphilip

[Bacardi]

PHP Code:

public void OnPluginStart()
{
    if(GetFeatureStatus(FeatureType_Capability, FEATURECAP_COMMANDLISTENER) != FeatureStatus_Available)
    SetFailState("SourceMod COMMAND LISTENER is not available");

    AddCommandListener(listen, "playerradio");
}

public Action listen(int client, const char[] command, int argc)
{
    if(client > 0 && argc == 2)
    {
        char buffer[10];
        GetCmdArg(1, buffer, sizeof(buffer));
        
        if(StrEqual(buffer, "deathcry", false))
        {
            if(IsClientInGame(client))
            {
                PrintToChat(client, "[SM] Stop it.");
            }

            return Plugin_Handled;
        }
    }
    
    return Plugin_Continue;
} 


[r3v]

PHP Code:

//// deathcry_blocker.sp
//
// D:\Servers\public_csgo\csgo\addons\sourcemod\scripting\deathcry_blocker.sp(11) : warning 211: possibly unintended assignment
// D:\Servers\public_csgo\csgo\addons\sourcemod\scripting\deathcry_blocker.sp(11) : error 022: must be lvalue (non-constant)
// D:\Servers\public_csgo\csgo\addons\sourcemod\scripting\deathcry_blocker.sp(11) : warning 215: expression has no effect
// D:\Servers\public_csgo\csgo\addons\sourcemod\scripting\deathcry_blocker.sp(11) : error 001: expected token: ";", but found ")"
// D:\Servers\public_csgo\csgo\addons\sourcemod\scripting\deathcry_blocker.sp(11) : error 029: invalid expression, assumed zero
// D:\Servers\public_csgo\csgo\addons\sourcemod\scripting\deathcry_blocker.sp(11) : fatal error 190: too many error messages on one line
//
// Compilation aborted.
// 4 Errors.
//
// Compilation Time: 0,34 sec
// ----------------------------------------

Press enter to exit ... 


[Bacardi]

Dam ==. Try again

[r3v]

Originally Posted by Bacardi Dam ==. Try again

Sorry, for late response. Plugin is working! Thank You!

[digin]

Originally Posted by Bacardi PHP Code: public void OnPluginStart() {     if(GetFeatureStatus(FeatureType_Capability, FEATURECAP_COMMANDLISTENER) != FeatureStatus_Available)     SetFailState("SourceMod COMMAND LISTENER is not available");     AddCommandListener(listen, "playerradio"); } public Action listen(int client, const char[] command, int argc) {     if(client > 0 && argc == 2)     {         char buffer[10];         GetCmdArg(1, buffer, sizeof(buffer));                  if(StrEqual(buffer, "deathcry", false))         {             if(IsClientInGame(client))             {                 PrintToChat(client, "[SM] Stop it.");             }             return Plugin_Handled;         }     }          return Plugin_Continue; }

Thanks!

[mranis18]

Originally Posted by Bacardi PHP Code: public void OnPluginStart() {     if(GetFeatureStatus(FeatureType_Capability, FEATURECAP_COMMANDLISTENER) != FeatureStatus_Available)     SetFailState("SourceMod COMMAND LISTENER is not available");     AddCommandListener(listen, "playerradio"); } public Action listen(int client, const char[] command, int argc) {     if(client > 0 && argc == 2)     {         char buffer[10];         GetCmdArg(1, buffer, sizeof(buffer));                  if(StrEqual(buffer, "deathcry", false))         {             if(IsClientInGame(client))             {                 PrintToChat(client, "[SM] Stop it.");             }             return Plugin_Handled;         }     }          return Plugin_Continue; }

i need same plugin just for block this playerradio Guardian.Victory
if u can help me

[Bacardi]

PHP Code:

public void OnPluginStart()
{
    if(GetFeatureStatus(FeatureType_Capability, FEATURECAP_COMMANDLISTENER) != FeatureStatus_Available)
    SetFailState("SourceMod COMMAND LISTENER is not available");

    AddCommandListener(listen, "playerradio");
}

public Action listen(int client, const char[] command, int argc)
{
    if(client > 0 && argc == 2)
    {
        char buffer[30];
        GetCmdArg(1, buffer, sizeof(buffer));
        
        if(StrContains(buffer, "guardian.", false) != -1)
        {
            if(IsClientInGame(client))
            {
                PrintToChat(client, "[SM] Stop it.");
            }

            return Plugin_Handled;
        }
    }
    
    return Plugin_Continue;
} 


[Bacardi]

I quick make test plugin. For testing only.

- It read response_rules.txt file (inside VPK) and collect possible playerradio words.
- sm_test open menu with list words.
- Reloading plugin you see in server console list of words.
- In-game cooldown will slow you for spamming playerradio commands :/

- Most working playerradio words are actually set in other file, file name is called by model name.
I have no time to fiddle with that...

- So most words in menu would not work, it depends either of team, model or it is round event sound, game play ? etc. etc.

test plugin

PHP Code:





#include <regex>

ArrayList arraylist;

public void OnPluginStart()
{
    File response_rules = OpenFile("scripts/talker/response_rules.txt", "rt", true);

    if(response_rules == null) SetFailState("Failed to open file");


    arraylist = new ArrayList(ByteCountToCells(MAX_NAME_LENGTH));

    Regex regex = new Regex("criterion .* \"concept\" (\\S+).* required");

    char buffer[500];
    char substring[MAX_NAME_LENGTH];

    while(!response_rules.EndOfFile())
    {
        response_rules.ReadLine(buffer, sizeof(buffer));
        substring[0] = '\0';

        if(regex.Match(buffer) == 2)
        {
            regex.GetSubString(1, substring, sizeof(substring));
            
            if(strlen(substring) > 2)
            {
                PrintToServer("substring %s", substring);
                arraylist.PushString(substring);
            }
        }
    }
    
    delete response_rules;
    delete regex;
    
    arraylist.Sort(Sort_Ascending, Sort_String);
    
    
    RegConsoleCmd("sm_test", test);
}


public Action test(int client, int argc)
{
    Menu menu1 = new Menu(menuhandler1);

    char buffer[MAX_NAME_LENGTH];

    for(int x = 0; x < arraylist.Length; x++)
    {
        if(arraylist.GetString(x, buffer, sizeof(buffer)) > 0)
            menu1.AddItem(buffer, buffer);
    }

    menu1.Display(client, 0);

    return Plugin_Handled;
}


public int menuhandler1(Menu menu, MenuAction action, int param1, int param2)
{
    switch(action)
    {
        case MenuAction_Select:
        {
            char buffer[MAX_NAME_LENGTH];

            menu.GetItem(param2, buffer, sizeof(buffer));
            ClientCommand(param1, "playerradio %s %s", buffer, buffer);
            
            menu.DisplayAt(param1, menu.Selection, 0);
        }
        case MenuAction_Cancel:
        {
            delete menu;
        }
    }
}