[abdobiskra]

Hi Evry one
My question is what is the code used it ? I want Example to achieve it ?

[Zynda]

This sparked my interest because is just sounds so fun, so i whipped this up just now.
It is far from foolproof, but this will make the owner of any rpg_rocket 'follow' by copying the velocity to the owner every time the rpg thinks.

Things that will mess this up:

• Shooting more than one rocket at a time
• Moving backwards while in the air

PHP Code:


// Tested on 1.8.3-dev+

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

public plugin_init()
{
    register_plugin( "Rocketscience", "1.0", "Rocketman" )

    RegisterHam( Ham_Think , "rpg_rocket" , "RocketThinkHandler" )
}

public RocketThinkHandler( entity )
{
    new id = pev( entity, pev_owner )
    
    if( is_user_connected( id ) && is_user_alive( id ) )
    {
        new iuser1 = pev( entity, pev_iuser1 )
        
        if( iuser1 == 0 )
        {
            set_pev( entity, pev_iuser1, 1 )
            
            new Float:nullVelocity[ 3 ] = { 0.0, 0.0, 0.0 }
            set_pev( id, pev_velocity, nullVelocity )
            
            new Float:startVector[ 3 ]
            pev( entity, pev_origin, startVector )
            
            new Float:destinationVector[ 3 ]
            pev( entity, pev_angles, destinationVector )
            
            engfunc( EngFunc_MakeVectors, destinationVector )
            global_get( glb_v_forward, destinationVector )
            
            xs_vec_mul_scalar( destinationVector, -50.0, destinationVector )
            xs_vec_add( startVector, destinationVector, destinationVector )
            
            engfunc( EngFunc_SetOrigin, id, destinationVector )
        }
        else
        {
            new Float:rocketVelocity[ 3 ]
            pev( entity, pev_velocity, rocketVelocity )
            
            set_pev( id, pev_velocity, rocketVelocity )
        }
    }

    return HAM_IGNORED
} 


[abdobiskra]

Zynda
I do not know how to thank you

[Leech_v2]

Originally Posted by abdobiskra Zynda I do not know how to thank you

you body...

[abdobiskra]

Leech_v2
Here is not the place for sarcasm
stoped floding like gays idiots ...

--------------------------------------------

Zynda

i want add godmode if rocket explod in the wall for owner and disabel it if player not flying (after explod the rocket )

i have this stock :

PHP Code:

stock fm_set_user_godmode(index, godmode = 0) {
    set_pev(index, pev_takedamage, godmode == 1 ? DAMAGE_NO : DAMAGE_AIM)
    return 1
} 


But I find it difficult to employ them can you tel me if you have any ida please ?

[meTaLiCroSS]

Provide your rocket explosion code then.

[abdobiskra]

Originally Posted by meTaLiCroSS Provide your rocket explosion code then.

can you give me for Exp! (code)

[Zynda]

Updated and tested as per request.

Now godmode is enabled just as the rocket explodes ( touches a wall, player etc.. ) then i set a timer to remove godmode after 0.5 seconds.

Also, that stock is just a wrapper, which i find to be more obscuring than helping in this case.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

public plugin_init()
{
    register_plugin( "Rocketscience", "1.0", "Rocketman" )

    RegisterHam( Ham_Think , "rpg_rocket" , "RocketThinkHandler" )
    RegisterHam( Ham_Touch , "rpg_rocket" , "RocketTouchHandler" )
}

public RocketThinkHandler( entity )
{
    new id = pev( entity, pev_owner )
    
    if( is_user_connected( id ) && is_user_alive( id ) )
    {
        new iuser1 = pev( entity, pev_iuser1 )
        
        if( iuser1 == 0 )
        {
            set_pev( entity, pev_iuser1, 1 )
            
            new Float:nullVelocity[ 3 ] = { 0.0, 0.0, 0.0 }
            set_pev( id, pev_velocity, nullVelocity )
            
            new Float:startVector[ 3 ]
            pev( entity, pev_origin, startVector )
            
            new Float:destinationVector[ 3 ]
            pev( entity, pev_angles, destinationVector )
            
            engfunc( EngFunc_MakeVectors, destinationVector )
            global_get( glb_v_forward, destinationVector )
            
            xs_vec_mul_scalar( destinationVector, -50.0, destinationVector )
            xs_vec_add( startVector, destinationVector, destinationVector )
            
            engfunc( EngFunc_SetOrigin, id, destinationVector )
        }
        else
        {
            new Float:rocketVelocity[ 3 ]
            pev( entity, pev_velocity, rocketVelocity )
            
            new Float:playerVelocity[ 3 ]
            pev( id, pev_velocity, playerVelocity )
            
            set_pev( id, pev_velocity, rocketVelocity )
        }
    }

    return HAM_IGNORED
}

public RocketTouchHandler( entity )
{
    new id = pev( entity, pev_owner )
    
    if( is_user_connected( id ) && is_user_alive( id ) )
    {
        // Enable godmode
        set_pev( id, pev_takedamage, DAMAGE_NO )
        
        // Set timer to remove godmode after 0.5 seconds
        set_task( 0.5, "ResetGodmode", id )
    }

    return HAM_IGNORED
}

public ResetGodmode( id )
{
    if( is_user_connected( id ) && is_user_alive( id ) )
    {
        set_pev( id, pev_takedamage, DAMAGE_AIM )
    }
}