[BrUn3S]

Hi guys... I have a issue.. when I want get some data from my db of admins.. It doesn't work but syntax in phpmyadmin working correctly.. please, can someone look on it?

PHP Code:

public bool:GetUserDatabaseData(Handle:db, String:steamID[], client)
{
    if(IsFakeClient(client)) return false;
    decl String:query[1024];
    decl String:flagsAndImmunity[68];
    decl String:DateExpiration[12];
    decl String:DaysLeft[12];
    Format(query, sizeof(query), "SELECT srv_flags, DateExpiration, TIMESTAMPDIFF(DAY, NOW(), DATE_FORMAT(STR_TO_DATE(DateExpiration, '%d.%m.%Y'),'%Y-%m-%d %H:%i:%s')) AS days_left FROM a_sb_admins WHERE authid LIKE '%s'", steamID);
    new Handle:hQuery = SQL_Query(db, query);
    if (hQuery != INVALID_HANDLE)
    {
        PrintToServer("Database request : Hrac %s (%N) -> reading...", steamID, client);
        while (SQL_FetchRow(hQuery))
        {
            SQL_FetchString(hQuery, 0, flagsAndImmunity, sizeof(flagsAndImmunity));
            SQL_FetchString(hQuery, 1, DateExpiration, sizeof(DateExpiration));
            SQL_FetchString(hQuery, 2, DaysLeft, sizeof(DaysLeft));
            
            strcopy(g_iDateExpiration[client], sizeof(DateExpiration), DateExpiration);
            strcopy(g_iDaysLeft[client], sizeof(DaysLeft), DaysLeft);
            
            PrintToServer(" %s (%N) '%s' %s",steamID, client, flagsAndImmunity, DateExpiration);
        }
        CloseHandle(hQuery);
        return true;
    }
    return false;
} 


I don't know what I have wrong with this code..
Thanks.

[Totenfluch]

Your whole code structure is flawed. Let me give you a better template:

PHP Code:

public void getUserDatabaseData(int client) {
    char steamID[20];
    GetClientAuthId(client, AuthId_Steam2, steamID, sizeof(steamID));
    
    char query[1024];
    Format(query, sizeof(query), "SELECT srv_flags, DateExpiration, TIMESTAMPDIFF(DAY, NOW(), DATE_FORMAT(STR_TO_DATE(DateExpiration, '%d.%m.%Y'),'%Y-%m-%d %H:%i:%s')) AS days_left FROM a_sb_admins WHERE authid = '%s'", steamID); 
    SQL_TQuery(g_DB, getDataCallback, query, GetClientUserId(client));
}

public void getDatesQueryCallback(Handle owner, Handle hndl, const char[] error, any data) {
    int client = GetClientOfUserId(data);
    char query[1024]; 
    char flagsAndImmunity[68]; 
    char DateExpiration[12]; 
    char DaysLeft[12]; 
    
    if (hndl!= INVALID_HANDLE) 
    { 
        while (SQL_FetchRow(hndl)) 
        { 
            SQL_FetchString(hndl, 0, flagsAndImmunity, sizeof(flagsAndImmunity)); 
            SQL_FetchString(hndl, 1, DateExpiration, sizeof(DateExpiration)); 
            SQL_FetchString(hndl, 2, DaysLeft, sizeof(DaysLeft)); 
             
            strcopy(g_iDateExpiration[client], sizeof(DateExpiration), DateExpiration); 
            strcopy(g_iDaysLeft[client], sizeof(DaysLeft), DaysLeft); 
             
            PrintToServer(" %s (%N) '%s' %s",steamID, client, flagsAndImmunity, DateExpiration); 
        }
    } 
} 


[Fyren]

If you look at your error log, you'll see an error about your Format call being broken. At the least, you'll have to escape some of your percent signs so Format doesn't try to handle them all.

[BrUn3S]

Thanks for reply..

I was rewrite this, now looks like this

PHP Code:

public void getUserDatabaseData(int client) {
    char steamID[20];
    GetClientAuthId(client, AuthId_Steam2, steamID, sizeof(steamID));
    
    char query[1024];
    Format(query, sizeof(query), "SELECT srv_flags, DateExpiration, TIMESTAMPDIFF(DAY, NOW(), DATE_FORMAT(STR_TO_DATE(DateExpiration, '%d.%m.%Y'),'%Y-%m-%d')) AS days_left FROM a_sb_admins WHERE authid = '%s'", steamID); 
    SQL_TQuery(DatabaseConnection, getDatesQueryCallback, query, GetClientUserId(client));
}

public void getDatesQueryCallback(Handle owner, Handle hndl, const char[] error, any data) {
    int client = GetClientOfUserId(data);
    char flagsAndImmunity[68]; 
    char DateExpiration[12]; 
    char DaysLeft[12];
    
    char steamID[20];
    GetClientAuthId(client, AuthId_Steam2, steamID, sizeof(steamID));
    
    if (hndl != INVALID_HANDLE) 
    {
        PrintToServer("Database request : Hrac %s (%N) -> Citanie ...", steamID, client);
        while (SQL_FetchRow(hndl)) 
        { 
            SQL_FetchString(hndl, 0, flagsAndImmunity, sizeof(flagsAndImmunity)); 
            SQL_FetchString(hndl, 1, DateExpiration, sizeof(DateExpiration)); 
            SQL_FetchString(hndl, 2, DaysLeft, sizeof(DaysLeft)); 
            
            strcopy(g_iDateExpiration[client], sizeof(DateExpiration), DateExpiration); 
            strcopy(g_iDaysLeft[client], sizeof(DaysLeft), DaysLeft); 
        }
    }
} 


still error

PHP Code:

[SM] Exception reported: String formatted incorrectly - parameter 5 (total 4) 


[Totenfluch]

PHP Code:

'%d.%m.%Y'),'%Y-%m-%d' 


This gets interpreted as placeholders for variables instead of %..

You have to escape them with \

PHP Code:

\%d  => %d
%d => replacement for a number 


so your code should look like

PHP Code:

Format(query, sizeof(query), "SELECT srv_flags, DateExpiration, TIMESTAMPDIFF(DAY, NOW(), DATE_FORMAT(STR_TO_DATE(DateExpiration, '\%d.\%m.\%Y'),'\%Y-\%m-\%d')) AS days_left FROM a_sb_admins WHERE authid = '%s'", steamID); 


(not tested tho)

[BrUn3S]

Yea, thanks for help. I resolve this by using timestamp and FormatTime.. thanks a lot

[asherkin]

Originally Posted by Totenfluch You have to escape them with \

That is incorrect, to specify a literal % in a format string you use the %% format specifier.

PHP Code:

DATE_FORMAT(STR_TO_DATE(DateExpiration, '%%d.%%m.%%Y'),'%%Y-%%m-%%d') 


Also, GetClientAuthId can fail, do not skip checking the return value.