[-Acid-]

Okay i was looking for a plugin that gives unlimited clips on connect to a player, didnt find out so i decided to create one, but i wanna make sure if the code is good, and well it work at all?? so heres my code......

PHP Code:

/* This plugin will set user clip to unlimited on connect to server. */

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Unlimited-Clips"
#define VERSION "1.0"
#define AUTHOR "-Acid-"

#if cellbits == 32
const OFFSET_CLIPAMMO = 51
#else
const OFFSET_CLIPAMMO = 65
#endif
const OFFSET_LINUX_WEAPONS = 4


new const MAXCLIP[] = { -1, 13, -1, 10, 1, 7, -1, 30, 30, 1, 30, 20, 25, 30, 35, 25, 12, 20,
10, 30, 100, 8, 30, 30, 20, 2, 7, 30, 30, -1, 50 }

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
    register_message(get_user_msgid("CurWeapon"), "message_cur_weapon")
}
public message_cur_weapon(msg_id, msg_dest, msg_entity)
{
    
    
    
    if (!is_user_alive(msg_entity) || get_msg_arg_int(1) != 1)
        return;
    
    static weapon, clip
    weapon = get_msg_arg_int(2) 
    clip = get_msg_arg_int(3) 
    
    
    if (MAXCLIP[weapon] > 2) 
    {
        set_msg_arg_int(3, get_msg_argtype(3), MAXCLIP[weapon])
        
        if (clip < 2) 
        {
            
            static wname[32], weapon_ent
            get_weaponname(weapon, wname, sizeof wname - 1)
            weapon_ent = fm_find_ent_by_owner(-1, wname, msg_entity)
            
            
            fm_set_weapon_ammo(weapon_ent, MAXCLIP[weapon])
        }
    }
}

stock fm_find_ent_by_owner(entity, const classname[], owner)
{
    while ((entity = engfunc(EngFunc_FindEntityByString, entity, "classname", classname)) && pev(entity, pev_owner) != owner) {}
    
    return entity;
}


stock fm_set_weapon_ammo(entity, amount)
{
    set_pdata_int(entity, OFFSET_CLIPAMMO, amount, OFFSET_LINUX_WEAPONS);
} 


So what do u think?? Well it work??.
Thanks in advance!!!

[Bugsy]

Here you go

I added 1 to the max clip ammo just so the clip ammo will always appear full instead of -1. ie. Using glock should always say 12 but without +1 it will always say 11. I'm not sure if the +1 will cause errors or not, it didn't while I tested. If you don't care about the clip ammo always being -1 of max then just remove the +1.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Unlimited Clip Ammo"
#define VERSION "1.0"
#define AUTHOR "bugsy"

#if cellbits == 32
const OFFSET_CLIPAMMO = 51
#else
const OFFSET_CLIPAMMO = 65
#endif

const OFFSET_LINUX_WEAPONS = 4

new const g_MaxClipAmmo[] = 
{
    0,
    13, //CSW_P228
    0,
    10, //CSW_SCOUT
    0,  //CSW_HEGRENADE
    7,  //CSW_XM1014
    0,  //CSW_C4
    30,//CSW_MAC10
    30, //CSW_AUG
    0,  //CSW_SMOKEGRENADE
    15,//CSW_ELITE
    20,//CSW_FIVESEVEN
    25,//CSW_UMP45
    30, //CSW_SG550
    35, //CSW_GALIL
    25, //CSW_FAMAS
    12,//CSW_USP
    20,//CSW_GLOCK18
    10, //CSW_AWP
    30,//CSW_MP5NAVY
    100,//CSW_M249
    8,  //CSW_M3
    30, //CSW_M4A1
    30,//CSW_TMP
    20, //CSW_G3SG1
    0,  //CSW_FLASHBANG
    7,  //CSW_DEAGLE
    30, //CSW_SG552
    30, //CSW_AK47
    0,  //CSW_KNIFE
    50//CSW_P90
}

public plugin_init() 
{
    register_plugin( PLUGIN , VERSION , AUTHOR );
    register_event( "CurWeapon" , "fw_CurWeapon" , "b" , "1=1" );
}

public fw_CurWeapon( id )
{
    static szWeapon[32], iWeapon, iWeaponEntity;
    
    iWeapon = read_data( 2 );
    
    get_weaponname( iWeapon , szWeapon , sizeof szWeapon - 1 );
    iWeaponEntity = fm_find_ent_by_owner( -1 , szWeapon , id );
    
    fm_set_weapon_ammo( iWeaponEntity , g_MaxClipAmmo[ iWeapon ] + 1 );
}

public fm_find_ent_by_owner( entity , const classname[] , owner )
{
    while ((entity = engfunc(EngFunc_FindEntityByString, entity, "classname", classname)) && pev(entity, pev_owner) != owner) {}
    
    return entity;
}

public fm_set_weapon_ammo(entity, amount)
{
    set_pdata_int(entity, OFFSET_CLIPAMMO, amount, OFFSET_LINUX_WEAPONS);
} 


[-Acid-]

Okay cool, is this still my original code, u just fix some errors?

[Bugsy]

I used your fm functions so I wouldn't have to dig through my inc's. Everything else is new

[-Acid-]

Okay so u wouldent mind if i post this in new submission with my name on it?

[Bugsy]

I don't care, just give credit please. Are you sure this doesn't already exist?

http://forums.alliedmods.net/showthread.php?t=26991 ??

[-Acid-]

Yea but that one u need to be using amx_ammo <nick,#userid> <0|1>
everytime a player connects, and this one doesnt.