[Exolent[jNr]]

The better question is this:
Are you only checking if a player's name exists in the constant global, or is the information going to be added dynamically via functions or something?

[lucas_7_94]

Second option exo! Bcoz i will try to set a custom model and custom weapon!

[Exolent[jNr]]

If you are using 1.8.2-dev version, then here is the TrieSet/GetArray method:

#include <amxmodx>

enum _:Type
{
    Name[ 64 ],
    Class[ 64 ],
    Access[ 64 ]
}

new const szAdminInfo[ ][ Type ] =
{
    { "Luqqas", "Developer", "Full" }
    // more more more 
}
new Trie:AdminInfo

public plugin_init( )
{
    AdminInfo = TrieCreate( )
    
    for( new i = 0; i < sizeof( szAdminInfo ); i++ )
    {
        TrieSetArray( AdminInfo, szAdminInfo[ i ][ Name ], szAdminInfo[ i ] );
    }
}

public check_name(id) {
    new name[32];
    get_user_name(id, name, charsmax(name));
    
    new info[Type];
    if( TrieGetArray(AdminInfo, name, info, Type) ) {
        // lets modify something
        copy(info[Class], charsmax(info[Class]), "edited");
        
        TrieSetArray(AdminInfo, name, info, Type);
    }
}

If that produces weird results, or you need one without TrieGet/SetArray, I can post another solution.

[lucas_7_94]

I'm using 1.8.1 , exists another method , or i should update my amx ?

Another question , when is better use Tries ? , because i'm sure i will use a menu with this , and i think its the better method , anyway , i'm trying to understand the tries , always like the method but never understand them ._., thanks you very much for the help , its really usefull.

[Exolent[jNr]]

Here is 1.8.1 friendly version:

#include <amxmodx>

enum _:Type
{
    Name[ 64 ],
    Class[ 64 ],
    Access[ 64 ]
}

new const szAdminInfo[ ][ Type ] =
{
    { "Luqqas", "Developer", "Full" }
    // more more more 
}

new Array:gAdminInfo
new Trie:gAdminIndex
new gNumAdminInfos

public plugin_init( )
{
    gAdminInfo = ArrayCreate( Type );
    gAdminIndex = TrieCreate( )
    
    for( new i = 0; i < sizeof( szAdminInfo ); i++ )
    {
        AddAdminInfo( szAdminInfo[ i ] );
    }
}

public check_name(id) {
    new name[32];
    get_user_name(id, name, charsmax(name));
    
    new index;
    if( TrieGetCell(gAdminIndex, name, index) ) {
        new info[Type];
        ArrayGetArray(gAdminInfo, index, info);
        
        // lets modify something
        copy(info[Class], charsmax(info[Class]), "edited");
        
        ArraySetArray(AdminInfo, index, info);
    }
}

AddAdminInfo(info[Type]) {
    ArrayPushArray(gAdminInfo, info);
    TrieSetCell(gAdminIndex, info[Name], gNumAdminInfos);
    gNumAdminInfos++;
}

[lucas_7_94]

Amazing helpful thread .

Thanks you very much for all!