[Watermelonnable]

So I want to delay a function inside an event and I'm going to use set_task for this. The problem is that the function delayed needs to be given a player ID which I have in the "set_task" scope but I don't know how to pass it. Any help here, please?

Thus far, this is what I've tried:

PHP Code:

public cswa_damage(weapon_id, victim, attacker, Float:damage)
{
    if (get_weapon_edict(weapon_id, REPL_CSWA_ITEMID) == g_iItemID) {
        static name[2][32];
        new callbackData[1];
        callbackData[0] = victim;
        get_user_name(victim, name[1], charsmax(name[]));
        set_task(4.0, "KillPlayer", name[1], callbackData);
    }
}

public KillPlayer(id)
{
    if (is_user_alive(id)) {
        user_kill(id);
    }
} 


[ZaX]

https://www.amxmodx.org/api/amxmodx/set_task

you dont need all this, you can simply do:

PHP Code:

public cswa_damage(weapon_id, victim, attacker, Float:damage)
{
    if(get_weapon_edict(weapon_id, REPL_CSWA_ITEMID) == g_iItemID)
    {
        set_task(4.0, "KillPlayer", victim);
    }
}

public KillPlayer(id)
{
    if(is_user_alive(id))
    {
        user_kill(id);
    }
} 


[Bugsy]

You can also pass more data if needed.

PHP Code:

new MoreData[ 3 ];
MoreData[ 0 ] = 123;
MoreData[ 1 ] = 456;
MoreData[ 2 ] = 789;
    
set_task( 1.0 , "Func" , id , MoreData , sizeof( MoreData ) );


public Func( const MoreData[ 3 ] , id )
{
    server_print( "id=%d MoreData[0]=%d MoreData[1]=%d MoreData[2]=%d" , id , MoreData[ 0 ] , MoreData[ 1 ] , MoreData[ 2 ] );
} 


[Bugsy]

@DjSoftero, you would always use sizeof() in set_task() since you are not formatting/manipulating a string. charsmax() returns sizeof() - 1, so using charsmax() on an array sized to 1 would be 0, meaning no data is passed. Your code is wrong and will cause confusion.

[DjSoftero]

Originally Posted by Bugsy @DjSoftero, you would always use sizeof() in set_task() since you are not formatting/manipulating a string. charsmax() returns sizeof() - 1, so using charsmax() on an array sized to 1 would be 0, meaning no data is passed. Your code is wrong and will cause confusion.

fair enough. lost my touch with it.

[JocAnis]

little offtopic but @Bugsy, is it possible to pass parameter(s) with register_clcmd ?

if we lets say have

public test( id, bool: print )

to have smth like: register_clcmd( "say /test", test, 1 ) ?

thanks in advance!

[Bugsy]

No, but it's still doable.

PHP Code:

register_clcmd( "say" , "SayFunc" );

public SayFunc( id )
{
    new szArgs[ 194 ] , szCmd[ 32 ];
    
    read_args( szArgs , charsmax( szArgs ) );
    remove_quotes( szArgs );
    argbreak( szArgs , szCmd, charsmax( szCmd ) , szArgs ,  charsmax( szArgs ) );
    
    if ( equali( szCmd , "/test" ) )
    {
        //szCmd = the command
        //szArgs = the text said after '/test'  eg. "/test 1234", szArgs would hold 1234
    }
} 


[Watermelonnable]

Thank you guys for your help. I understand it better now The plugin compiled fine, I'm gonna test it now.