[xxxperts]

today i gone in one sv " 103.2.238.246:27019" their was a plugin name pray, when i am dead and spectating the player and when i type "/pray" then player get 20 HP health but maximum life of player is 100HP this can be used only once for one player, after praying player in chat is comes "my cs user name" has just prayed for "name of player to whom i am spectating" if their is any plugin like this then plz give name or link & if not then plz make this plugin....

[Moody92]

Explain more ?

[joshknifer]

Spectators can say /pray and whoever they are spectating gets +20HP. Each player spectating can use it once per round, and only on one person. Max HP stays at 100. Then he wants a print saying who gave and recieved the hp

[Moody92]

I am not familiar with the 'targeting the spectator guy' method if it does exist.
Here what I have done. Not sure if it works or not as it's been a long time since I last used AMXX-Studio

You can pray to someone when you're dead/spectator by typing /pray <name of the player>

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <cstrike>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"

new prayed[33]
new Health2
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_event("HLTV", "NewRound", "a", "1=0", "2=0")  
    Health2 = register_cvar("amx_pray_health", "20")
    
    register_clcmd("/pray", "pray")

}

public NewRound(id){
    prayed[id] = 0
}

public pray(id){
    
    if(is_user_alive(id)){
        client_print(id, print_chat, "You cannot use /pray because you are alive")
    }
    else if(prayed[id] == 1){
        client_print(id, print_chat, "You can only use /pray once per round, please try the next round")
    }
    
    prayed[id] = 1
    
    new arg[20]
    read_argv(1, arg, 19)

    new Health = get_user_health(id)
    new player = cmd_target(id, arg, 1)
    new name[32]
    get_user_name(id, name, charsmax(name))
    new name2[32]
    get_user_name(player, name2, charsmax(name2))
    
    if (!player)
    {
        client_print(id, print_chat, "[AMXX] Sorry, player %s could not be found or targetted!", arg)
        return PLUGIN_HANDLED
    } 
    else {
        set_user_health(player, Health + Health2)
        client_print(0, print_chat, "%s has just prayed for %s", name, name2)
    }
 
    return PLUGIN_HANDLED
} 


[xxxperts]

moody i have an idea..!, u can use set_task for giving health and after the i use /pray and if the target dead than

client_print(id, print_chat, "Aww! %s has Diead Before Your Prayer Completed ", name2)

[OWNX]

and a sound as long you pray will be awsome

[Moody92]

Originally Posted by xxxperts moody i have an idea..!, u can use set_task for giving health and after the i use /pray and if the target dead than client_print(id, print_chat, "Aww! %s has Diead Before Your Prayer Completed ", name2)

Could you explain more ?

The plugin I posted has many bugs that I noticed after revising it.
Due to my short free time, if anyone wants to edit the plugin I posted he is free to do that.

[ConnorMcLeod]

@Moody92

You should learn :

- how to use cvars pointers
- how to hook global events

-> pointers doesn't hold cvar value
-> global events don't pass any player index

Those mistake are basic mistakes.

[Moody92]

Originally Posted by ConnorMcLeod @Moody92 You should learn : - how to use cvars pointers - how to hook global events -> pointers doesn't hold cvar value -> global events don't pass any player index Those mistake are basic mistakes.

Thank you for your observations, I understand the meaning of what you just said. I'll edit the plugin as soon as possible
I'll look out for more tutorials regarding this matter as I am not a literally coder

[Shooting King]

Pray

PHP Code:

#include <amxmodx>
#include <engine>

#define PLUGIN        "Pray Plugin"
#define VERSION        "1.0"
#define AUTHOR        "Shooting King"

#define TASK_PRAY    78238

new bool:HasPrayed[33][2];
new pCvar_Hp;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_clcmd("say /pray", "cmd_GiveHp");
    register_clcmd("say_team /pray", "cmd_GiveHp");

    pCvar_Hp = register_cvar("amx_sk_pray_hp", "20");
    
    register_event("HLTV", "event_NewRound", "a", "1=0", "2=0");
}

public event_NewRound()
{
    for(new i=1; i < 33; i++)
    {
        HasPrayed[i][1] = false;
        HasPrayed[i][0] = false;
    }
}

public client_putinserver(id)
{
    HasPrayed[id][1] = false;
    HasPrayed[id][0] = false;
}

public cmd_GiveHp(id)
{
    static iSpecMode, iSpecPlayer, szName[32], szSpecName[32], izParam[1];
    
    iSpecMode = entity_get_int(id, EV_INT_iuser1);
    if(iSpecMode == 0 || iSpecMode == 3)
    {
        client_print( id, print_chat, "You are not Spectating a player." );
        return PLUGIN_CONTINUE;
    }
    
    if(HasPrayed[id][0])
    {
        client_print( id, print_chat, "You have to wait for 2.5 seconds." );
        return PLUGIN_CONTINUE;
    }
    
    if(HasPrayed[id][1])
    {
        client_print( id, print_chat, "You have already prayed this round." );
        return PLUGIN_CONTINUE;
    }
    
    iSpecPlayer = entity_get_int(id, EV_INT_iuser2);
    if(entity_get_float(iSpecPlayer, EV_FL_health) == 100.0)
    {    
        client_print( id, print_chat, "The Player you are spectating already has 100 Hp." );
        return PLUGIN_CONTINUE;
    }
    
    get_user_name( id, szName, charsmax(szName));
    get_user_name( iSpecPlayer, szSpecName, charsmax(szSpecName));
    
    client_print( 0, print_chat, "%s has just prayed for %s.", szName, szSpecName);
    izParam[0] = iSpecPlayer;
    HasPrayed[id][0] = true;
    set_task( 2.5, "Pray", (TASK_PRAY+id), izParam, 1);
    return PLUGIN_CONTINUE;
}

public Pray( param[1], id )
{
    id -= TASK_PRAY;
    static Float:flCvarHealth, Float:flHealth, Float:flRemPlayerHealth;    
    
    flRemPlayerHealth = 100.0-entity_get_float(param[0], EV_FL_health);
    
    if( is_user_alive(param[0]) && (flRemPlayerHealth > 0.0))
    {    
        flCvarHealth = get_pcvar_float(pCvar_Hp);
        flHealth = ( flRemPlayerHealth >= flCvarHealth )? flCvarHealth:flRemPlayerHealth;
        
        entity_set_float(param[0], EV_FL_health, entity_get_float(param[0], EV_FL_health)+flHealth);
        HasPrayed[id][1] = true;
    }
    HasPrayed[id][0] = false;
} 


Cvars:
amx_sk_pray_hp <health> Default: 20