How to detect grenade damage in the Ham_takedamage function?

ot_207 · **Author**

I know that in cs the grenade doesn't have an assigned damage type ...
Is it possible to detect if an attack is made by a gun or by a grenade in ham_takedamage?

DA

Code:

/**
	 * Description:		Usually called whenever an entity takes any kind of damage.
	 *					Inflictor is the entity that caused the damage (such as a gun).
	 *					Attacker is the entity that tirggered the damage (such as the gun's owner).
	 * Forward params:	function(this, idinflictor, idattacker, Float:damage, damagebits);
	 * Return type:		Integer.
	 * Execute params:	ExecuteHam(Ham_TakeDamage, this, idinflictor, idattacker, Float:damage, damagebits);
	 */
	Ham_TakeDamage,

This is from ham_const.inc. idinflictor is the id from the weapon.

ot_207

What id???
As an entity or CSW_HEGRENADE?

anakin_cstrike

Lol...const !
CSW_HEGRENADE

Alka

I remember connorr detected a damage flag for HE grenades, but idr now...
You can make like this

Code:

if(!(bitDamage & (DMG_FALL | DMG_DROWN)))
    //Damage maked by HE grenade.

DA

Quote:

Originally Posted by ot_207

What id???
As an entity or CSW_HEGRENADE?

Yes. You can with CSW_HEGRENADE detect which gun the player has.

Quote:

Originally Posted by Alka

I remember connorr detected a damage flag for HE grenades, but idr now...
You can make like this

Code:

if(!(bitDamage & (DMG_FALL | DMG_DROWN)))
    //Damage maked by HE grenade.

Well. The function result the weapon. Why should he detect the weapon like this?

ot_207 · *Last edited by ot_207; 06-04-2008 at 08:16.*

i will try the CSW_HEGRENADE id ...
[EDIT] that isn't it

There is a problem with my nanosuit plugin.
The problem is when a user throws a grenade, if he has the knife and strength mode on when the nade explodes the grenade deals 4* damage ... a thing which i don't know how to detect ...[/EDIT]

ot_207

Quote:

Originally Posted by Alka

I remember connorr detected a damage flag for HE grenades, but idr now...
You can make like this

Code:

if(!(bitDamage & (DMG_FALL | DMG_DROWN)))
    //Damage maked by HE grenade.

I don't think that's it ...
What about DMG_BULLET ???

**Arkshine** · *Last edited by Arkshine; 06-04-2008 at 09:13.*

Ham way :

Code:

    #include <amxmodx>
    #include <hamsandwich>
    
    #define DMG_GRENADE ( 1 << 24 )
    
    public plugin_init ()
    {
        RegisterHam ( Ham_TakeDamage, "player", "fwd_TakeDamage" );
    }
    
    public fwd_TakeDamage ( id, i_Inflictor, i_Attacker, Float:f_Damage, i_DamageBits )
    {
        if ( i_DamageBits & DMG_GRENADE )
        {
            client_print ( id, print_chat, "Grenade triggered." );
        }
    }

if not enough, or doesn't work well, try this :

Code:

    #include <amxmodx>
    #include <fakemeta>
    #include <hamsandwich>

    public plugin_init ()
    {
        RegisterHam ( Ham_TakeDamage, "player", "fwd_TakeDamage" );
    }
    
    public fwd_TakeDamage ( id, i_Inflictor, i_Attacker, Float:f_Damage, i_DamageBits )
    {
        if ( IsGrenade ( i_Inflictor ) )
        {
            client_print ( id, print_chat, "Grenade triggered." );
        }
    }
    
    bool:IsGrenade ( i_Inflictor )
    {
        static s_Classname[ 8 ];
        pev ( i_Inflictor, pev_classname, s_Classname, charsmax ( s_Classname ) );
        
        return equal ( s_Classname, "grenade" ) ? true : false;
    }

Fakemeta way :

Code:


    #include <amxmodx>
    #include <fakemeta>

    public plugin_init ()
    {
        register_event ( "Damage", "e_Damage", "be", "2!0" );
    }
    
    public e_Damage ( i_Victim )
    {
        if ( IsGrenade ( pev ( i_Victim, pev_dmg_inflictor ) ) )
        {
            client_print ( i_Victim, print_chat, "Grenade triggered." );
        }
    }
    
    bool:IsGrenade ( i_Inflictor )
    {
        static s_Classname[ 8 ];
        pev ( i_Inflictor, pev_classname, s_Classname, charsmax ( s_Classname ) );
        
        return equal ( s_Classname, "grenade" ) ? true : false;
    }

ot_207

Thanks arkshine! +k

Just another question what does the << operator do exactly?
I didn't quite understood from the tutorial

...