[Dakex]

Hi guys, I am trying to create game mode system for my jailbreak plugin.
The problem is, I want to implement natives which will allow to create custom game modes from different plugins.

I am using two ArrayLists, one for the menu (name of gamemode), second one is used to save the handler.

But the code is not working at all. When I try to open the menu, nothing happens, it just says invalid index 8 at line 57 which makes no sense to me.

Here is the code:

PHP Code:

#define PLUGIN_NAME           "GameModes"
#define PLUGIN_AUTHOR         "Dakex"
#define PLUGIN_DESCRIPTION    ""
#define PLUGIN_VERSION        "1.1 Epom"
#define PLUGIN_URL            ""

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1

ArrayList gameModes;
ArrayList gameModes_Handler;

char defaultGameModes_Handler[] = {"Shooter_Handle", "HNS_Handle", "Matrix_Handle", "CODMW_Handle"};
char defaultGameModes[] = {"Shooter", "HNS", "Matrix", "COD:MW"};

public Plugin:myinfo =
{
    name = PLUGIN_NAME,
    author = PLUGIN_AUTHOR,
    description = PLUGIN_DESCRIPTION,
    version = PLUGIN_VERSION,
    url = PLUGIN_URL
};

public OnPluginStart()
{
    gameModes = CreateArray(64);
    gameModes_Handler = CreateArray(64);
    
    LoadDefaultGameModes();
    
    RegConsoleCmd("gamemod", GameModeMenu, "turns the gamemode on");
}
public void LoadDefaultGameModes() 
{
    for(int i = 0; i <= sizeof(defaultGameModes); i++)
    {
        gameModes.PushString(defaultGameModes[i]);
        gameModes_Handler.PushString(defaultGameModes_Handler[i]);
    }
}
public Action GameModeMenu(int client, int args)
{
    Menu gameModeMenu = new Menu(GameModeMenu_Handler);
    char buffer[64];
    char idBuffer[64];
    
    gameModeMenu.SetTitle("Game Modes");
    
    for(int i = 0; i <= gameModes.Length; i++)
    {
        IntToString(i, idBuffer, sizeof(idBuffer));
        
        gameModes.GetString(i, buffer, sizeof(buffer) );
        gameModeMenu.AddItem(idBuffer, buffer);
    }
    gameModeMenu.Display(client, 20);
    
    return Plugin_Handled;
}
public int GameModeMenu_Handler(Menu menu, MenuAction action, int param1, int param2)
{
    char menuIdBuffer[64];
    char buffer[64];
    
    GetMenuItem(menu, param2, menuIdBuffer, sizeof(menuIdBuffer));
    int menuId = StringToInt(menuIdBuffer);
    
    gameModes_Handler.GetString(menuId, buffer, sizeof(buffer));
    
    PrintToServer("%s %d", buffer, menuId);
    
    Function gameModeFunc = GetFunctionByName(INVALID_HANDLE, buffer);
    Call_StartFunction(INVALID_HANDLE, gameModeFunc);
    Call_Finish();
}
public void Shooter_Handle() 
{
    PrintToChatAll("TURNING ON SHOOTER!");
}
public void HNS_Handle()
{
    PrintToChatAll("TURNING ON HNS!");
}
public void Matrix_Handle()
{
    PrintToChatAll("TURNING ON MATRIX!");
}
public void CODMW_Handle()
{
    PrintToChatAll("Turning the COD:MW MODE ON!");
} 


[Kailo]

I would to suggest next tips:
1) Use ByteCountToCells function to convert byte count to cells for ArrayList contructor
2) Use enum struct to trick ArrayList and be able to set Function type
3) In condition, that menu uses only such type of items. Use param id instead of "info" data

PS
1) Your code is looking right, can't see why it not work
2) I also don't know, why ArrayList::*Function natives not exists. weird.

[Dakex]

Hi, Thank you for your help, but I'm not sure how to go about it.
I tried, but my code throws a lot of errors.

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1

ArrayList gameModes;

typedef gameModeFunc = function Action ();

enum struct GameMode 
{
    char name[48];
    gameModeFunc gameMode_Handler;
}

gameModeFunc defaultGameModes_Handler[] = {Shooter_Handle, HNS_Handle, Matrix_Handle, CODMW_Handle};
char defaultGameModes[] = {"Shooter", "HNS", "Matrix", "COD:MW"};

public Plugin:myinfo =
{
    name = PLUGIN_NAME,
    author = PLUGIN_AUTHOR,
    description = PLUGIN_DESCRIPTION,
    version = PLUGIN_VERSION,
    url = PLUGIN_URL
};

public OnPluginStart()
{
    gameModes = CreateArray(ByteCountToCells(64));
    
    LoadDefaultGameModes();
    
    RegConsoleCmd("gamemod", GameModeMenu, "turns on any gamemode!");
}
public void LoadDefaultGameModes() 
{
    for(int i = 0; i <= sizeof(defaultGameModes); i++)
    {
        GameMode gameMod;
        strcopy(gameMod.name, ByteCountToCells(48), defaultGameModes[i]);
        
        gameMod.gameMode_Handler = defaultGameModes_Handler[i];
        
        gameModes.PushArray(gameMod, sizeof(gameMod));
    }
}
public Action GameModeMenu(int client, int args)
{
    Menu gameModeMenu = new Menu(GameModeMenu_Handler);
    GameMode buffer[64];
    char idBuffer[64];
    
    gameModeMenu.SetTitle("Game Modes");
    
    for(int i = 0; i <= gameModes.Length; i++)
    {
        IntToString(i, idBuffer, sizeof(idBuffer));
        
        gameModes.GetArray(i, buffer);
        gameModeMenu.AddItem(idBuffer, buffer.name);
    }
    gameModeMenu.Display(client, 20);
    
    return Plugin_Handled;
}
public int GameModeMenu_Handler(Menu menu, MenuAction action, int param1, int param2)
{
    if(action == MenuAction_End || action == MenuAction_Cancel)
    {
        CloseHandle(menu);
    }
    
    if(action == MenuAction_Select)
    {
        GameMode buffer[64];
        gameModes.GetArray(param2, buffer);
        
        buffer.gameMode_Handler();
        
    }
}
public Action Shooter_Handle() 
{
    PrintToChatAll("shooter!");
}
public Action HNS_Handle()
{
    PrintToChatAll("hns!");
}
public Action Matrix_Handle()
{
    PrintToChatAll("matrix!");
}
public Action CODMW_Handle()
{
    PrintToChatAll("codmw!");
} 


Errors:

PHP Code:

    F:\workspace\sourcepawn\jailbreak\testmod.sp(24) : error 008: must be a constant expression; assumed zero
    F:\workspace\sourcepawn\jailbreak\testmod.sp(69) : error 048: array (s do not match
    F:\workspace\sourcepawn\jailbreak\testmod.sp(70) : error 106: cannot call methods on an array
    F:\workspace\sourcepawn\jailbreak\testmod.sp(86) : error 048: array (s do not match
    F:\workspace\sourcepawn\jailbreak\testmod.sp(88) : error 106: cannot call methods on an array
    F:\workspace\sourcepawn\jailbreak\testmod.sp(88) : error 029: invalid expression, assumed zero
    F:\workspace\sourcepawn\jailbreak\testmod.sp(88) : warning 215: expression has no effect
    F:\workspace\sourcepawn\jailbreak\testmod.sp(39) : warning 204: symbol is assigned a value that is never used: "gameModes_Handler" 


[Kailo]

I see you found main problem of first example, incorrect menu handler function

1) You must use Call_* natives to call function by function id. You can't use () operator for this
2) Adding typedef is optional here
3) ByteCountToCells needed if you store strings insde ArrayList like in your first example. Because ArrayList constructor take size param in cell - 64 cells equal 256 bytes, but you use char[64] (64 bytes)
4) Not use array brackets for enum strcut variables if this not array, like you did: "GameMode buffer[64];"
5) Use sizeof to take enum struct size, with structure name or varialbe name, ex.: sizeof(GameMode)
6) Don't close menu handle on Cancel action, only on End action
7) Array have indexes from 0 to size - 1. You must use < comparison agains <= in loops, overwise you will got error with try to [size] access
Use null instead INVALID_HANDLE

You want to make native for addtions of new gamemodes with modules in feature? Or why you use ArrayList? If you already know final count of modes, you can use only common arrays.

I would do like this, ask all things that you don't understand "how it works" in this code:

PHP Code:

#define PLUGIN_NAME           "GameModes"
#define PLUGIN_AUTHOR         "Dakex"
#define PLUGIN_DESCRIPTION    ""
#define PLUGIN_VERSION        "1.1 Epom"
#define PLUGIN_URL            ""

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1

ArrayList gameModes;
ArrayList gameModes_Handler;

enum struct Wrapper 
{
    Function id;
}

char defaultGameModes[] = {"Shooter", "HNS", "Matrix", "COD:MW"};
char defaultGameModes_Handler[] = {"Shooter_Handle", "HNS_Handle", "Matrix_Handle", "CODMW_Handle"};

public Plugin:myinfo =
{
    name = PLUGIN_NAME,
    author = PLUGIN_AUTHOR,
    description = PLUGIN_DESCRIPTION,
    version = PLUGIN_VERSION,
    url = PLUGIN_URL
};

public OnPluginStart()
{
    gameModes = new ArrayList(ByteCountToCells(64));
    gameModes_Handler = new ArrayList(sizeof(Wrapper));

    LoadDefaultGameModes();

    RegConsoleCmd("gamemod", GameModeMenu, "turns on any gamemode!");
}
public void LoadDefaultGameModes() 
{
    Wrapper func;

    for(int i = 0; i < sizeof(defaultGameModes); i++)
    {
        gameModes.PushString(defaultGameModes[i]);
        func.id = GetFunctionByName(null, defaultGameModes_Handler[i]);
        gameModes_Handler.PushArray(func);
    }
}
public Action GameModeMenu(int client, int args)
{
    Menu gameModeMenu = new Menu(GameModeMenu_Handler);
    char buffer[64];

    gameModeMenu.SetTitle("Game Modes");

    for(int i = 0, size = gameModes.Length; i < size; i++)
    {
        gameModes.GetString(i, buffer, sizeof(buffer));
        gameModeMenu.AddItem("", buffer);
    }
    gameModeMenu.Display(client, 20);

    return Plugin_Handled;
}
public int GameModeMenu_Handler(Menu menu, MenuAction action, int param1, int param2)
{
    if(action == MenuAction_Select)
    {
        Wrapper func;
        gameModes_Handler.GetArray(param2, func);

        Call_StartFunction(null, func.id);
        Call_Finish();
    }
    else if(action == MenuAction_End)
    {
        menu.Close();
    }
}
public Action Shooter_Handle() 
{
    PrintToChatAll("shooter!");
}
public Action HNS_Handle()
{
    PrintToChatAll("hns!");
}
public Action Matrix_Handle()
{
    PrintToChatAll("matrix!");
}
public Action CODMW_Handle()
{
    PrintToChatAll("codmw!");
} 


[Dakex]

Thank you!

You want to make native for addtions of new gamemodes with modules in feature? Or why you use ArrayList? If you already know final count of modes, you can use only common arrays.

Yes, that's right.

[Dakex]

Bump, it's not working.
The menu says: Shooter
hooter
ooter
and only the first one works.

[Bacardi]

Aaa.... string array?

char*defaultGameModes_Handler[][]*=*{"Shooter_Handle",*"HNS_Handle",*"Matrix_Handle",*"CODMW_Handle"};
char*defaultGameModes[][]*=*{"Shooter",*"HNS",*"Matrix",*"COD:MW"};

*edit
Okey, my copy/paste code got broken. But you get a idea.

[StrikeR14]

PHP Code:

char defaultGameModes[] = {"Shooter", "HNS", "Matrix", "COD:MW"};
char defaultGameModes_Handler[] = {"Shooter_Handle", "HNS_Handle", "Matrix_Handle", "CODMW_Handle"}; 


To

PHP Code:

char defaultGameModes[][] = {"Shooter", "HNS", "Matrix", "COD:MW"};
char defaultGameModes_Handler[][] = {"Shooter_Handle", "HNS_Handle", "Matrix_Handle", "CODMW_Handle"}; 


An array of chars is a string, and an array of an array of chars simply means an array of strings.

[Dakex]

Thank you both! Now it is working as expected.

But I still have lot to go trough unfortunately. I need to find a way, how to save Plugin handle, which is required to call the function.

[Kailo]

Originally Posted by Dakex Thank you both! Now it is working as expected. But I still have lot to go trough unfortunately. I need to find a way, how to save Plugin handle, which is required to call the function.

PHP Code:

enum struct GameMode
{
    Handle plugin;
    Function id;
}