[CrazY.]

Hey, I need a stock to freeze/unfreeze a player but don't freeze he camera. Anyone ?

[Natsheh]

Set his speed to zero hook pre primary & secondary attack, set his next primary & second attack delay to get_gametime + 99999 then return max value

Or use set_pev(id, pev_flags, pev(id, pev_flags)|FL_FROZEN)

[CrazY.]

Trying...

[edon1337]

set_user_frozen( id, bool:bFrozen ) {

    if( bFrozen ) 
    set_pev( id, pev_flags, pev( id, pev_flags ) | FL_FROZEN ) ;

    set_pev( id, pev_flags, pev( id, pev_flags ) & ~ FL_FROZEN ) ;
}

set_user_frozen( id, true ) // freeze
set_user_frozen( id, false ) // unfreeze 

[HamletEagle]

While passing 1/0 will work, you should just use true/false since bFrozen is tagged as bool(to be consistent).

[CrazY.]

Well, the frozen work, but this stock is blocking to move the camera. I think I need do something like of natahe have said.

[sirerick]

example:

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <engine>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"

#if AMXX_VERSION_NUM < 183
new Ham:Ham_Player_ResetMaxSpeed = Ham_Item_PreFrame
#endif

new g_frozen[33]

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_Player_ResetMaxSpeed, "player", "fw_Player_ResetMaxSpeed", 1)
    register_forward(FM_CmdStart, "fw_Start")
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1)

    // Add your code here...
}
public client_putinserver(id)
{
    g_frozen[id] = false
}
public fw_PlayerSpawn_Post(id)
{
    // Not alive or didn't join a team yet
    if(!is_user_alive(id))
        return;
        
    set_task(5.0, "block_speed", id)
    
}
public block_speed(id)
{
    if(!is_user_alive(id))
        return;

    
    g_frozen[id] = true
    ExecuteHamB(Ham_Player_ResetMaxSpeed, id)
}
public fw_Player_ResetMaxSpeed(id)
{
    if(!is_user_alive(id))
        return;

    new Float:current_maxspeed
    pev(id, pev_maxspeed, current_maxspeed)
    
    if (g_frozen[id])
    {
        set_pev( id, pev_maxspeed, 1.0 )
        entity_set_vector(id, EV_VEC_velocity, Float:{0.0,0.0,0.0})
    }
}
public fw_Start(id, uc_handle, seed)
{
    static button ; button = get_uc ( uc_handle, UC_Buttons )
    static oldbutton ; oldbutton = entity_get_int ( id, EV_INT_oldbuttons )

    if(!is_user_alive(id))
        return
        
    if (g_frozen[id])
    {
        if(button & IN_ATTACK || button & IN_ATTACK2)
        {
            set_uc(uc_handle,UC_Buttons,(button & ~IN_ATTACK) & ~IN_ATTACK2)
        }
        else if( !(oldbutton & IN_JUMP) )
        {
            entity_set_int(id, EV_INT_oldbuttons, oldbutton | IN_JUMP)
        }
    }
} 


[CrazY.]

Well, with some modifications, thats work.

Thanks, solved.

[Natsheh]

here try this ...

PHP Code:


#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN "Freeze"
#define VERSION "1.0"
#define AUTHOR "Natsheh"

new user_frozen;

#define set_user_frozen(%1)    (user_frozen |= (1<<(%1-1)))
#define remove_user_frozen(%1)    (user_frozen &= ~(1<<(%1-1)))
#define check_user_frozen(%1)    (user_frozen & (1<<(%1-1)))

#define    m_flNextPrimaryAttack    46
#define    m_flNextSecondaryAttack    47
#define       m_pPlayer   41


public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    for(new i = CSW_P228, sWpnname[32]; i <= CSW_P90; i++)
    {
        get_weaponname(i, sWpnname, charsmax(sWpnname))
        if(strlen(sWpnname) <= 7) continue;
        
        RegisterHam(Ham_Item_Drop, sWpnname, "fw_weapon_drop_pre")
        RegisterHam(Ham_CS_Item_CanDrop, sWpnname, "fw_weapon_drop_pre")
        RegisterHam(Ham_Item_Deploy, sWpnname, "fw_weapon_deploy_post",1)
        RegisterHam(Ham_CS_Item_GetMaxSpeed, sWpnname, "fw_weapon_maxspeed_pre")
    }
    
    register_clcmd("say /freeze", "clcmd_freeze")
}

public clcmd_freeze(id)
{
    freeze_player(id, check_user_frozen(id) ? false:true);
    client_print(id, print_center, "* %sFrozen *", (check_user_frozen(id) ? "":"un"))
}

public fw_weapon_maxspeed_pre(const wpn)
{
    if(check_user_frozen(get_pdata_cbase(wpn,m_pPlayer,4)))
    {
        SetHamReturnFloat(-1.0)
        return HAM_SUPERCEDE;
    }
    
    return HAM_IGNORED;
}

public fw_weapon_drop_pre(const wpn)
{
    if(check_user_frozen(get_pdata_cbase(wpn,m_pPlayer,4)))
    {
        set_pdata_float(wpn,m_flNextPrimaryAttack,0.0,4)
        set_pdata_float(wpn,m_flNextSecondaryAttack,0.0,4)
    }
}

public fw_weapon_deploy_post(const wpn)
{
    if(check_user_frozen(get_pdata_cbase(wpn,m_pPlayer,4)))
    {
        static Float:gtime; gtime = get_gametime();
        set_pdata_float(wpn,m_flNextPrimaryAttack,gtime + 999.0,4)
        set_pdata_float(wpn,m_flNextSecondaryAttack,gtime + 999.0,4)
    }
}

freeze_player(id, bool:bFreeze=false)
{
    if(!bFreeze)
    {
        remove_user_frozen(id)
        
        new wpns[32], wnum, sWpnname[24], wpn;
        get_user_weapons(id, wpns, wnum)
        
        for(new i = 0; i < wnum; i++)
        {
            get_weaponname(wpns[i], sWpnname, charsmax(sWpnname))
            
            if((wpn = fm_find_ent_byowner(id, sWpnname)) > -1)
            {
                set_pdata_float(wpn,m_flNextPrimaryAttack,0.0,4)
                set_pdata_float(wpn,m_flNextSecondaryAttack,0.0,4)
            }
        }
        
        set_pev(id, pev_maxspeed, 250.0);
    }
    else
    {
        set_user_frozen(id);
        
        new sWpnname[24], wpn;
        get_weaponname(get_user_weapon(id), sWpnname, charsmax(sWpnname))
        
        if((wpn = fm_find_ent_byowner(id, sWpnname)) > -1) ExecuteHamB(Ham_Item_Deploy, wpn);
        set_pev(id, pev_maxspeed, -1.0)
    }
}

stock fm_find_ent_byowner(id, const wpnname[])
{
    new ent = -1;
    while ( ((ent = engfunc(EngFunc_FindEntityByString, ent, "classname", wpnname)) > 0) && pev(ent, pev_owner) != id) { }
    
    return (pev_valid(ent) && pev(ent,pev_owner) == id) ? ent:-1;
} 


[CrazY.]

I dont need support to weapons, but your code work also. Thanks !