[wazer]

Having an issue, no clue how to fix it.

L 05/25/2017 - 13:28:43: [SM] Exception reported: Invalid convar handle 0 (error 4)
L 05/25/2017 - 13:28:43: [SM] Blaming: kick_bots.smx
L 05/25/2017 - 13:28:43: [SM] Call stack trace:
L 05/25/2017 - 13:28:43: [SM]   [0] GetConVarInt
L 05/25/2017 - 13:28:43: [SM]   [1] Line 24, kick_bots.sp::OnClientPutInServer

I provided compiled and script.

Script by Sylwester posted in this thread

[Peace-Maker]

Move the bot_quota convar lookup into OnPluginStart like this

PHP Code:

public OnPluginStart(){
    g_Cvar_bot_quota = FindConVar("bot_quota");
} 


[wazer]

Originally Posted by Peace-Maker Move the bot_quota convar lookup into OnPluginStart like this PHP Code: public OnPluginStart(){     g_Cvar_bot_quota = FindConVar("bot_quota"); }

Oh I just noticed its you the creator of the scrds auto complete addon, I made an issue to on github the other night ..



So Like this?

PHP Code:

#include <sourcemod>

public Plugin:myinfo = {
    name = "Bot Crash Prevention",
    author = "Sylwester, Peace-Maker",
    description = "prevents server from adding too many bots when players switch teams",
    version = "2.0",
    url = "https://forums.alliedmods.net/showthread.php?t=297839"
}


new Handle:g_Cvar_bot_quota = INVALID_HANDLE;
new g_bot_quota
new g_max_players

public OnPluginStart(){
    g_Cvar_bot_quota = FindConVar("bot_quota");
} 

public OnConfigsExecuted(){
    g_bot_quota = GetConVarInt(g_Cvar_bot_quota);
    g_max_players = GetMaxClients();
}

public OnClientPutInServer(client){
    if(!IsFakeClient(client))
        return;
        
    if(g_bot_quota < GetConVarInt(g_Cvar_bot_quota))
        SetConVarInt(g_Cvar_bot_quota, g_bot_quota);
    
    new i, count;
    for(i = 1; i<=g_max_players; i++)
        if(IsClientInGame(i) && GetClientTeam(i)>1)
            count++;
            
    if(count<=g_bot_quota)
        return;
    
    new String:name[32]
    if(!GetClientName(client, name, 31))
        return;
    ServerCommand("bot_kick %s", name);
} 


[Peace-Maker]

Yes. You could remove the g_max_players variable too and replace it with the built in MaxClients variable.

[wazer]

Originally Posted by Peace-Maker Yes. You could remove the g_max_players variable too and replace it with the built in MaxClients variable.

I dont know how to ;D

[fiction]

Originally Posted by wazer I dont know how to ;D

Spoiler

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>

int g_iBotQuota;
ConVar g_cvBotQuota;

public Plugin myinfo = {
    name = "Bot Crash Prevention",
    author = "Sylwester, Peace-Maker",
    description = "Prevents addition of too many bots during team switches.",
    version = "2.0",
    url = "https://forums.alliedmods.net/showthread.php?t=297839"
};

public void OnPluginStart()
{
    g_cvBotQuota = FindConVar("bot_quota");
} 

public void OnConfigsExecuted()
{
    g_iBotQuota = g_cvBotQuota.IntValue;
}

public void OnClientPutInServer(int client)
{
    if(!IsFakeClient(client))
        return;
        
    if(g_cvBotQuota.IntValue > g_iBotQuota)
        g_cvBotQuota.SetInt(g_iBotQuota);
    
    int iPlayers;
    for(int i = 1; i <= MaxClients; i++)
        if(IsClientInGame(i) && GetClientTeam(i) > 1)
            iPlayers++;
            
    if(iPlayers <= g_iBotQuota)
        return;
    
    char sName[32];
    if(!GetClientName(client, sName, sizeof(sName)))
        return;

    ServerCommand("bot_kick %s", sName);
} 


[wazer]

Originally Posted by fiction Spoiler PHP Code: #pragma semicolon 1 #pragma newdecls required #include <sourcemod> int g_iBotQuota; ConVar g_cvBotQuota; public Plugin myinfo = {     name = "Bot Crash Prevention",     author = "Sylwester, Peace-Maker",     description = "Prevents addition of too many bots during team switches.",     version = "2.0",     url = "https://forums.alliedmods.net/showthread.php?t=297839" }; public void OnPluginStart() {     g_cvBotQuota = FindConVar("bot_quota"); }  public void OnConfigsExecuted() {     g_iBotQuota = g_cvBotQuota.IntValue; } public void OnClientPutInServer(int client) {     if(!IsFakeClient(client))         return;              if(g_cvBotQuota.IntValue > g_iBotQuota)         g_cvBotQuota.SetInt(g_iBotQuota);          int iPlayers;     for(int i = 1; i <= MaxClients; i++)         if(IsClientInGame(i) && GetClientTeam(i) > 1)             iPlayers++;                  if(iPlayers <= g_iBotQuota)         return;          char sName[32];     if(!GetClientName(client, sName, sizeof(sName)))         return;     ServerCommand("bot_kick %s", sName); }

Thanks will test :=)