[claudiuhks]

Can I reproduce somehow with a SourceMod plug-in the centered message "MATCH WILL RESTART IN %"?

Minute 10:49

[ecca]

ESEA emitts center messages from their client, not possible with sourcemod.

The "match restarting in" you see on the screen here is from command mp_restartgame x where x is number of seconds before restart is triggered, the game itself shows that countdown. Also the message triggered by this command isn't editable without changing gamefiles i think.

[Wilczek]

You mean the top or the bottom message?

If the latter, it's pretty easy:

PHP Code:

for (new i = 1; i <= MaxClients; i++)
{
   if(IsClientInGame(i) && !IsFakeClient(i))
       PrintCenterText(i, "%t", "String");
} 


[Powerlord]

Originally Posted by ecca The "match restarting in" you see on the screen here is from command mp_restartgame x where x is number of seconds before restart is triggered, the game itself shows that countdown. Also the message triggered by this command isn't editable without changing gamefiles i think.

It may just be a TextMsg usermessage, which has an option for center text.

Granted, you'd need to know which translation phrase it is.

[Dr. Api]

I saw a hunger game server with a message a the top and this message was shaking and changing color too.
Usermessage should do the trick.

[claudiuhks]

Originally Posted by Wilczek You mean the top or the bottom message? If the latter, it's pretty easy: PHP Code: for (new i = 1; i <= MaxClients; i++) {    if(IsClientInGame(i) && !IsFakeClient(i))        PrintCenterText(i, "%t", "String"); }

This will print a hint-text message.

Originally Posted by Powerlord It may just be a TextMsg usermessage, which has an option for center text. Granted, you'd need to know which translation phrase it is.

Can you give me an example of how I can call that function?

[Powerlord]

Originally Posted by claudiuhks Can you give me an example of how I can call that function?

I don't know if this is valid for CS:GO, but for TF2... say I wanted to print that a player had been autobalanced to the other team.

	decl String:name[MAX_NAME_LENGTH+1];
	GetClientName(client, name, sizeof(name));
	
	PrintValveTranslationToAll(HUD_PRINTTALK, "#game_player_was_team_balanced", name);

In this case, HUD_PRINTTALK was the destination (chat), "#game_player_was_team_balanced" is the name of the translation string in TF2 prefixed with a #, and name is the first argument to that translation string.

If you pass in a translation string, it will need # in front of it... you can even use a translation string as an argument, such as in this next example:

		new String:streakString[4];
		GetConVarString(g_Cvar_Arena_Streak, streakString, sizeof(streakString));
		
		new String:teamName[4];
		if (winningTeam == _:TFTeam_Red)
		{
			teamName = "#TF_RedTeam_Name";
		}
		else if (winningTeam == _:TFTeam_Blue)
		{
			teamName = "#TF_BlueTeam_Name";
		}
		
		PrintValveTranslationToAll(HUD_PRINTTALK, "#TF_Arena_MaxStreak", teamName, streakString);

In this case, HUD_PRINTTALK is the destination, "#TF_Arena_MaxStreak" is the translation string prefixed with a #, teamName is the first argument to TF_Arena_MaxStreak and is ALSO a translation string prefixed with a #, and streakString is the second argument.

(winningTeam really should be a TFTeam value but is actually an int. One day I'll fix this in the plugin's next version.)

[Franc1sco]

Originally Posted by Powerlord It may just be a TextMsg usermessage, which has an option for center text. Granted, you'd need to know which translation phrase it is.

I found this

		////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
		//Notice Text
		////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


		"SFUI_Notice_Alert_Match_Point"					"MATCH POINT"
		"SFUI_Notice_Alert_Final_Round"					"FINAL ROUND"
		"SFUI_Notice_Alert_Last_Round_Half"				"LAST ROUND OF FIRST HALF"
		"SFUI_Notice_Alert_Warmup_Period"				"WARMUP %s1"
		"SFUI_Notice_Alert_Warmup_Period_Ending"		"WARMUP ENDING %s1"
		"SFUI_Notice_Alert_Waiting_For_Players"			"WAITING FOR PLAYERS %s1"
		"SFUI_Notice_Alert_Match_Starting_In"			"<font color='#C6E075'>MATCH STARTING IN %s1...</font>"
		"SFUI_Notice_Alert_Match_Starting"			"<font color='#C6E075'>MATCH STARTING</font>"
		"SFUI_Notice_Alert_Match_Restarting_In"			"<font color='#C6E075'>MATCH RESTARTING IN %s1...</font>"
		"SFUI_Notice_Alert_Match_Restarting"			"<font color='#C6E075'>MATCH RESTARTING</font>"
		"SFUI_Notice_Alert_Match_Start"					"MATCH START"
		"SFUI_Notice_Alert_Freeze_Pause"				"MATCH PAUSED"

Seems that is called "Notice Text"


I am testing it. Test code:

PHP Code:

#include <sourcemod>

#define HUD_PRINTNOTIFY        1
#define HUD_PRINTCONSOLE    2
#define HUD_PRINTTALK        3
#define HUD_PRINTCENTER        4

public OnPluginStart()
{
    RegConsoleCmd("sm_testa", Testa);
}

public Action:Testa(client, args)
{
    PrintValveTranslationToOne(client, HUD_PRINTTALK, "#SFUI_Notice_Alert_Match_Restarting");
}

// Print a Valve translation phrase to a group of players
// Adapted from util.h's UTIL_PrintToClientFilter
stock PrintValveTranslation(clients[],
                            numClients,
                            msg_dest,
                            const String:msg_name[],
                            const String:param1[]="",
                            const String:param2[]="",
                            const String:param3[]="",
                            const String:param4[]="")
{
    new Handle:bf = StartMessage("TextMsg", clients, numClients, USERMSG_RELIABLE);
    
    if (GetUserMessageType() == UM_Protobuf)
    {
        PbSetInt(bf, "msg_dest", msg_dest);
        PbAddString(bf, "params", msg_name);
        
        PbAddString(bf, "params", param1);
        PbAddString(bf, "params", param2);
        PbAddString(bf, "params", param3);
        PbAddString(bf, "params", param4);
    }
    else
    {
        BfWriteByte(bf, msg_dest);
        BfWriteString(bf, msg_name);
        
        BfWriteString(bf, param1);
        BfWriteString(bf, param2);
        BfWriteString(bf, param3);
        BfWriteString(bf, param4);
    }
    
    EndMessage();
}  

stock PrintValveTranslationToAll(msg_dest,
                                const String:msg_name[],
                                const String:param1[]="",
                                const String:param2[]="",
                                const String:param3[]="",
                                const String:param4[]="")
{
    new total = 0;
    new clients[MaxClients];
    for (new i=1; i<=MaxClients; i++)
    {
        if (IsClientConnected(i))
        {
            clients[total++] = i;
        }
    }
    PrintValveTranslation(clients, total, msg_dest, msg_name, param1, param2, param3, param4);
}

stock PrintValveTranslationToOne(client,
                                msg_dest,
                                const String:msg_name[],
                                const String:param1[]="",
                                const String:param2[]="",
                                const String:param3[]="",
                                const String:param4[]="")
{
    new players[1];
    
    players[0] = client;
    
    PrintValveTranslation(players, 1, msg_dest, msg_name, param1, param2, param3, param4);
} 


Log error and server crash:

L 07/29/2015 - 07:20:11: [SM] Native "PbSetInt" reported: Invalid field "msg_dest" for message "CCSUsrMsg_TextMsg"
L 07/29/2015 - 07:20:11: [SM] Displaying call stack trace for plugin "alert_test.smx":
L 07/29/2015 - 07:20:11: [SM]   [0]  Line 33, alert_test.sp::PrintValveTranslation()
L 07/29/2015 - 07:20:11: [SM]   [1]  Line 86, alert_test.sp::PrintValveTranslationToOne()
L 07/29/2015 - 07:20:11: [SM]   [2]  Line 15, alert_test.sp::Testa()
L 07/29/2015 - 07:20:13: [SM] Native "PrintToChat" reported: Could not send a usermessage

I also tried with

new Handle:bf = StartMessage("NoticeText", players, 1, USERMSG_RELIABLE);

Seems to not exist:

L 07/29/2015 - 07:35:29: [SM] Native "StartMessage" reported: Invalid message name: "NoticeText"
L 07/29/2015 - 07:35:29: [SM] Displaying call stack trace for plugin "alert_test.smx":
L 07/29/2015 - 07:35:29: [SM]   [0]  Line 18, alert_test.sp::Testa()

I will continue testing it

[claudiuhks]

L 07/29/2015 - 07:20:11: [SM] Native "PbSetInt" reported: Invalid field "msg_dest" for message "CCSUsrMsg_TextMsg"

It probably means that msg_dest is not a valid field for CSGO's TextMsg message.
Try not to use PbSetInt(..., "msg_dest", ...) anymore. We must figure it out somehow, about what fields we need for CSGO's TextMsg message.

[Powerlord]

Whoops, it's "msg_dst" instead of msg_dest in CS:GO.

Probably a typo from when I originally wrote it.