[EpicMonkey]

thats not what am trying to do ...

[Devil259]

http://forums.alliedmods.net/showthread.php?p=11751

[fysiks]

You need to store both day and number of slaps for each player. Then, when they enter the server check to see if the day stored is today. If it is today, load the number of slaps in the global array that counts slaps. If it is not today then enter 0 for the slap count.

Simple as that.

[EpicMonkey]

Originally Posted by fysiks You need to store both day and number of slaps for each player. Then, when they enter the server check to see if the day stored is today. If it is today, load the number of slaps in the global array that counts slaps. If it is not today then enter 0 for the slap count. Simple as that.

hmm so , When player connects , Check if the day is different, if it is then store todays date and remove the previous one and give the player x number of slaps , right?

[Exolent[jNr]]

#include <amxmodx>
#include <nvault>

new gVault;

public plugin_init() {
    gVault = nvault_open("daily_slaps");
    
    // get current timestamp
    new now = get_systime();
    
    // subtract all time of hours, minutes, and seconds such that the day just started
    new hour, minute, second;
    time(hour, minute, second);
    new day_start = now - ((hour * 3600) + (minute * 60) + second);
    
    // remove all vault entries before today
    nvault_prune(gVault, 0, day_start);
    
    // set task to prune again for next day start, in case plugin is running across midnight
    new next_day = day_start + 86400;
    set_task(float(next_day - now), "TaskPruneVault");
}

public TaskPruneVault() {
    // prune vault since day is changing right now
    nvault_prune(gVault, 0, get_systime() + 1);
    
    // set task to execute again next day
    set_task(86400.0, "TaskPruneVault");
}

public plugin_end() {
    nvault_close(gVault);
}

GetSlaps(id) {
    new steamID[35];
    get_user_authid(id, steamID, charsmax(steamID));
    
    return nvault_get(gVault, steamID);
}

SetSlaps(id, slaps) {
    new steamID[35];
    get_user_authid(id, steamID, charsmax(steamID));
    
    new value[12];
    num_to_str(slaps, value, charsmax(value));
    
    nvault_set(gVault, steamID, value);
}

Then your slap function would look like this:

public CmdSlap(id, level, cid) {
    // check access, args, grab target, etc.
    
    new slaps = GetSlaps(id);
    if(slaps >= /* max slaps per day */) {
        // you cannot slap anymore!
        return PLUGIN_HANDLED;
    }
    
    // update slaps
    SetSlaps(id, slaps + 1);
    
    // rest of command code...
}

[EpicMonkey]

very interesting , i like what you did with the pruning function , had a problem with the date thing , and the way of saving with nvault is just amazing ... , thanks a bunch for showing me how to do it