[bebe9b]

Hi,
I have update last verion sourcemod and include files but compile erorr:
compile\addons\sourcemod\scripting\SendToSpec .sp (16) : erorr 147: new-style declarations are required

Thx,

[Cruze]

PHP Code:

#pragma newdecls required 
#pragma semicolon 1

#include <sourcemod> 
#include <sdktools> 
#include <cstrike> 

public Plugin myinfo =  
{ 
    name = "Send player to spec", 
    author = "Arkarr", 
    description = "A simple spectator manager.", 
    version = "1.0", 
    url = "http://www.sourcemod.net" 
}; 

public void OnPluginStart() 
{ 
    RegConsoleCmd("sm_spec", Command_Spectator, "Send player to spec team."); 
    RegConsoleCmd("sm_afk", Command_Spectator, "Send player to spec team."); 
    RegAdminCmd("sm_fspec", ForceSendPlayerAFK, ADMFLAG_GENERIC, "sage: sm_fspec <#userid|name>"); 
     
    LoadTranslations("common.phrases"); 
} 

public Action Command_Spectator(int client, int args) 
{ 
    if (client) // commands can be executed by Console (client == 0) 
    { 
        SendPlayerToSpectators(client); 
    } 
     
    return Plugin_Handled; 
} 

public Action ForceSendPlayerAFK(int client, int args) 
{ 
    if (args < 1) 
    { 
        ReplyToCommand(client, "[SM] Usage: sm_fspec <#userid|name>"); 
        return Plugin_Handled; 
    } 
     
    char arg[MAX_TARGET_LENGTH]; 
    GetCmdArg(1, arg, sizeof(arg)); 
     
    char target_name[MAX_TARGET_LENGTH]; 
    int target_list[MAXPLAYERS], target_count; 
    bool tn_is_ml; 
     
    if ((target_count = ProcessTargetString( 
            arg, 
            client,  
            target_list,  
            MAXPLAYERS,  
            COMMAND_FILTER_CONNECTED, 
            target_name, 
            sizeof(target_name), 
            tn_is_ml)) > 0) 
    { 
        for (int i = 0; i < target_count; i++) 
        { 
            SendPlayerToSpectators(target_list[i]); 
        } 
    } 
    else 
    { 
        ReplyToTargetError(client, target_count); 
    } 
     
    return Plugin_Handled; 
} 

void SendPlayerToSpectators(int client) 
{ 
    if (GetClientTeam(client) != CS_TEAM_SPECTATOR) 
    { 
        if (IsPlayerAlive(client)) 
        { 
            ForcePlayerSuicide(client); 
        } 
         
        ChangeClientTeam(client, CS_TEAM_SPECTATOR); 
    } 
} 


[bebe9b]

Hi,
Thx man , compile plugin.

[Razvann.]

Can u add another function (I think is very cool), cvar to check if he stay more then ~5 minutes to kick him from Spec (I know there are similar plugin to do this but are outdated... many errors)?

[bebe9b]

Hi,
Please, if possible change the plugin :
Disable comand playeri if there are less than 12 players on the server.
sm_spec, Command_Spectator, "Send player to spec team.");
sm_afk, Command_Spectator, "Send player to spec team.");

When there are less than 12 players on the server and someone wants to use the commands! afk and !spec chat message appears.
You can not use the command yet

Thx,

[Cruze]

Originally Posted by bebe9b Hi, Please, if possible change the plugin : Disable comand playeri if there are less than 12 players on the server. sm_spec, Command_Spectator, "Send player to spec team."); sm_afk, Command_Spectator, "Send player to spec team."); When there are less than 12 players on the server and someone wants to use the commands! afk and !spec chat message appears. You can not use the command yet Thx,

PHP Code:

#pragma newdecls required 
#pragma semicolon 1

#include <sourcemod> 
#include <sdktools> 
#include <cstrike> 

public Plugin myinfo =  
{ 
    name = "Send player to spec", 
    author = "Arkarr", 
    description = "A simple spectator manager.", 
    version = "1.0", 
    url = "http://www.sourcemod.net" 
}; 

public void OnPluginStart() 
{ 
    RegConsoleCmd("sm_spec", Command_Spectator, "Send player to spec team."); 
    RegConsoleCmd("sm_afk", Command_Spectator, "Send player to spec team."); 
    RegAdminCmd("sm_fspec", ForceSendPlayerAFK, ADMFLAG_GENERIC, "sage: sm_fspec <#userid|name>"); 
     
    LoadTranslations("common.phrases"); 
} 

public Action Command_Spectator(int client, int args) 
{ 
    if (client) // commands can be executed by Console (client == 0) 
    { 
        if(GetClientCount() >= 12)
        {
            SendPlayerToSpectators(client);
        }
        else
        {
            PrintToChat(client, "[SM] You cannot use the command yet.");
        }
    } 
    return Plugin_Handled; 
} 

public Action ForceSendPlayerAFK(int client, int args) 
{ 
    if (args < 1) 
    { 
        ReplyToCommand(client, "[SM] Usage: sm_fspec <#userid|name>"); 
        return Plugin_Handled; 
    } 
     
    char arg[MAX_TARGET_LENGTH]; 
    GetCmdArg(1, arg, sizeof(arg)); 
     
    char target_name[MAX_TARGET_LENGTH]; 
    int target_list[MAXPLAYERS], target_count; 
    bool tn_is_ml; 
     
    if ((target_count = ProcessTargetString( 
            arg, 
            client,  
            target_list,  
            MAXPLAYERS,  
            COMMAND_FILTER_CONNECTED, 
            target_name, 
            sizeof(target_name), 
            tn_is_ml)) > 0) 
    { 
        for (int i = 0; i < target_count; i++) 
        { 
            SendPlayerToSpectators(target_list[i]); 
        } 
    } 
    else 
    { 
        ReplyToTargetError(client, target_count); 
    } 
     
    return Plugin_Handled; 
} 

void SendPlayerToSpectators(int client) 
{ 
    if (GetClientTeam(client) != CS_TEAM_SPECTATOR) 
    { 
        if (IsPlayerAlive(client)) 
        { 
            ForcePlayerSuicide(client); 
        } 
         
        ChangeClientTeam(client, CS_TEAM_SPECTATOR); 
    } 
} 


[Arkarr]

Originally Posted by Razvann. Can u add another function (I think is very cool), cvar to check if he stay more then ~5 minutes to kick him from Spec (I know there are similar plugin to do this but are outdated... many errors)?

Yeah, but like, kick it from the server? Or put it back in a team ?

@Cruze
thanks

[bebe9b]

Thx man

[bebe9b]

Hi,
Pls disable comand !spec.

Thx,

[Arkarr]

Originally Posted by bebe9b Hi, Pls disable comand !spec. Thx,

Remove line :

PHP Code:

RegConsoleCmd("sm_spec", Command_Spectator, "Send player to spec team."); 


And recompile !