[Doc-Holiday]

So I have a question hopefully someone knows this for me.. Btw i am testing and have done some searches... Im lookging at various example and cant find anything on this so...

"Root"
{
     "SomeKey"
     {
          "Unknown Key"     "Value" //I need the key and value
     }
}

I know how to retrieve the section name. But is there anway to loop through and get the names of the keys?

[Despirator]

didn't try myself

PHP Code:

decl String:section[128], String:value[256];
    if (KvGotoFirstSubKey(kv, true))
    {
        do 
        {
            KvSavePosition(kv);
            
            KvGetSectionName(kv, section, sizeof(section));
            PrintToServer("Started looping keys from %s section", section);
            
            if (KvGotoFirstSubKey(kv, false))
            {
                do
                {
                    KvGetSectionName(kv, section, sizeof(section));
                    KvGetString(kv, NULL_STRING, value, sizeof(value));
                    PrintToServer("--> Key: %s | Value: %s", section, value);
                }
                while (KvGotoNextKey(kv, false));
            }
            
            KvGoBack(kv);
        }
        while (KvGotoNextKey(kv, true));
    }
    KvRewind(kv); 


[Despirator]

tested and worked. Full code i've used

PHP Code:

public OnPluginStart()
{
    RegConsoleCmd("sm_test", Command_Test);
}

public Action:Command_Test(client, args)
{
    decl String:buffer[PLATFORM_MAX_PATH];
    BuildPath(Path_SM, buffer, sizeof(buffer), "configs/test.txt");
    
    new Handle:kv = CreateKeyValues("test");
    
    if (!FileToKeyValues(kv, buffer))
    {
        ReplyToCommand(client, "Could not test file: %s", buffer);
        CloseHandle(kv);
        return Plugin_Handled;
    }
    ReplyToCommand(client, "Testing file: %s", buffer);
    
    decl String:section[128], String:value[256];
    if (KvGotoFirstSubKey(kv, true))
    {
        do 
        {
            KvSavePosition(kv);
            
            KvGetSectionName(kv, section, sizeof(section));
            ReplyToCommand(client, "Started looping keys from %s section", section);
            
            if (KvGotoFirstSubKey(kv, false))
            {
                do
                {
                    KvGetSectionName(kv, section, sizeof(section));
                    KvGetString(kv, NULL_STRING, value, sizeof(value));
                    ReplyToCommand(client, "--> Key: %s | Value: %s", section, value);
                }
                while (KvGotoNextKey(kv, false));
            }
            
            KvGoBack(kv);
        }
        while (KvGotoNextKey(kv, true));
    }
    CloseHandle(kv);
    
    ReplyToCommand(client, "Finished testing file: %s", buffer);
    
    return Plugin_Handled;
} 


test.txt structure

PHP Code:

"test"
{
     "SomeKey"
     {
          "Unknown Key"     "Value"
     }
     "SomeKey2"
     {
          "Unknown Key2"     "Value2"
     }
     "SomeKey3"
     {
          "Unknown Key3"     "Value3"
     }
     "SomeKey4"
     {
          "Unknown Key4"     "Value4"
          "Unknown Key5"     "Value5"
          "Unknown Key6"     "Value6"
          "Unknown Key7"     "Value7"
     }
} 


output

Testing file: addons\sourcemod\configs\test.txt
Started looping keys from SomeKey section
--> Key: Unknown Key | Value: Value
Started looping keys from SomeKey2 section
--> Key: Unknown Key2 | Value: Value2
Started looping keys from SomeKey3 section
--> Key: Unknown Key3 | Value: Value3
Started looping keys from SomeKey4 section
--> Key: Unknown Key4 | Value: Value4
--> Key: Unknown Key5 | Value: Value5
--> Key: Unknown Key6 | Value: Value6
--> Key: Unknown Key7 | Value: Value7
Finished testing file: addons\sourcemod\configs\test.txt

[Bacardi]

textparse

output

NewSection "Root"
NewSection "SomeKey"
KeyValue "Unknown Key" "Value"

SMC

PHP Code:

public OnPluginStart()
{
    RegConsoleCmd("sm_test", test);
}

public Action:test(client, args)
{
    new Handle:smc = SMC_CreateParser();
    SMC_SetReaders(smc, NewSection, KeyValue, EndSection);
    new SMCError:error = SMC_ParseFile(smc, "myfile.txt");

    if(error != SMCError_Okay)
    {
        new String:buffer[255];
        if(SMC_GetErrorString(error, buffer, sizeof(buffer)))
        {
            LogError("%s", buffer);
        }
    }
 
    CloseHandle(smc);
    return Plugin_Handled;
}

public SMC_ParseStart(Handle:smc){
}

public SMCResult:NewSection(Handle:smc, const String:name[], bool:opt_quotes){
    PrintToServer("NewSection \"%s\"", name);
}

public SMCResult:KeyValue(Handle:smc, const String:key[], const String:value[], bool:key_quotes, bool:value_quotes){
    PrintToServer("KeyValue \"%s\" \"%s\"", key, value);
}

public SMCResult:EndSection(Handle:smc){
} 


[Doc-Holiday]

Very nice guys Thanks for the replies