[RockTheStreet]

Hi.

Ladies and gentlemen, can you tell me how to catch an antach by a player to the essence?
Through register_touch I detect touch. It is also necessary to catch the untouch.

[Natsheh]

If you rethink about it you will find it is not possible and the term untouching an entity doesn't exist...

[RockTheStreet]

Originally Posted by Natsheh If you rethink about it you will find it is not possible and the term untouching an entity doesn't exist...

Let's go from the other side.

Is there a function to check whether the player is touching the entity or not? So that the condition can check whether the player is in contact with the entity or not.

[lexzor]

register_touch

to detect when it's not touching anymore, hook the think of player entity when touching and check if it's in touched entity area using find_entity_in_sphere

[Natsheh]

Originally Posted by RockTheStreet Let's go from the other side. Is there a function to check whether the player is touching the entity or not? So that the condition can check whether the player is in contact with the entity or not.

If you want to check if a certain player is not colliding with an entity simply check the player size if it is colliding with entity size...

You can do it in player prethink

PHP Code:


............

static Float:fOrigin1[3], Float:fOrigin2[3], Float:fMaxs1[3], Float:fMins1[3], Float:fMaxs2[3], Float:fMins2[3];
pev(id, pev_origin, fOrigin1);
pev(id, pev_maxs, fMaxs1);
pev(id, pev_mins, fMins1);

xs_vec_add(fMaxs1, fOrigin1, fMaxs1);
xs_vec_add(fMins1, fOrigin1, fMins1);

pev(g_entity, pev_origin, fOrigin2);
pev(g_entity, pev_maxs, fMaxs2);
pev(g_entity, pev_mins, fMins2);

xs_vec_add(fMaxs2, fOrigin2, fMaxs2);
xs_vec_add(fMins2, fOrigin2, fMins2);

if(!BoundsIntersect(fMins1, fMaxs1, fMins2, fMaxs2))
{
   // Entities do not collide or touch!
}

...........

bool:BoundsIntersect(const  Float:mins1[3], const  Float:maxs1[3], const  Float:mins2[3], const Float:maxs2[3])
{
    if (mins1[0] > maxs2[0] || mins1[1] > maxs2[1] || mins1[2] > maxs2[2])
        return false;
    if (maxs1[0] < mins2[0] || maxs1[1] < mins2[1] || maxs1[2] < mins2[2])
        return false;
    return true;
} 


[RockTheStreet]

Originally Posted by Natsheh If you want to check if a certain player is not colliding with an entity simply check the player size if it is colliding with entity size... You can do it in player prethink PHP Code: ............ static Float:fOrigin1[3], Float:fOrigin2[3], Float:fMaxs1[3], Float:fMins1[3], Float:fMaxs2[3], Float:fMins2[3]; pev(id, pev_origin, fOrigin1); pev(id, pev_maxs, fMaxs1); pev(id, pev_mins, fMins1); xs_vec_add(fMaxs1, fOrigin1, fMaxs1); xs_vec_add(fMins1, fOrigin1, fMins1); pev(g_entity, pev_origin, fOrigin2); pev(g_entity, pev_maxs, fMaxs2); pev(g_entity, pev_mins, fMins2); xs_vec_add(fMaxs2, fOrigin2, fMaxs2); xs_vec_add(fMins2, fOrigin2, fMins2); if(!BoundsIntersect(fMins1, fMaxs1, fMins2, fMaxs2)) {    // Entities do not collide or touch! } ........... bool:BoundsIntersect(const  Float:mins1[3], const  Float:maxs1[3], const  Float:mins2[3], const Float:maxs2[3]) {     if (mins1[0] > maxs2[0] || mins1[1] > maxs2[1] || mins1[2] > maxs2[2])         return false;     if (maxs1[0] < mins2[0] || maxs1[1] < mins2[1] || maxs1[2] < mins2[2])         return false;     return true; }

I like this option better.
Thanks, I'll try.

[JusTGo]

It's possible, in register_touch use set_task with 0.1 or for more accuracy do RequestFrame and in the callback check if the player is still touching the entity.

[Bugsy]

I got this to work between 2 player entities

PHP Code:


#include <amxmodx>
#include <engine>

new g_TouchedEnts[ MAX_PLAYERS + 1 ][ 2 ][ 32 ];

#define SetBit(%1,%2)    (%1[%2>>5] |= (1<<(%2 & 31)))

public plugin_init() 
{
    register_touch( "player" , "player" , "PlayerTouched" );
    
    set_task( 0.5 , "CheckBits" , .flags="b" );
}

public PlayerTouched( iTouched , iToucher )
{
    SetBit( g_TouchedEnts[ iToucher ][ 0 ] , iTouched );
}

public CheckBits()
{
    static szName1[ 32 ] , szName2[ 32 ];
    
    for ( new i = 1 ; i <= MAX_PLAYERS ; i++ )
    {
        if ( !is_user_connected( i ) ) continue;
        
        for ( new p = 0 ; p < sizeof( g_TouchedEnts[][] ) ; p++ )
        {
            for ( new k = 0 ; k < 32 ; k++ )
            {
                if ( !( g_TouchedEnts[ i ][ 0 ][ p ] & ( 1 << k ) ) && ( g_TouchedEnts[ i ][ 1 ][ p ] & ( 1 << k ) ) ) 
                {
                    get_user_name( i , szName1 , charsmax( szName1 ) );
                    get_user_name( k , szName2 , charsmax( szName2 ) );
                    
                    client_print( i , print_chat , "* %s stopped touching %s" , szName1 , szName2 );    
                }
            }
            
            g_TouchedEnts[ i ][ 1 ][ p ] = g_TouchedEnts[ i ][ 0 ][ p ];
            g_TouchedEnts[ i ][ 0 ][ p ] = 0;
        }
    }
}