[raulGLD]

Hello, is there a plugin for CS:GO that can automatically remove a password from a server if the server is empty? For ex some of my friends want to play a game on my server and they set a password on it, but they leave in a hurry and forget to remove the password, if no one is around to remove the password manually the server stays empty.. so I was wondering if there is a plugin to check if there are players on the server and if there are not any players, after 10 minutes for example, the password is removed.
Thank you very much for taking your time to read and answer!
Have a great day!

[CliptonHeist]

Needs sv_hibernate_when_empty 0 or it won't work.

PHP Code:

Handle g_hTimer = null;

public void OnClientDisconnect_Post(int client)
{
    char sPass[64];
    FindConVar("sv_password").GetString(sPass, sizeof(sPass));
    if(StrEqual(sPass, "")) return;

    bool bPlayers = false;
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsValidClient(i))
        {
            bPlayers = true;
            break;
        }
    }

    if(bPlayers) return;

    if(g_hTimer != null)
    {
        delete g_hTimer;
        g_hTimer = null;
    }

    g_hTimer = CreateTimer(600.0, Timer_RemovePassword);
}

public void OnClientPutInServer(int client)
{
    if(IsValidClient(client) && g_hTimer != null)
    {
        delete g_hTimer;
        g_hTimer = null;
    }
}

public Action Timer_RemovePassword(Handle hTimer)
{
    FindConVar("sv_password").SetString("");

    delete g_hTimer;
    g_hTimer = null;
    return Plugin_Stop;
}

stock bool IsValidClient(int client)
{
    return client >= 1 && 
    client <= MaxClients && 
    IsClientConnected(client) && 
    !IsFakeClient(client);
}