[toki]

Hi, I would like that in the part where it shows who you have killed you can count how many frags you have, for example:

"Player +1 💀 Player 2"
"Player +2 💀 Player 3"
"Player +3 💀 Player 4"

And when they kill you, reset the account to zero.

[tarsisd2]

Originally Posted by toki Hi, I would like that in the part where it shows who you have killed you can count how many frags you have, for example: "Player +1 💀 Player 2" "Player +2 💀 Player 3" "Player +3 💀 Player 4" And when they kill you, reset the account to zero.

you mean how many frags he has over the killed player or overall? if it is over the players he killed, i like the idea like

PHP Code:

"PlayerA +5 💀 PlayerB"
"PlayerC +15 💀 PlayerD"
"PlayerE 💀 PlayerF +68" 


showing only the +frags player had in positive, so we dont take much of the characters of nicknames

[toki]

Originally Posted by tarsisd2 you mean how many frags he has over the killed player or overall? if it is over the players he killed, i like the idea like

The idea is that it be in general, but it would not be bad if there is also the option that you can remember the frags that you are doing to "X" player and if the "X" player kills you, your count will be returned to 0.

[toki]

Someone please help me with this request.

[Celena Luna]

Where do you want to show the counter tbh?
When they got kill? Above HP HUD? Right side? or you print in chat?

[toki]

Originally Posted by Celena Luna Where do you want to show the counter tbh? When they got kill? Above HP HUD? Right side? or you print in chat?

Thank you for your response, just like the example in the picture (top right)

[JocAnis]

Hello, can you try this to see if it works? I couldnt test it on my lan so its a little blind try
It should change name of killer to 'his_nick + his_frags_on_map' in the same moment as he kills someone, and after 0.1sec setting back his nickname to what he had while connection on your server:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

new g_msgDeath, g_msgSay
new g_iFrags[ 33 ]
new g_szName[ 33 ][ 32 ], g_szWeapon[ 33 ][ 11 ]

public plugin_init()
{
    register_plugin( "DeathMSG Frags", "1.0", "amxx" )

    g_msgDeath = get_user_msgid( "DeathMsg" )
    g_msgSay =   get_user_msgid( "SayText" )
    register_message( g_msgDeath, "event_dmg" )
    register_message( g_msgSay, "event_saytxt" ) //prevent chat spam of changing nicks
}
public client_putinserver( id )
{
    g_iFrags[ id ] = 0
    g_szWeapon[ id ][ 0 ] = EOS
    get_user_name( id, g_szName[ id ], charsmax( g_szName ) )
}
public event_saytxt( msg_id, msg_dest, msg_entity )
{
    new arg[ 32 ]
    get_msg_arg_string( 2, arg, charsmax( arg ) )

    if( equal( arg, "#Cstrike_Name_Change" ) ) 
        return PLUGIN_HANDLED //prevent chat spam of changing nicks

    return PLUGIN_CONTINUE
}
public event_dmg()
{
    new data[ 4 ]
    data[ 0 ] = get_msg_arg_int( 1 ) //credits to Bugsy
    data[ 1 ] = get_msg_arg_int( 2 )
    data[ 2 ] = get_msg_arg_int( 3 )
    get_msg_arg_string( 4 , g_szWeapon[ data[ 0 ] ], charsmax( g_szWeapon[] ) ) //not so smart part here, but i think it will work properly with set_task

    if( data[ 0 ] == data[ 1 ] )
        return PLUGIN_CONTINUE //do nothing if its suicide..

    g_iFrags[ data[ 0 ] ]++
    static name2[ 32 ]
    formatex( name2, charsmax( name2 ), "%s + %d", g_szName[ data[ 0 ] ], g_iFrags[ data[ 0 ] ] )
    set_user_info( data[ 0 ], "name", name2 )

    set_task( 0.1, "send_info", 0, data, sizeof data )
    return PLUGIN_HANDLED
}
public send_info( data[] )
{
    message_begin( MSG_ALL, g_msgDeath )
    write_byte( data[ 0 ] )
    write_byte( data[ 1 ] )
    write_byte( data[ 2 ] )
    write_string( g_szWeapon[ data[ 0 ] ] )
    message_end()

    set_user_info( data[ 0 ], "name", g_szName[ data[ 0 ] ] )
}

[toki]

Originally Posted by JocAnis Hello, can you try this to see if it works? I couldnt test it on my lan so its a little blind try It should change name of killer to 'his_nick + his_frags_on_map' in the same moment as he kills someone, and after 0.1sec setting back his nickname to what he had while connection on your server: #include <amxmodx> #include <amxmisc> #include <fakemeta> new g_msgDeath, g_msgSay new g_iFrags[ 33 ] new g_szName[ 33 ][ 32 ], g_szWeapon[ 33 ][ 11 ] public plugin_init() { register_plugin( "DeathMSG Frags", "1.0", "amxx" ) g_msgDeath = get_user_msgid( "DeathMsg" ) g_msgSay = get_user_msgid( "SayText" ) register_message( g_msgDeath, "event_dmg" ) register_message( g_msgSay, "event_saytxt" ) //prevent chat spam of changing nicks } public client_putinserver( id ) { g_iFrags[ id ] = 0 g_szWeapon[ id ][ 0 ] = EOS get_user_name( id, g_szName[ id ], charsmax( g_szName ) ) } public event_saytxt( msg_id, msg_dest, msg_entity ) { new arg[ 32 ] get_msg_arg_string( 2, arg, charsmax( arg ) ) if( equal( arg, "#Cstrike_Name_Change" ) ) return PLUGIN_HANDLED //prevent chat spam of changing nicks return PLUGIN_CONTINUE } public event_dmg() { new data[ 4 ] data[ 0 ] = get_msg_arg_int( 1 ) //credits to Bugsy data[ 1 ] = get_msg_arg_int( 2 ) data[ 2 ] = get_msg_arg_int( 3 ) get_msg_arg_string( 4 , g_szWeapon[ data[ 0 ] ], charsmax( g_szWeapon[] ) ) //not so smart part here, but i think it will work properly with set_task if( data[ 0 ] == data[ 1 ] ) return PLUGIN_CONTINUE //do nothing if its suicide.. g_iFrags[ data[ 0 ] ]++ static name2[ 32 ] formatex( name2, charsmax( name2 ), "%s + %d", g_szName[ data[ 0 ] ], g_iFrags[ data[ 0 ] ] ) set_user_info( data[ 0 ], "name", name2 ) set_task( 0.1, "send_info", 0, data, sizeof data ) return PLUGIN_HANDLED } public send_info( data[] ) { message_begin( MSG_ALL, g_msgDeath ) write_byte( data[ 0 ] ) write_byte( data[ 1 ] ) write_byte( data[ 2 ] ) write_string( g_szWeapon[ data[ 0 ] ] ) message_end() set_user_info( data[ 0 ], "name", g_szName[ data[ 0 ] ] ) }

Shows the +1,+2,+3...

The only thing missing would be for the frag count to return to 0 at death, and it occurred to me that at the start of another round it would also return to 0.

[Celena Luna]

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

new g_msgDeath, g_msgSay
new g_iFrags[ 33 ]
new g_szName[ 33 ][ 32 ], g_szWeapon[ 33 ][ 11 ]

public plugin_init()
{
    register_plugin( "DeathMSG Frags", "1.0", "amxx" )

    g_msgDeath = get_user_msgid( "DeathMsg" )
    g_msgSay =   get_user_msgid( "SayText" )
    register_message( g_msgDeath, "event_dmg" )
    register_message( g_msgSay, "event_saytxt" ) //prevent chat spam of changing nicks
    register_event("HLTV", "event_new_round", "a", "1=0", "2=0") 

}
public client_putinserver( id )
{
    g_iFrags[ id ] = 0
    g_szWeapon[ id ][ 0 ] = EOS
    get_user_name( id, g_szName[ id ], charsmax( g_szName ) )
}
public event_saytxt( msg_id, msg_dest, msg_entity )
{
    new arg[ 32 ]
    get_msg_arg_string( 2, arg, charsmax( arg ) )

    if( equal( arg, "#Cstrike_Name_Change" ) ) 
        return PLUGIN_HANDLED //prevent chat spam of changing nicks

    return PLUGIN_CONTINUE
}
public event_dmg()
{
    new data[ 4 ]
    data[ 0 ] = get_msg_arg_int( 1 ) //credits to Bugsy
    data[ 1 ] = get_msg_arg_int( 2 )
    data[ 2 ] = get_msg_arg_int( 3 )
    get_msg_arg_string( 4 , g_szWeapon[ data[ 0 ] ], charsmax( g_szWeapon[] ) ) //not so smart part here, but i think it will work properly with set_task                       

    if( data[ 0 ] == data[ 1 ] )
        return PLUGIN_CONTINUE //do nothing if its suicide..

    g_iFrags[ data[ 0 ] ]++
    g_iFrags[ data[ 1 ] ] = 0 //Reset Victim kill streak
    static name2[ 32 ]
    formatex( name2, charsmax( name2 ), "%s + %d", g_szName[ data[ 0 ] ], g_iFrags[ data[ 0 ] ] )
    set_user_info( data[ 0 ], "name", name2 )

    set_task( 0.1, "send_info", 0, data, sizeof data )
    return PLUGIN_HANDLED
}

public event_new_round()
{
    for(new i=0;i < get_maxplayers();i++)
        g_iFrags[i] = 0
}

public send_info( data[] )
{
    message_begin( MSG_ALL, g_msgDeath )
    write_byte( data[ 0 ] )
    write_byte( data[ 1 ] )
    write_byte( data[ 2 ] )
    write_string( g_szWeapon[ data[ 0 ] ] )
    message_end()

    set_user_info( data[ 0 ], "name", g_szName[ data[ 0 ] ] )
} 


His code is OK already so I just add kill reset and new round reset

[toki]

Working thanks to both of you for helping me just a small detail, I was checking the console and when a user with "flags" makes a frag appears in console "[admin.amxx] Login:" and it makes a huge spam haha ¿is there a way to fix that tiny detail?