[andre neves]

I always use the strip to remove weapons from the player but I was wondering if there a way I can just pull out a gun, or just the primary weapons.

[ConnorMcLeod]

http://forums.alliedmods.net/showthr...47#post1109747

[andre neves]

how do I remove weapons from the number 2?

[ConnorMcLeod]

Try this :

ham_strip_user_weapon_slot(id, 2)

PHP Code:

ham_strip_user_weapon_slot(id, iSlot, bool:bSwitchIfActive = true) 
{
    if( !(1 <= iSlot <= 5) )
    {
        return 0
    }
    const XO_PLAYER = 5
    const m_rgpPlayerItems_Slot0 = 367
    const m_pActiveItem = 373

    const XO_WEAPON = 4
    const m_pNext = 42
    const m_iId = 43

    new iWeapon = get_pdata_cbase(id, m_rgpPlayerItems_Slot0 + iSlot, XO_PLAYER)
    if( iWeapon <= 0 )
    {
        return 0 // no weapon in this slot
    }

    new iId, pNext
    while( iWeapon > 0 )
    {
        pNext = get_pdata_cbase(iWeapon, m_pNext, XO_WEAPON)
        iId = get_pdata_cbase(iWeapon, m_iId, XO_WEAPON)

        if( bSwitchIfActive && pNext <= 0 && get_pdata_cbase(id, m_pActiveItem, XO_PLAYER) == iWeapon )
        {
            ExecuteHamB(Ham_Weapon_RetireWeapon, iWeapon)
        }

        if( ExecuteHamB(Ham_RemovePlayerItem, id, iWeapon) )
        {
            user_has_weapon(id, iId, 0)
            ExecuteHamB(Ham_Item_Kill, iWeapon)
        }
        iWeapon = pNext
    }

    return 1
}