[villyvilly]

I am making a request here as well because I am not quite familiar with the topic categories here.

Just like the title stated, I am looking for a simple plugin, that gives "addcond 55" for 0.1 second, to a player when he/she does a "voicemenu 0 0" command, which is the "calling for medic" command.

From what I know, I can use AddCommandListener(OnVoiceMenu, "voicemenu");

I found a plugin by Tylerst, which can give addcond effects. It seems to be a good reference.

PHP Code:

#include <tf2>

public Plugin:myinfo =
{
    name = "TF2 Add Condition",
    author = "Tylerst",
    description = "Add a condition to the target(s)",
    version = "1.0.0",
    url = "None"
}

public OnPluginStart()
{
    LoadTranslations("common.phrases");
    RegAdminCmd("sm_addcond", Command_AddCondition, ADMFLAG_GENERIC, "Add a condition to the target(s), Usage: sm_addcond "target" "condition number" "duration"");
    RegAdminCmd("sm_removecond", Command_RemoveCondition, ADMFLAG_GENERIC, "Add a condition to the target(s), Usage: sm_removecond "target" "condition number"");
}

public Action:Command_AddCondition(client, args)
{

    if(args != 3)
    {
        ReplyToCommand(client, "[SM] Usage: sm_addcond "target" "condition number" "duration"");
        return Plugin_Handled;
    }

    new String:strBuffer[MAX_NAME_LENGTH], String:target_name[MAX_TARGET_LENGTH], target_list[MAXPLAYERS], target_count, bool:tn_is_ml;
    GetCmdArg(1, strBuffer, sizeof(strBuffer));
    if ((target_count = ProcessTargetString(strBuffer, client, target_list, MAXPLAYERS, COMMAND_FILTER_ALIVE, target_name, sizeof(target_name), tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }

    new iCondition, Float:flDuration;

    GetCmdArg(2, strBuffer, sizeof(strBuffer));
    iCondition = StringToInt(strBuffer);

    GetCmdArg(3, strBuffer, sizeof(strBuffer));
    flDuration = StringToFloat(strBuffer);    

    for(new i = 0; i < target_count; i++)
    {
        TF2_AddCondition(target_list[i], TFCond:iCondition, flDuration);
    }
    return Plugin_Handled;
}

public Action:Command_RemoveCondition(client, args)
{

    if(args != 2)
    {
        ReplyToCommand(client, "[SM] Usage: sm_removecond "target" "condition number"");
        return Plugin_Handled;
    }

    new String:strBuffer[MAX_NAME_LENGTH], String:target_name[MAX_TARGET_LENGTH], target_list[MAXPLAYERS], target_count, bool:tn_is_ml;
    GetCmdArg(1, strBuffer, sizeof(strBuffer));
    if ((target_count = ProcessTargetString(strBuffer, client, target_list, MAXPLAYERS, COMMAND_FILTER_ALIVE, target_name, sizeof(target_name), tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }

    new iCondition;

    GetCmdArg(2, strBuffer, sizeof(strBuffer));
    iCondition = StringToInt(strBuffer);

    for(new i = 0; i < target_count; i++)
    {
        TF2_RemoveCondition(target_list[i], TFCond:iCondition);
    }
    return Plugin_Handled;
} 


[PC Gamer]

This should do what you want. I added a timer to prevent command spamming.

PHP Code:

#include <tf2>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = 
{
    name = "Call for Medic",
    author = "PC Gamer",
    description = "Add condition when medic is called",
    version = "1.0",
    url = "www.sourcemod.com"    
}

bool g_wait[MAXPLAYERS + 1] = {false, ...}; 

public void OnPluginStart()
{
    AddCommandListener(Command_Listening, "voicemenu");
}

public Action Command_Listening(int client, char[] command, int args)
{
    char arguments[4];
    GetCmdArgString(arguments, sizeof(arguments));
    if (StrEqual(arguments, "0 0") && g_wait[client] == false)
    {
        //PrintToChatAll("Player %N called for a Medic", client);
        TF2_AddCondition(client, TFCond_RadiusHealOnDamage, 0.1);
        g_wait[client] = true;
        CreateTimer(10.0, Waiting, client); //How long you have to wait to use it again    
    }
    
    return Plugin_Continue;
}

public Action Waiting(Handle timer, any client) 
{
    g_wait[client] = false;
    
    return Plugin_Handled;     
} 


[villyvilly]

Originally Posted by PC Gamer This should do what you want. I added a timer to prevent command spamming. PHP Code: #include <tf2> #pragma semicolon 1 #pragma newdecls required public Plugin myinfo =  {     name = "Call for Medic",     author = "PC Gamer",     description = "Add condition when medic is called",     version = "1.0",     url = "www.sourcemod.com"     } bool g_wait[MAXPLAYERS + 1] = {false, ...};  public void OnPluginStart() {     AddCommandListener(Command_Listening, "voicemenu"); } public Action Command_Listening(int client, char[] command, int args) {     char arguments[4];     GetCmdArgString(arguments, sizeof(arguments));     if (StrEqual(arguments, "0 0") && g_wait[client] == false)     {         //PrintToChatAll("Player %N called for a Medic", client);         TF2_AddCondition(client, TFCond_RadiusHealOnDamage, 0.1);         g_wait[client] = true;         CreateTimer(10.0, Waiting, client); //How long you have to wait to use it again         }          return Plugin_Continue; } public Action Waiting(Handle timer, any client)  {     g_wait[client] = false;          return Plugin_Handled;      }

Thanks a lot! It works exactly what I wanted.

[ThatKidWhoGames]

Untested. Added a couple of ConVars for controlling plugin functionality, which is evident and self-explainable in the source code. Feel free to use it if you like!

PHP Code:

#include <sourcemod>
#include <tf2_stocks>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = {
    name        = "[TF2] 'MEDIC!' AddCond",
    author      = "PC Gamer, ThatKidWhoGames",
    description = "Gives a player radius healing for a configurable amount of time after calling for medic.",
    version     = "1.0.0",
    url         = "https://sourcemod.net/"
};

// Variables //
ConVar g_cvarEnable;            // Used for storing ConVar for enabling/disabling plugin functionality
ConVar g_cvarDelay;             // Used for storing ConVar for setting delay before a client can use this again
ConVar g_cvarTime;              // Used for storing ConVar for setting time for condition to last for
ConVar g_cvarCondition;         // Used for storing ConVar for condition to set
Handle g_timer[MAXPLAYERS + 1]; // Used for storing timer handle for client's usage delay

public void OnPluginStart() {
    // Create the ConVars
    g_cvarEnable    = CreateConVar("sm_callformedic_enable",    "1",   "Enable/disable the plugin",                                                    _, true, 0.0, true, 1.0);
    g_cvarDelay     = CreateConVar("sm_callformedic_delay",     "10",  "Delay (in seconds) before players can use the feature again (0 = No delay)", _, true, 0.0);
    g_cvarTime      = CreateConVar("sm_callformedic_time",      "0.1", "Time (in seconds) for the condition to last for",                              _, true, 0.1);
    g_cvarCondition = CreateConVar("sm_callformedic_condition", "55",  "Condition to give players");

    // Add the command listener
    AddCommandListener(CommandListener_VoiceMenu, "voicemenu");
}

public void OnClientDisconnect_Post(int client) {
    // Kill timer handle
    delete g_timer[client];
}

public Action CommandListener_VoiceMenu(int client, const char[] command, int argc) {
    // Check if plugin is enabled
    if (g_cvarEnable.BoolValue) {
        // Fetch arguments string
        char argstr[4];
        GetCmdArgString(argstr, sizeof(argstr));

        // Check if client indeed called for medic, is alive, and doesn't currently have the condition active
        if (StrEqual(argstr, "0 0") && IsPlayerAlive(client) && !TF2_IsPlayerInCondition(client, view_as<TFCond>(g_cvarCondition.IntValue))) {
            // Check if delay is enabled
            if (FloatCompare(0.0, g_cvarDelay.FloatValue) == -1) {
                // Check if client is not on cooldown
                if (g_timer[client] == null) {
                    // Create cooldown timer for client
                    g_timer[client] = CreateTimer(g_cvarDelay.FloatValue, Timer_Cooldown, client);
                }
                else {
                    // Skip execution; continue normally
                    return Plugin_Continue;
                }
            }

            // Add the condition to the client
            TF2_AddCondition(client, view_as<TFCond>(g_cvarCondition.IntValue), g_cvarTime.FloatValue);
        }
    }

    // Continue normally
    return Plugin_Continue;
}

public Action Timer_Cooldown(Handle timer, int client) {
    // Set timer handle to null
    g_timer[client] = null;

    // Stop execution (unnecessary, but I prefer explicitly stating it ;-) )
    return Plugin_Stop;
}