[Whai]

The "IsClientConnected" with "IsPlayerAlive" (I forgot about that) have to be after the comparison, because it would check on every client
Change "tp <client>" into "sm_tp <client>"

[Doggg]

so like this?

PHP Code:

#pragma semicolon 1

#define DEBUG

#define PLUGIN_AUTHOR ""
#define PLUGIN_VERSION "0.00"

#include <sourcemod>
#include <sdktools>
#include <cstrike>
//#include <sdkhooks>

#pragma newdecls required


public Plugin myinfo = 
{
    name = "",
    author = PLUGIN_AUTHOR,
    description = "",
    version = PLUGIN_VERSION,
    url = ""
};

public void OnPluginStart()
{
RegAdminCmd("sm_tp", tp, ADMFLAG_KICK);
}

public Action tp(int client, int args)
{
    if(args < 0)
    {
    ReplyToCommand(client, "[SM] tp <client>");
    return Plugin_Handled;
    }
    
    float origin[3];
    GetClientAbsOrigin(client, origin);  
    char Enteredname[30]; 
    GetCmdArg(1, Enteredname, sizeof(Enteredname));
    char Clientname[30];
    
    for (int i = 1; i <= MaxClients; i++){
        
            GetClientName(i, Clientname, sizeof(Clientname));
            if(StrEqual(Enteredname,Clientname)){
        
                if(IsClientConnected(i)){
            
                    if(IsPlayerAlive(i))
                    {
                    PrintToChat(client, "\x04 You Teleported \x03 %s",Clientname);
                    PrintToChat(i, "\x03 %s Teleported \x04 You",client);
                    TeleportEntity(i, origin, NULL_VECTOR, NULL_VECTOR);  
                    break;                            
                    }
                    else
                    {
                     ReplyToCommand(client, "Please Enter A Alive Player");
                     break;
                        }
                        
                }
        }
        
    }
    return Plugin_Handled;
} 


[Psyk0tik]

You're doing it all wrong. There's already a specific method for targeting players without checking for their names. In fact, finding players via name is bad practice.

Here's how it should be done:

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    RegAdminCmd("sm_tp", cmdTeleport, ADMFLAG_KICK, "Teleport a player to your position.");
}

public Action cmdTeleport(int client, int args)
{
    if (client <= 0 || client > MaxClients || !IsClientInGame(client) || !IsPlayerAlive(client))
    {
        ReplyToCommand(client, "[SM] You must be in-game and alive to teleport players to your position.");

        return Plugin_Handled;
    }

    switch (args)
    {
        case 1:
        {
            float flPos[3];
            GetClientAbsOrigin(client, flPos);

            char target[32], target_name[32];
            int target_list[MAXPLAYERS], target_count;
            bool tn_is_ml;
            GetCmdArg(1, target, sizeof(target));

            if ((target_count = ProcessTargetString(target, client, target_list, MAXPLAYERS, COMMAND_FILTER_NO_BOTS|COMMAND_FILTER_ALIVE, target_name, sizeof(target_name), tn_is_ml)) <= 0)
            {
                ReplyToTargetError(client, target_count);
                return Plugin_Handled;
            }

            for (int iPlayer = 0; iPlayer < target_count; iPlayer++)
            {
                if (0 < target_list[iPlayer] <= MaxClients && IsClientInGame(target_list[iPlayer]))
                {
                    TeleportEntity(target_list[iPlayer], flPos, NULL_VECTOR, NULL_VECTOR);
                    ReplyToCommand(client, "[SM] You teleported %N to your position.", target_list[iPlayer]);
                    PrintToChat(target_list[iPlayer], "[SM] You were teleported to %N's position.", client);
                }
            }
        }
        default: ReplyToCommand(client, "[SM] Usage: sm_tp <#userid|name>");
    }

    return Plugin_Handled;
} 


This allows you to use target filters like @red and @blue, and also allows you to target User IDs and Steam IDs. It's safer and more accurate.

[Doggg]

Originally Posted by Crasher_3637 You're doing it all wrong. There's already a specific method for targeting players without checking for their names. In fact, finding players via name is bad practice. Here's how it should be done: PHP Code: #include <sourcemod> #include <sdktools> #pragma semicolon 1 #pragma newdecls required public void OnPluginStart() {     RegAdminCmd("sm_tp", cmdTeleport, ADMFLAG_KICK, "Teleport a player to your position."); } public Action cmdTeleport(int client, int args) {     if (client <= 0 || client > MaxClients || !IsClientInGame(client) || !IsPlayerAlive(client))     {         ReplyToCommand(client, "[SM] You must be in-game and alive to teleport players to your position.");         return Plugin_Handled;     }     switch (args)     {         case 1:         {             float flPos[3];             GetClientAbsOrigin(client, flPos);             char target[32], target_name[32];             int target_list[MAXPLAYERS], target_count;             bool tn_is_ml;             GetCmdArg(1, target, sizeof(target));             if ((target_count = ProcessTargetString(target, client, target_list, MAXPLAYERS, COMMAND_FILTER_NO_BOTS|COMMAND_FILTER_ALIVE, target_name, sizeof(target_name), tn_is_ml)) <= 0)             {                 ReplyToTargetError(client, target_count);                 return Plugin_Handled;             }             for (int iPlayer = 0; iPlayer < target_count; iPlayer++)             {                 if (0 < target_list[iPlayer] <= MaxClients && IsClientInGame(target_list[iPlayer]))                 {                     TeleportEntity(target_list[iPlayer], flPos, NULL_VECTOR, NULL_VECTOR);                     ReplyToCommand(client, "[SM] You teleported %N to your position.", target_list[iPlayer]);                     PrintToChat(target_list[iPlayer], "[SM] You were teleported to %N's position.", client);                 }             }         }         default: ReplyToCommand(client, "[SM] Usage: sm_tp <#userid|name>");     }     return Plugin_Handled; }  This allows you to use target filters like @red and @blue, and also allows you to target User IDs and Steam IDs. It's safer and more accurate.

DUDEEEEEEE ITS SOO COMPLICATED, can you explain this code a bit? i am a begginer lol

[Psyk0tik]

Originally Posted by Doggg DUDEEEEEEE ITS SOO COMPLICATED, can you explain this code a bit? i am a begginer lol

I will try my best and start from top to bottom.

First, the if statement is saying that if the client has an invalid index OR is not in-game OR is dead, he/she cannot use the command.

Second, inside the switch statement... If the client enters more or less than 1 argument, a message will be displayed to him/her saying how to properly use the command. If the client enters 1 argument, the plugin will get the client's position (origin vector).

Lastly, once the client's origin vector is retrieved, the plugin will look through the current list of players and filter out any bots and dead players, and once it finds players that match the name (ex: Doggg), User ID, Steam ID, or target filter (ex: @red), those players will be teleported to the client.

Examples:

sm_tp Doggg - this will teleport you to me.
sm_tp #123 - this will teleport the client with the User ID of 123 to me.
sm_tp @red - this will teleport all players on red team to me.

The key function you need to access these targeting features is ProcessTargetString because it will allow the plugin to retrieve the list of players that match your argument and will loop through the list to teleport each player to your position.

PHP Code:

char target[32], target_name[32];
int target_list[MAXPLAYERS], target_count;
bool tn_is_ml;
GetCmdArg(1, target, sizeof(target)); // get the 1st argument of the command.

if ((target_count = ProcessTargetString(target, client, target_list, MAXPLAYERS, COMMAND_FILTER_NO_BOTS|COMMAND_FILTER_ALIVE, target_name, sizeof(target_name), tn_is_ml)) <= 0)
{
    ReplyToTargetError(client, target_count); // display error message to client if target(s) cannot be retrieved, if target cannot be found, etc.
    return Plugin_Handled;
} 


I hope this will give you some understanding of how the code works.

[Nexd]

You can get the client target like this:

PHP Code:

char argument[MAX_NAME_LENGTH];
GetCmdArg(1, argument, sizeof(argument));
int target = FindTarget(client, argument, true);