[4ever16]

If player disconnects he gets a reserved slot for 5 minutes.

This is so no one else can join for 5 minutes so that the disconencted player have chance to come back.

Hope someone can make it.

[4ever16]

Bump!

[fysiks]

Try this. I didn't test it but I think it should work.

-- plugin removed -- didn't quite work and Bugsy wrote his own version that looks like it should work.

[4ever16]

When i leave other players gets kicked.

Kicked by Console: "Player idle" Kicked :"Player idle"

[Bugsy]

Not tested, and reserved slots are lost at map change. Set SLOT_COUNT as needed.

PHP Code:


#include <amxmodx>

#define MAX_PLAYERS 32

const SLOT_COUNT = 5;

enum SlotInfo
{
    AuthID[ 34 ],
    DisconnectTime
}

new g_siSlots[ SLOT_COUNT ][ SlotInfo ];
new g_szAuthID[ MAX_PLAYERS + 1 ][ 34 ];
new bool:g_bKicked[ MAX_PLAYERS + 1 ];
new g_iUsedSlots;
new g_iMaxPlayers;
new g_pReserveTime;

new const g_szKickReason[] = "There are no unreserved slots, please try again later";

public plugin_init()
{
    register_plugin( "Disconnect Reserve Slot" , "0.1" , "bugsy" );
    
    g_pReserveTime = register_cvar( "drs_reserveminutes" , "5" );
    g_iMaxPlayers = get_maxplayers();
}

public client_disconnect( id )
{
    RefreshSlots();
    
    if ( !g_bKicked[ id ] )
    {
        AddSlot( id );
    }
}

public client_authorized( id )
{
    new iSlotID;
    
    RefreshSlots();
    get_user_authid( id , g_szAuthID[ id ] , charsmax( g_szAuthID[] ) );
    g_bKicked[ id ] = false;
    
    iSlotID = GetPlayerSlotID( id );
    
    if ( ( get_playersnum() + g_iUsedSlots ) > g_iMaxPlayers )
    {
        if ( iSlotID == -1 )
        {
            g_bKicked[ id ] = true;
            server_cmd( "kick #%d ^"%s^"" , get_user_userid( id ) , g_szKickReason );
        }
        else
        {
            g_siSlots[ iSlotID ][ AuthID ][ 0 ] = EOS;
            g_siSlots[ iSlotID ][ DisconnectTime ] = 0;
            g_iUsedSlots--;
        }
    }
    else if ( iSlotID != -1 )
    {
        g_siSlots[ iSlotID ][ AuthID ][ 0 ] = EOS;
        g_siSlots[ iSlotID ][ DisconnectTime ] = 0;
        g_iUsedSlots--;
    }
}

AddSlot( id )
{
    if ( g_iUsedSlots < SLOT_COUNT )
    {
        for ( new i = 0 ; i < sizeof( g_siSlots ) ; i++ )    
        {
            if ( g_siSlots[ i ][ AuthID ][ 0 ] == EOS )
            {
                copy( g_siSlots[ i ][ AuthID ] , charsmax( g_siSlots[][ AuthID ] ) , g_szAuthID[ id ] );
                g_siSlots[ i ][ DisconnectTime ] = get_systime();
                g_iUsedSlots++;
                break;
            }
        }
    }
}

GetPlayerSlotID( id )
{
    new iSlotID = -1;
    
    for ( new i = 0 ; i < sizeof( g_siSlots ) ; i++ )    
    {
        if ( equal( g_siSlots[ i ][ AuthID ] , g_szAuthID[ id ] ) )
        {
            iSlotID = i;
            break;
        }
    }
    
    return iSlotID;
}

RefreshSlots()
{
    new iSlotTime = ( get_pcvar_num( g_pReserveTime ) * 60 );
    new iSysTime = get_systime();
    
    for ( new i = 0 ; i < sizeof( g_siSlots ) ; i++ )
    {
        if ( g_siSlots[ i ][ DisconnectTime ] && ( ( g_siSlots[ i ][ DisconnectTime ] + iSlotTime ) < iSysTime ) )
        {
            g_siSlots[ i ][ AuthID ][ 0 ] = EOS;
            g_siSlots[ i ][ DisconnectTime ] = 0;
            g_iUsedSlots--;
        }
    }        
} 


[fysiks]

Originally Posted by 4ever16 When i leave other players gets kicked.

I'm not sure how my plugin would be related to that.

Also, I realized that in my version, I forgot to account for cases when a player doesn't come back. However, it looks like Bugsy wrote a version that takes into account some things that I didn't consider so it will be more likely to work.

Originally Posted by Bugsy Not tested, and reserved slots are lost at map change. Set SLOT_COUNT as needed.

Bugsy,

I think there is an oddity that will occur with your code. When a player with a reserved slot reconnects within the alotted time, it won't clear his reserved slot. So, there will still be a reserved slot until it expires and is removed with RefreshSlots().

This will occur when someone leaves/reconnects in a less than full server situation. For example, if there are 8 players and one disconnects and then reconnects within the 5 minutes, the slot check doesn't occur because iNum + g_iUsedSlots is only 9.

You'd need to check if there is a reserved slot for all connecting players if there are any reserved slots.

[Bugsy]

It will clear his slot since his slot id will return a non -1 value on connect and subsequently clear it. Also, all slots are pruned on every player connect and disconnect so it should not ever allow stale slots.

[fysiks]

Originally Posted by Bugsy It will clear his slot since his slot id will return a non -1 value on connect and subsequently clear it. Also, all slots are pruned on every player connect and disconnect so it should not ever allow stale slots.

Consider the following scenario:

• Maxplayers = 10
• Player count = 9
• 1 player leaves
• Slot get reserved for that player
• Player count = 8
• Same player reconnects 1 minute later
• Player count = 9
• iNum + g_iUsedSlots = 9 + 1
• ( iNum + g_iUsedSlots ) > g_iMaxPlayers => false
• GetPlayerSlotID( id ) is never called, slot is still reserved for 4 more minutes
• A 10th player joins
• Player count = 10
• iNum + g_iUsedSlots = 10 + 1
• ( iNum + g_iUsedSlots ) > g_iMaxPlayers => true
• GetPlayerSlotID( id ) returns -1
• 10th player gets kicked because that 9th player's slot is still reserved
• 10th player will get kicked for the next 4 minutes

I think you simply need to change the condition to g_iUsedSlots > 0. Also, since you're not using iPlayers, you can use get_playersnum() isntead. The other thing I noticed is that you're using definitions only defined for AMX Mod X 1.9+ (and, unfortunately, it's not release yet).

Let me know if I have a flaw in my logic there, I'm quite tired right now (should probably go to bed).

[Bugsy]

All of those bullets are making my head hurt. I give you props for putting that much thought into it.

But the fact that the slots will be freed every time a player connects and disconnects, you think there is still an issue?

[fysiks]

Originally Posted by Bugsy But the fact that the slots will be freed every time a player connects and disconnects, you think there is still an issue?

But that's not entirely true. Only expired reserved slots will be freed on every connect and disconnect. Clearing a slot that is not yet expired requires ( iNum + g_iUsedSlots ) > g_iMaxPlayers to return true which doesn't always happen (as shown in my above scenario).