[superang]

Hey everyone.
Can someone do a plug-in that in the server snows, and all guys when they connect have a Christmas hat?

Hat Attached.

[soolt]

I need too but that christmas hat will be invisible with human class on wc3ft mod.

[T-z3P]

Take a look on this :

http://forums.alliedmods.net/showthread.php?t=81172

and

http://forums.alliedmods.net/showthread.php?t=80382

[superang]

Yeah its like a fusion from both plugins.
Plugin winter has unnecessary bomb sounds, and xpaw plugin is just prefect but i dont wanna use both plugins.

[xPaw]

Have fun.

#include < amxmodx >
#include < engine >
#include < cstrike >
#include < hamsandwich >

new const g_szHatModel[ CsTeams ][ ] = {
    "",
    "models/santahat.mdl",
    "models/santahat_blue.mdl",
    ""
};

new g_iHats[ 33 ];

public plugin_init( ) {
    register_plugin( "Santa Hat + Snow", "1.3", "xPaw" );
    
    register_cvar( "santa_hat", "1.3", FCVAR_SERVER );
    
    register_event( "TeamInfo", "EventTeamInfo", "a" );
    
    RegisterHam( Ham_Spawn, "player", "FwdHamPlayerSpawn", 1 );
}

public plugin_precache( ) {
//  create_entity( "env_snow" );
    
    precache_model( g_szHatModel[ CS_TEAM_T ] );
    precache_model( g_szHatModel[ CS_TEAM_CT ] );
}

public client_disconnect( id )
    if( is_valid_ent( g_iHats[ id ] ) )
        remove_entity( g_iHats[ id ] );

public FwdHamPlayerSpawn( const id ) {
    if( is_user_alive( id ) ) {
        new iEntity = g_iHats[ id ];
        
        if( !is_valid_ent( iEntity ) ) {
            if( !( iEntity = g_iHats[ id ] = create_entity( "info_target" ) ) )
                return;
            
            new CsTeams:iTeam = cs_get_user_team( id );
            
            if( iTeam != CS_TEAM_T && iTeam != CS_TEAM_CT )
                iTeam = CS_TEAM_T;
            
            entity_set_model( iEntity, g_szHatModel[ iTeam ] );
            entity_set_int( iEntity, EV_INT_movetype, MOVETYPE_FOLLOW );
            entity_set_edict( iEntity, EV_ENT_aiment, id );
        }
    }
}

public EventTeamInfo( ) {
    new id = read_data( 1 ), iEntity = g_iHats[ id ];
    
    if( !is_valid_ent( iEntity ) ) {
        if( iEntity > 0 )
            g_iHats[ id ] = 0;
        
        return;
    }
    
    new szTeam[ 2 ];
    read_data( 2, szTeam, 1 );
    
    if( szTeam[ 0 ] == 'C' )
        entity_set_model( iEntity, g_szHatModel[ CS_TEAM_CT ] );
    else
        entity_set_model( iEntity, g_szHatModel[ CS_TEAM_T ] );
}

[T-z3P]

It's working xPaw . Can you make this plugin to enforce "cl_weather 3" on players on connect ?
And another thing : when using semi clip , the santa hat is solid (not transparent like the rest of the skin) . Can you solve this ?

[superang]

Thank you xPaw

[xPaw]

Originally Posted by T-z3P It's working xPaw . Can you make this plugin to enforce "cl_weather 3" on players on connect ?

Slow hacking (:

Originally Posted by T-z3P And another thing : when using semi clip , the santa hat is solid (not transparent like the rest of the skin) . Can you solve this ?

Umm... i don't want to hook massive forwards like prethink, so.. if no one going to give me better solution, no.

[soolt]

How to do hat invisible with human ? on war3ft mod human have a low visibility, but hat visible fine.

[T-z3P]

Why it's not working to enforce that command with this ?

PHP Code:

public client_connect(id)
    client_cmd(id,"cl_weather 3") 


LE : My bad , I didn't restarted the server ...