[redivcram]

This is a bit mind-boggling and I cannot find anything related to my issue. Is it even possible to refer arrays in dynamic/fake natives?

[Bugsy]

Can you show an example of what you're trying to accomplish?

[redivcram]

PHP Code:

// Plugin 1
public plugin_natives()
{
    register_library("fakenatives");
    
    register_native("FakeNative", "_FakeNative");
}

public _FakeNative(iPlugin, iParams) {
    
    // Do something to the parsed array?
} 


I wanna use the native as such:

PHP Code:

// Plugin 2
new myArray[8];

FakeNative(myArray);

// Do something with the modified array. 


Basically what I said in the first post.

[Bugsy]

Here's an example setting string and an array

PHP Code:


#include <amxmodx>

public plugin_init()
{
    register_plugin( "String/Array in Dynamic Natives" , "0.1" , "bugsy" );
}

public plugin_natives()
{
    register_library( "bugsy_test" );
    
    register_native( "get_steam_id","_get_steam_id" );
    register_native( "get_random_nums","_get_random_nums" );
}

public _get_steam_id( iPlugin , iParams )
{
    new szTmpStr[ 34 ];
    
    get_user_authid( get_param(1) , szTmpStr , charsmax( szTmpStr ) );
    set_string( 2 , szTmpStr , get_param( 3 ) );
}

public _get_random_nums( iPlugin , iParams )
{
    new iCount , iNumbers[ 10 ];
    
    iCount = get_param( 1 );
    
    if ( iCount > 10 ) 
        return -1;
        
    for ( new i = 0 ; i < iCount ; i++ )
    {
        iNumbers[ i ] = random( 5000 );
    }
    
    set_array( 2 , iNumbers , iCount );
    
    return iCount;
} 


PHP Code:

#pragma reqlib "bugsy_test"

native get_steam_id( id , szDest[] , iMaxChars )
native get_random_nums( iCount , iDest[] ) 


The plugin

PHP Code:


#include <amxmodx>
#include <bugsytest>

new const VERSION[] = "0.1";

public plugin_init() 
{
    register_plugin( "Native test" , VERSION , "bugsy" );
    
    register_clcmd( "say string" , "GetAuthID" );
    register_clcmd( "say array" , "RandomNumbers" );
}

public GetAuthID( id ) 
{    
    new szSteamID[ 33 ];
    get_steam_id( id , szSteamID, charsmax( szSteamID ) );
    server_print( "String value: %s" , szSteamID );
} 

public RandomNumbers( id ) 
{    
    new iNumbers[ 10 ];
    get_random_nums( 5 , iNumbers );
    server_print( "%d %d %d %d %d" , iNumbers[0] , iNumbers[1] ,iNumbers[2] ,iNumbers[3] ,iNumbers[4] );
} 


[redivcram]

Thanks! All seems to be working well for me.