[joac1144]

Hello,

I'm trying to make a plugin that creates a command which only should be able to activate one time pr. round.
Example:
I type !randombuff when the round begins, after that, I shouldn't be able to use the command again that round.

I have no idea how I can do that, so please come with an example

(I have already made the command, I only need the "one time per round" thing)

[Powerlord]

Well, it will go something like this:

PHP Code:

// outside any functions
new bool:g_bCommandUsed[MAXPLAYERS+1];

//in OnPluginStart, if you haven't already hooked it.
    HookEvent("round_start", Event_RoundStart);
    HookEventEx("teamplay_round_start", Event_RoundStart); // TF2-only

// and the actual round start event hook
public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    for (new i = 1; i <= MaxClients; i++)
    {
        g_bCommandUsed[i] = false;
    }
}

// When the command is used
    if (g_bCommandUsed[client])
    {
        PrintToChat(client, "You already used this command once this round.");
        return Plugin_Handled;
    }

    g_bCommandUsed[client] = true; 


You can find a real-world example of this in the TF2 PropHunt Redux plugin with its propreroll feature, although it only binds the TF2-specific round start.

[joac1144]

Originally Posted by Powerlord Well, it will go something like this: PHP Code: // outside any functions new bool:g_bCommandUsed[MAXPLAYERS+1]; //in OnPluginStart, if you haven't already hooked it.     HookEvent("round_start", Event_RoundStart);     HookEventEx("teamplay_round_start", Event_RoundStart); // TF2-only // and the actual round start event hook public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast) {     for (new i = 1; i <= MaxClients; i++)     {         g_bCommandUsed[i] = false;     } } // When the command is used     if (g_bCommandUsed[client])     {         PrintToChat(client, "You already used this command once this round.");         return Plugin_Handled;     }     g_bCommandUsed[client] = true;  You can find a real-world example of this in the TF2 PropHunt Redux plugin with its propreroll feature, although it only binds the TF2-specific round start.

Thank you for the fast reply!
But it doesn't work properly;
the second time I am using the command in a round, it prints the message, but the command still works.
Here's the FULL sourcecode:

Spoiler

PHP Code:

#include <sourcemod>
#include <morecolors>
#include <sdktools>

new bool:g_bCommandUsed[MAXPLAYERS+1];

public Plugin:myinfo =
{
    name = "Random buffs",
    author = "Born",
    description = "Gives you a random buff",
    version = "1.0",
    url = ""
};

public OnPluginStart()
{
    RegConsoleCmd("sm_randombuff", RandomBuffCmd, "Roll the dice!");
    HookEvent("player_spawn", PlayerSpawnEvent); 
    HookEvent("round_start", RoundStartEvent);
}

public Action:RandomBuffCmd(client, args)
{
    new randombuff = GetRandomInt(1, 5);
    new randomweapon = GetRandomInt(1, 4);
    new randommoney = GetRandomInt(1000, 5000);
    new money = GetEntProp(client, Prop_Send, "m_iAccount");
    new health = GetClientHealth(client);
    new randomhealth = GetRandomInt(10, 30);
    
    switch(randombuff)
    {
        case 1:
        {
            SetEntityHealth(client, health +randomhealth);
            CPrintToChat(client, "{green}[RandomBuff] {default}You got extra health!");
        }
        
        case 2:
        {
            SetEntityGravity(client, 0.7);
            CPrintToChat(client, "{green}[RandomBuff] {default}You got lower gravity!");
        }
        
        case 3:
        {
            SetEntProp(client, Prop_Send, "m_iAccount", money +randommoney); 
            CPrintToChat(client, "{green}[RandomBuff] {default}You got extra money!");
        }
        
        case 4:
        {
            SetEntPropFloat(client, Prop_Data, "m_flLaggedMovementValue", 1.4);
            CPrintToChat(client, "{green}[RandomBuff] {default}You got extra speed!");
        }
        
        case 5:
        {
            switch(randomweapon)
            {
                case 1:
                {
                    GivePlayerItem(client, "weapon_ak47");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got an AK47!");
                }
        
                case 2:
                {
                    GivePlayerItem(client, "weapon_m4a1");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got a M4A1!");
                }
        
                case 3:
                {
                    GivePlayerItem(client, "weapon_awp");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got an AWP!");
                }
        
                case 4:
                {
                    GivePlayerItem(client, "weapon_scout");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got a Scout!");
                }
            }
        }
    }
    
    if (g_bCommandUsed[client])
    {
        CPrintToChat(client, "{green}[RandomBuff] {default}You already have used Randombuff this round!");
        return Plugin_Handled;
    }
    
    g_bCommandUsed[client] = true;
    
    return Plugin_Handled;
}

public PlayerSpawnEvent(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));

    SetEntityGravity(client, 1.0);
}

public RoundStartEvent(Handle:event, const String:name[], bool:dontBroadcast)
{
    for (new i = 1; i <= MaxClients; i++)
    {
        g_bCommandUsed[i] = false;
    }
} 


]

[Mitchell]

It would probably work if you'd use the snippet he gave you. you're not even hooking round_start, you're hooking player_spawn, which is fired every player spawn, plus the loop.

[joac1144]

Originally Posted by Mitchell It would probably work if you'd use the snippet he gave you. you're not even hooking round_start, you're hooking player_spawn, which is fired every player spawn, plus the loop.

Woops!
I misread it...
But after changing it to what PowerLord actually said, it still does the same
I have updated my code to the new one

[Mitchell]

you put the code that is supposed to stop the command from executing after the code of the command...

PHP Code:

    if (g_bCommandUsed[client])
    {
        CPrintToChat(client, "{green}[RandomBuff] {default}You already have used Randombuff this round!");
        return Plugin_Handled;
    }
    
    g_bCommandUsed[client] = true; 


should be before anything happens in the code.

edited code:

PHP Code:

#include <sourcemod>
#include <morecolors>
#include <sdktools>

new bool:g_bCommandUsed[MAXPLAYERS+1];

public Plugin:myinfo =
{
    name = "Random buffs",
    author = "Born",
    description = "Gives you a random buff",
    version = "1.0",
    url = ""
};

public OnPluginStart()
{
    RegConsoleCmd("sm_randombuff", RandomBuffCmd, "Roll the dice!");
    HookEvent("player_spawn", PlayerSpawnEvent); 
    HookEvent("round_start", RoundStartEvent);
}

public Action:RandomBuffCmd(client, args)
{
    if (g_bCommandUsed[client])
    {
        CPrintToChat(client, "{green}[RandomBuff] {default}You already have used Randombuff this round!");
        return Plugin_Handled;
    }
    
    g_bCommandUsed[client] = true;
    ApplyRandomBuff(client);
    return Plugin_Handled;
}

public ApplyRandomBuff(client)
{
    switch(GetRandomInt(1, 5))
    {
        case 1:
        {
            SetEntityHealth(client, GetClientHealth(client) + GetRandomInt(10, 30));
            CPrintToChat(client, "{green}[RandomBuff] {default}You got extra health!");
        }
        
        case 2:
        {
            SetEntityGravity(client, 0.7);
            CPrintToChat(client, "{green}[RandomBuff] {default}You got lower gravity!");
        }
        
        case 3:
        {
            SetEntProp(client, Prop_Send, "m_iAccount", GetEntProp(client, Prop_Send, "m_iAccount") + GetRandomInt(1000, 5000)); 
            CPrintToChat(client, "{green}[RandomBuff] {default}You got extra money!");
        }
        
        case 4:
        {
            SetEntPropFloat(client, Prop_Data, "m_flLaggedMovementValue", 1.4);
            CPrintToChat(client, "{green}[RandomBuff] {default}You got extra speed!");
        }
        
        case 5:
        {
            switch(GetRandomInt(1, 4))
            {
                case 1:
                {
                    GivePlayerItem(client, "weapon_ak47");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got an AK47!");
                }
        
                case 2:
                {
                    GivePlayerItem(client, "weapon_m4a1");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got a M4A1!");
                }
        
                case 3:
                {
                    GivePlayerItem(client, "weapon_awp");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got an AWP!");
                }
        
                case 4:
                {
                    GivePlayerItem(client, "weapon_scout");
                    CPrintToChat(client, "{green}[RandomBuff] {default}You got a Scout!");
                }
            }
        }
    }
}

public PlayerSpawnEvent(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));

    SetEntityGravity(client, 1.0);
}

public RoundStartEvent(Handle:event, const String:name[], bool:dontBroadcast)
{
    for (new i = 1; i <= MaxClients; i++)
    {
        g_bCommandUsed[i] = false;
    }
} 


[joac1144]

Originally Posted by Mitchell you put the code that is supposed to stop the command from executing after the code of the command... PHP Code:     if (g_bCommandUsed[client])     {         CPrintToChat(client, "{green}[RandomBuff] {default}You already have used Randombuff this round!");         return Plugin_Handled;     }          g_bCommandUsed[client] = true;  should be before anything happens in the code. edited code: PHP Code: #include <sourcemod> #include <morecolors> #include <sdktools> new bool:g_bCommandUsed[MAXPLAYERS+1]; public Plugin:myinfo = {     name = "Random buffs",     author = "Born",     description = "Gives you a random buff",     version = "1.0",     url = "" }; public OnPluginStart() {     RegConsoleCmd("sm_randombuff", RandomBuffCmd, "Roll the dice!");     HookEvent("player_spawn", PlayerSpawnEvent);      HookEvent("round_start", RoundStartEvent); } public Action:RandomBuffCmd(client, args) {     if (g_bCommandUsed[client])     {         CPrintToChat(client, "{green}[RandomBuff] {default}You already have used Randombuff this round!");         return Plugin_Handled;     }          g_bCommandUsed[client] = true;     ApplyRandomBuff(client);     return Plugin_Handled; } public ApplyRandomBuff(client) {     switch(GetRandomInt(1, 5))     {         case 1:         {             SetEntityHealth(client, GetClientHealth(client) + GetRandomInt(10, 30));             CPrintToChat(client, "{green}[RandomBuff] {default}You got extra health!");         }                  case 2:         {             SetEntityGravity(client, 0.7);             CPrintToChat(client, "{green}[RandomBuff] {default}You got lower gravity!");         }                  case 3:         {             SetEntProp(client, Prop_Send, "m_iAccount", GetEntProp(client, Prop_Send, "m_iAccount") + GetRandomInt(1000, 5000));              CPrintToChat(client, "{green}[RandomBuff] {default}You got extra money!");         }                  case 4:         {             SetEntPropFloat(client, Prop_Data, "m_flLaggedMovementValue", 1.4);             CPrintToChat(client, "{green}[RandomBuff] {default}You got extra speed!");         }                  case 5:         {             switch(GetRandomInt(1, 4))             {                 case 1:                 {                     GivePlayerItem(client, "weapon_ak47");                     CPrintToChat(client, "{green}[RandomBuff] {default}You got an AK47!");                 }                          case 2:                 {                     GivePlayerItem(client, "weapon_m4a1");                     CPrintToChat(client, "{green}[RandomBuff] {default}You got a M4A1!");                 }                          case 3:                 {                     GivePlayerItem(client, "weapon_awp");                     CPrintToChat(client, "{green}[RandomBuff] {default}You got an AWP!");                 }                          case 4:                 {                     GivePlayerItem(client, "weapon_scout");                     CPrintToChat(client, "{green}[RandomBuff] {default}You got a Scout!");                 }             }         }     } } public PlayerSpawnEvent(Handle:event, const String:name[], bool:dontBroadcast) {     new client = GetClientOfUserId(GetEventInt(event, "userid"));     SetEntityGravity(client, 1.0); } public RoundStartEvent(Handle:event, const String:name[], bool:dontBroadcast) {     for (new i = 1; i <= MaxClients; i++)     {         g_bCommandUsed[i] = false;     } }

Thank you!
It works now.