[joac1144]

Warning 213: tag mismatch

PHP Code:

TF2_StunPlayer(target_list[i], duration, _, TF_STUNFLAG_THIRDPERSON, iAttacker); 


Warning 213: tag mismatch

PHP Code:

TF2_MakeBleed(target_list[i], iAttacker, duration); 


Can anyone please help me to fix this?
I really can't find out what is wrong with the tags

[Root_]

duration must be float value.

[joac1144]

Originally Posted by Root_ duration must be float value.

I'll just post the whole code.
Stun

PHP Code:

public Action:Command_Stun(client, args)
{
    new String:Target[32], String:time[32], String:attacker[32];
    new duration = GetConVarInt(sm_stun_duration);
 
    GetCmdArg(1, Target, sizeof(Target));
    
    if (args >= 2 && GetCmdArg(2, time, sizeof(time)))
    {
        duration = StringToInt(time);
    }
    
    GetCmdArg(3, attacker, sizeof(attacker));
    new iAttacker = FindTarget(client, attacker, false, true);
    
    if (args < 2)
    {
        PrintToChat(client, "[SM] Usage: sm_stun <name or #userid> <duration>");
    }
 
    new String:target_name[MAX_TARGET_LENGTH];
    new target_list[MAXPLAYERS], target_count;
    new bool:tn_is_ml;
 
    if ((target_count = ProcessTargetString(
            Target,
            client,
            target_list,
            MAXPLAYERS,
            COMMAND_FILTER_ALIVE,
            target_name,
            sizeof(target_name),
            tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }
 
    for (new i = 0; i < target_count; i++)
    {
        TF2_StunPlayer(target_list[i], duration, _, TF_STUNFLAG_THIRDPERSON, iAttacker);
        LogAction(client, target_list[i], "Admin %L stunned %L", client, target_list[i]);
    }
 
    if (tn_is_ml)
    {
        ShowActivity2(client, "[SM] ", "Stunned %s", target_name);
    }
    else
    {
        ShowActivity2(client, "[SM] ", "Stunned %s", target_name);
    }
 
    return Plugin_Handled;
} 


Bleed

PHP Code:

public Action:Command_Bleed(client, args)
{
    new String:Target[32], String:time[32];
    new duration = GetConVarInt(sm_bleed_duration);
 
    GetCmdArg(1, Target, sizeof(Target));
    
    if (args >= 2 && GetCmdArg(2, time, sizeof(time)))
    {
        duration = StringToInt(time);
    }
    
    if (args < 2)
    {
        PrintToChat(client, "[SM] Usage: sm_bleed <name or #userid> <duration>");
    }
 
    new String:target_name[MAX_TARGET_LENGTH];
    new target_list[MAXPLAYERS], target_count;
    new bool:tn_is_ml;
 
    if ((target_count = ProcessTargetString(
            Target,
            client,
            target_list,
            MAXPLAYERS,
            COMMAND_FILTER_ALIVE,
            target_name,
            sizeof(target_name),
            tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }
 
    new String:attacker[32];
    GetCmdArg(3, attacker, sizeof(attacker));
    new iAttacker = FindTarget(client, attacker);
 
    for (new i = 0; i < target_count; i++)
    {
        TF2_MakeBleed(target_list[i], iAttacker, duration);
        LogAction(client, target_list[i], "Admin %L toggled bleed on %L", client, target_list[i]);
    }
 
    if (tn_is_ml)
    {
        ShowActivity2(client, "[SM] ", "Toggled bleed on %s", target_name);
    }
    else
    {
        ShowActivity2(client, "[SM] ", "Toggled bleed on %s", target_name);
    }
 
    return Plugin_Handled;
} 


>This is not the WHOLE plugin code, but the whole code of the commands<

[KissLick]

The question is already answered..

[Powerlord]

Originally Posted by joac1144 It IS a float value, I have set it to 5.0

PHP Code:

new duration = GetConVarInt(sm_stun_duration); 


No it isn't, you're reading it out as an int. What you need is

PHP Code:

new Float:duration = GetConVarFloat(sm_stun_duration); 


[ddhoward]

It must be a float. You may SAY that you are using a float, but you are lying. You are even using GetConVarInt() and StringToInt(). Int is not the same thing as float. Int means integer. Integers are not floating point values.

Change this:

new duration = GetConVarInt(sm_stun_duration);

to this:

new Float:duration = GetConVarFloat(sm_stun_duration);

This:

duration = StringToInt(time);

to this:

duration = StringToFloat(time);

[KissLick]

This is not like Python or PHP.. look at tut on SM wiki.

[joac1144]

Thank you!
Now it will compile