[Avo]

Hi,

Since an august update (don't know which), my plugin doesn't work anymore. To be precise, it make the server crash on the GivePlayerItem(client, "weapon_c4");
It worked before without any problem, but now I can't find the right fix.

Here is the code :

public Action:CS_OnCSWeaponDrop(client, weapon)
{
	if (IsClientConnected(client) && IsClientInGame(client) && IsPlayerAlive(client) && IsValidEdict(weapon))
	{
		decl String:sWeapon[64];
		GetEdictClassname(weapon, sWeapon, 64);
		if (StrEqual(sWeapon, "weapon_c4"))
		{
			g_iWeaponC4 = weapon;
			CreateTimer(0.1, TimerDropBomb, client);
		}
	}
	return Plugin_Continue;
}

public Action:TimerDropBomb(Handle:timer, any:client)
{
	if (IsClientConnected(client) && IsClientInGame(client) && IsPlayerAlive(client) && IsValidEdict(g_iWeaponC4))
	{
		AcceptEntityInput(g_iWeaponC4, "kill");
		GivePlayerItem(client, "weapon_c4");
	}
}

I tried moving or removing the AcceptEntityInput, replacing it with a RemoveEdict, anyway those commands pass, it's always the GivePlayerItem which crash. And other bomb plugins (like Bomb Commands or Request Bomb) work the same way (I don't know if they are broken too).


Could someone help me ?

[TnTSCS]

what version do you have on your server for metamod and source mod?

[Avo]

MetaMod:Source v1.10.0-devV,
SourceMod v1.6.0-dev+3865

[thetwistedpanda]

Try using the 1.5 snapshot branch instead; 1.6 still has experimental changes. And I'll just leave this here, I was bored.

Spoiler

PHP Code:

public Action:CS_OnCSWeaponDrop(client, weapon)
{
    if(!IsValidEdict(weapon) || !IsClientInGame(client) || !IsPlayerAlive(client))
        return Plugin_Continue;

    decl String:sWeapon[32];
    GetEdictClassname(weapon, sWeapon, sizeof(sWeapon));
    if(!StrEqual(sWeapon, "weapon_c4"))
        return Plugin_Continue;
        
    new Handle:hPack = INVALID_HANDLE;
    CreateDataTimer(0.1, Timer_DropBomb, hPack);
    WritePackCell(hPack, GetClientUserId(client));
    WritePackCell(hPack, EntIndexToEntRef(weapon));

    return Plugin_Continue;
}

public Action:Timer_DropBomb(Handle:timer, Handle:pack)
{
    ResetPack(pack);
    new client = GetClientOfUserId(ReadPackCell(pack));        
    new entity = EntRefToEntIndex(ReadPackCell(pack));
    if(entity != INVALID_ENT_REFERENCE)
        AcceptEntityInput(entity, "Kill");
        
    if(client && IsPlayerAlive(client) && GetPlayerWeaponSlot(client, CS_SLOT_C4) == -1)    
        GivePlayerItem(client, "weapon_c4");
} 


[Avo]

Thanks a lot, it's indeed the 1.6 branch which isn't functional anymore on this feature. Works great with 1.5.1.

And thanks for your bored work, I'll definitely use it. ;)

[asherkin]

Originally Posted by Avo Thanks a lot, it's indeed the 1.6 branch which isn't functional anymore on this feature. Works great with 1.5.1.

The snapshot of 1.6 you were using is very, very old. Would you please consider testing on the latest one - there are no known issues with it and we really need to know if something is broken.

[Avo]

No problem with SourceMod v1.6.0-dev+4118, I should have look into that first.

However, now that 1.5 is fully operationnal on CSGO, and just FMI, what are main benefits and features, to pass on dev 1.6 ? (and stay up to date of course).

Thanks