[claudiuhks]

I am wondering how I can block +reload/ -reload player command in CSGO, because I want to block this command for those who have Unlimited Clip feature enabled.

RegConsoleCmd("(+|-)reload", OnReload) and then returning Plugin_Handled or Stop doesn't work.

Thanks.

[TheUnderTaker]

If it doesn't work for you, apperantly it's client side, I'm unsure cause i'm not a programmer for cs:go.

[KissLick]

Have you tried SDKHook_Reload ?

-> https://sm.alliedmods.net/new-api/sdkhooks/__raw

[claudiuhks]

Originally Posted by KissLick Have you tried SDKHook_Reload ? -> https://sm.alliedmods.net/new-api/sdkhooks/__raw

Tested and doesn't work.

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <cstrike>

public OnPluginStart()
{
    CreateTimer(0.33, TimerReload, _, TIMER_REPEAT);
}

public Action:OnWpnReload(Weapon)
{
    static Owner = 0;

    if (Weapon != INVALID_ENT_REFERENCE && IsValidEdict(Weapon))
    {
        Owner = GetEntProp(Weapon, Prop_Send, "m_hOwner");

        if (Owner != INVALID_ENT_REFERENCE && Owner >= 1 && Owner <= MaxClients && \
            IsClientInGame(Owner) && IsPlayerAlive(Owner))
            return Plugin_Stop;
    }

    return Plugin_Continue;
}

public OnEntityCreated(Entity, const String:className[])
{
    if (Entity != INVALID_ENT_REFERENCE && IsValidEdict(Entity) && StrContains(className, "Weapon", false) != -1)
        SDKHook(Entity, SDKHook_Reload, OnWpnReload);
}

public OnEntityDestroyed(Entity)
{
    if (Entity != INVALID_ENT_REFERENCE)
        SDKUnhook(Entity, SDKHook_Reload, OnWpnReload);
}

public Action:TimerReload(Handle:pTimer)
{
    static Weapon = 0, Client = 0, String:Class[64];

    for (Client = 1; Client <= MaxClients; Client++)
    {
        if (!IsClientInGame(Client) || !IsPlayerAlive(Client))
            continue;

        Weapon = GetEntPropEnt(Client, Prop_Send, "m_hActiveWeapon");

        if (Weapon != INVALID_ENT_REFERENCE && IsValidEdict(Weapon) && GetEdictClassname(Weapon, Class, sizeof(Class)))
        {
            if (StrContains(Class, "Knife", false) == -1 && \
                StrContains(Class, "Taser", false) == -1 && \
                StrContains(Class, "Grenade", false) == -1 && \
                StrContains(Class, "Flash", false) == -1 && \
                StrContains(Class, "Smoke", false) == -1 && \
                StrContains(Class, "Incendiary", false) == -1 && \
                StrContains(Class, "Molotov", false) == -1 && \
                StrContains(Class, "Projectile", false) == -1 && \
                StrContains(Class, "Defuse", false) == -1 && \
                StrContains(Class, "Kit", false) == -1 && \
                StrContains(Class, "Zeus", false) == -1 && \
                StrContains(Class, "Bang", false) == -1 && \
                StrContains(Class, "Decoy", false) == -1)
            {
                SetEntProp(Weapon, Prop_Send, "m_iClip1", 32);
                SetEntProp(Weapon, Prop_Send, "m_iClip2", 32);
            }
        }
    }
} 


[Potato Uno]

Originally Posted by TheUnderTaker If it doesn't work for you, apperantly it's client side, I'm unsure cause i'm not a programmer for cs:go.

It's DEFINITELY not client side since the server needs to be informed if a client loads a clip.

Do you need to use a command listener maybe? (Just guessing.)

[claudiuhks]

Originally Posted by Potato Uno Do you need to use a command listener maybe? (Just guessing.)

I've tried with AddCommandListener(CmdReload, "(+|-)reload"), and still doesn't work. If this is what you mean.

[Powerlord]

Owner = GetEntProp(Weapon, Prop_Send, "m_hOwner");

should probably be

Owner = GetEntPropEnt(Weapon, Prop_Send, "m_hOwner");

[Icon315]

This should work, I used it for a paintball game I made. It will still run the reload animation for the client, since that part is client side, but it will not reload their weapon.

PHP Code:

#include <sdkhooks> 
#include <sdktools> 

public Action:OnPlayerRunCmd(client, &buttons)
{
    if(!(buttons & IN_RELOAD))
    {
        return Plugin_Continue;
    }
    else
    {
        buttons &= ~IN_RELOAD;
        return Plugin_Changed;
    }
} 


[claudiuhks]

Originally Posted by Powerlord Owner = GetEntProp(Weapon, Prop_Send, "m_hOwner"); should probably be Owner = GetEntPropEnt(Weapon, Prop_Send, "m_hOwner");

Thank God, hon. It did really work! Appreciate!
Where's the Thank button when you need it...

Originally Posted by Icon315 This should work, I used it for a paintball game I made. It will still run the reload animation for the client, since that part is client side, but it will not reload their weapon.

Thank you too.

[Powerlord]

And since that apparently was the solution, I'll mention one more thing:

If a netprop or datamap has an h before the name (i.e. m_hSomething) it requires GetEntPropEnt because it's wrapped in a EHandle/CHandle on the server side. Which is similar to a SourceMod reference, but slightly different.

Actually, does SourceMod even have a function to convert from a Source reference to a SourceMod reference? I think MakeCompatEntRef is to go the other direction (SourceMod reference to Source reference).