[B3none]

I haven't written anything for a while ^^

PHP Code:

#include <sourcemod>
#include <sdktools>
 
#pragma newdecls required
#pragma semicolon 1

#define TAG_MESSAGE "[\x02VIP\x01]"

public Plugin myinfo =
{
    name = "Give VIP",
    author = "B3none",
    description = "Temporarily give players VIP in the server.",
    version = "0.1.0",
    url = "https://forums.alliedmods.net/showthread.php?t=301305"
};

public void OnPluginStart()
{
    RegAdminCmd("sm_addstatus", addStatus, ADMFLAG_GENERIC);
}

public Action addStatus(int client, int target)
{
    if (!IsValidClient(client) || !IsValidClient(target)) {
        return;
    }
    
    
    char clientName[64];
    char targetName[64];
    
    GetClientName(client, clientName, strlen(clientName));
    GetClientName(target, targetName, strlen(targetName));
    
    if (CheckCommandAccess(target, "sm_admin_check", ADMFLAG_RESERVATION)) {
        AddUserFlags(target, Admin_Reservation);
    }
    
    PrintToChatAll("%s %s granted VIP access to %s", TAG_MESSAGE, clientName, targetName);
}

stock bool IsValidClient(int client)
{
    return (client <= 0 || client > MAXPLAYERS+1 || !IsClientInGame(client));
} 


In theory this code should work but if anyone else wants to suggest otherwise by all means do so

If you have any questions then feel free to ask and I will explain what I have written to you from a PHP developers perspective

[bbz]

Originally Posted by Bacardi Btw @op, are you using any other admin plugins (ex. SourceBans?) than SM basic admin system ?

sourcebans

Thanks.

[bbz]

Originally Posted by b3none I haven't written anything for a while ^^ PHP Code: #include <sourcemod> #include <sdktools>   #pragma newdecls required #pragma semicolon 1 #define TAG_MESSAGE "[\x02VIP\x01]" public Plugin myinfo = {     name = "Give VIP",     author = "B3none",     description = "Temporarily give players VIP in the server.",     version = "0.1.0",     url = "https://forums.alliedmods.net/showthread.php?t=301305" }; public void OnPluginStart() {     RegAdminCmd("sm_addstatus", addStatus, ADMFLAG_GENERIC); } public Action addStatus(int client, int target) {     if (!IsValidClient(client) || !IsValidClient(target)) {         return;     }               char clientName[64];     char targetName[64];          GetClientName(client, clientName, strlen(clientName));     GetClientName(target, targetName, strlen(targetName));          if (CheckCommandAccess(target, "sm_admin_check", ADMFLAG_RESERVATION)) {         AddUserFlags(target, Admin_Reservation);     }          PrintToChatAll("%s %s granted VIP access to %s", TAG_MESSAGE, clientName, targetName); } stock bool IsValidClient(int client) {     return (client <= 0 || client > MAXPLAYERS+1 || !IsClientInGame(client)); }  In theory this code should work but if anyone else wants to suggest otherwise by all means do so If you have any questions then feel free to ask and I will explain what I have written to you from a PHP developers perspective

Thank you, but maybe my english is not that good, so you understand wrong. I want something, maybe with a "db" so i mannualy add some codes, imagine ( xkaoskd, qoekqwoek, lroqwlro ), 30 each code gives 30 days of VIP. To use the code you go inside the server and do "!vip xkaoskd", after that the code "xkaoskd" is not usable anymore.

Sorry for bad english :/

[B3none]

Ahh, I see what you mean, my SQL skills with SP are very limited and certainly very insecure, I think that the code I wrote may infact need an alteration I can look into doing it tomorrow for you. It sounds like quite a fun little task!

I suggest you look up using and integrating a database with the code i.e. connecting / editing rows and I will write the code generation and the other parts

[BraveFox]

Btw there is my VIP plugin, you can take it and edit it to be as you want it.

[B3none]

I'm still writing this and it can be found on my Github,

Github Link

Current code:

PHP Code:

#include <sourcemod>
#include <sdktools>
 
#pragma newdecls required
#pragma semicolon 1

#define TAG_MESSAGE "[\x02VIP\x01]"
#define TOKEN_LIMIT 6

static const char vipCodes[][] =
{
    "adszxc",
    "moomoo",
};

static const char developerArgs[][] =
{
    "debug",
};

static const char tokenCharacters[][] =
{
    "a", "b", "c", "d", "e", "f",
    "g", "h", "i", "j", "k", "l",
    "m", "n", "o", "p", "q", "r",
    "s", "t", "u", "v", "w", "x",
    "y", "z", "A", "B", "C", "D",
    "E", "F", "G", "H", "I", "J",
    "K", "L", "M", "N", "O", "P",
    "Q", "R", "S", "T", "U", "V",
    "W", "X", "Y", "Z", "0", "1",
    "2", "3", "4", "5", "6", "7",
    "8", "9"
};

public Plugin myinfo =
{
    name = "Give VIP",
    author = "B3none",
    description = "Temporarily give players VIP in the server.",
    version = "0.1.2",
    url = "https://forums.alliedmods.net/showthread.php?t=301305"
};

public void OnPluginStart()
{
    RegConsoleCmd("sm_vip", checkCode);
    RegAdminCmd("sm_addstatus", addStatus, ADMFLAG_ROOT);
    RegAdminCmd("sm_generate", generateNewCode, ADMFLAG_ROOT);
}

public Action generateNewCode(int client, int args)
{
    char newToken[TOKEN_LIMIT];
    
    char argString[64];
    GetCmdArgString(argString, sizeof(argString));
    
    bool debugState = false;
    
    if (strlen(argString) > 0) {
        if (StrEqual(argString, developerArgs[0])) {
            PrintToChat(client, "%s Debug mode initiated.", TAG_MESSAGE);
            debugState = true;
        }
    }
    
    for (int i = 1; i <= TOKEN_LIMIT && strlen(newToken) < TOKEN_LIMIT; i++) {
        Format(newToken, sizeof(newToken), "%s%s", newToken, tokenCharacters[GetRandomInt(1, sizeof(tokenCharacters))]);
        if (debugState) {
            PrintToChat(client, "%s Current token: %s (increment %i / %i)", TAG_MESSAGE, newToken, i, TOKEN_LIMIT);
        }
    }
    
    char clientName[64];
    GetClientName(client, clientName, sizeof(clientName));
    
    if (debugState) {
        PrintToChat(client, "%s Token to be added: %s", TAG_MESSAGE, newToken);
    }
    
    // Add code to database
    
    PrintToChat(client, "%s The generated code is %s", TAG_MESSAGE, newToken);
    LogMessage("%s %s generated code \"%s\"", TAG_MESSAGE, clientName, newToken);
}

public Action checkCode(int client, int args)
{
    char code[64];
    GetCmdArgString(code, sizeof(code));
    
    if (strlen(code) > TOKEN_LIMIT) {
        PrintToChat(client, "%s Invalid token.", TAG_MESSAGE);
        return;
    }
    
    for (int i = 0; i <= sizeof(vipCodes); i++) {
        if (StrEqual(code, vipCodes[i])) {
            addStatus(0, client);
            
            // Remove used code from the database
            
            break;
        }
    }
    
    PrintToChat(client, "%s Invalid token.", TAG_MESSAGE);
}

public Action addStatus(int client, int target)
{
    if ((!IsValidClient(client) && client != 0) || !IsValidClient(target)) {
        return;
    }
    
    char clientName[64];
    char targetName[64];
    
    GetClientName(client, clientName, sizeof(clientName));
    GetClientName(target, targetName, sizeof(targetName));
    
    if (CheckCommandAccess(target, "sm_admin_check", ADMFLAG_RESERVATION)) {
        AddUserFlags(target, Admin_Reservation);
    }
    
    if (client == 0) {
        PrintToChatAll("%s %s was granted VIP access via a secret token", TAG_MESSAGE, targetName);
    } else {
        PrintToChatAll("%s %s granted VIP access to %s", TAG_MESSAGE, clientName, targetName);
    }
}

stock bool IsValidClient(int client)
{
    return (client <= 0 || client > MaxClients || !IsClientInGame(client));
} 


[Bacardi]

If I have tomorrow some energy and inspiration after nightshift, I could post first version... let see.
I have just check how SourceBans work for now.

[bbz]

Thanks you guys! i'll be waiting

[Bacardi]

youtube video

Ok. I'm not sure how much you know MySQL+phpMyAdmin

But in your SourceBans:
Group Management
» Home » Admin Panel » Group management
- Create Server Admin Group, name it example "vip"
- Give flag(s) or you can also override commands (allow|deny).


Then you need get to SourceBans database (phpMyAdmin ?)
- Select same database where are SourceBans tables.
- Below is SQL command, you maybe not need that red part

MySQL database table

CREATE TABLE `sb_vip_random_codes` (
 `code` varchar(10) NOT NULL DEFAULT '',
 `steamid` varchar(30) DEFAULT NULL,
 `expire` date DEFAULT NULL,
 `admin_group` varchar(30) NOT NULL DEFAULT 'vip',
 PRIMARY KEY (`code`)
) ENGINE=InnoDB DEFAULT CHARSET=utf8

Once you have this extra table in SourceBans database (sb_vip_random_codes)
- Insert row, fill only code and admin_group part.
In code set only letters and numbers, in admin_group set your admin group name "vip"






Here plugin, first release. Maybe not perfect.
https://www.sourcemod.net/compiler.php

command is
sm_vip_code C0d3

- In those servers where you install this plugin, it creates admins from sb_vip_random_codes table (steamid and expire date)
You can't see them in SourceBans, its into SM local admin system. (See server admin dumb file)
- When player activate code, it will be working 1 month.
- You can also create "codes" for different admin groups, not need to be specific "vip" named.
- You can also let one player activate multiple codes and join multiple admin groups.
But this plugin not set admin groups in right order like it should.

PHP Code:


#include <regex>


public void OnRebuildAdminCache(AdminCachePart part)
{
    switch(part)
    {
        case AdminCache_Admins:
        {
            if(SQL_CheckConfig("sourcebans"))
            {
                SQL_TConnect(Connect_callback, "sourcebans");
            }
        }
    }
}

public void OnPluginStart()
{
    RegConsoleCmd("sm_vip_code", vip_code);
}

public Action vip_code(int client, int arg)
{

    // no console, connecting players, bots, not authorized
    if(client == 0 || !IsClientInGame(client) || IsFakeClient(client) || !IsClientAuthorized(client)) return Plugin_Handled;

    if(arg < 1)
    {
        ReplyToCommand(client, "[SM] Usage:sm_vip_code R4nd0mC0d3");
        return Plugin_Handled;
    }


    static spamblock[MAXPLAYERS+1];

    int time = GetTime();

    if(time < spamblock[client])
    {
        ReplyToCommand(client, "[SM] Do not spam command!");
        return Plugin_Handled;
    }

    spamblock[client] = time + 3;



    char args[20];
    GetCmdArgString(args, sizeof(args));


    if(SimpleRegexMatch(args, "[^a-zA-Z0-9]") > 0)
    {
        ReplyToCommand(client, "[SM] Random code only numbers and letters, a-z, A-Z, 0-9");
        return Plugin_Handled;
    }

    
    if(SQL_CheckConfig("sourcebans"))
    {
        Database DB = SQL_Connect("sourcebans", false, "", 0);

        if(DB == null) return Plugin_Handled;


        char buffer[300];

        Format(buffer, sizeof(buffer), "SELECT admin_group FROM sb_vip_random_codes WHERE code = '%s';", args);
        //PrintToServer("%s", buffer);
        DBResultSet result = SQL_Query(DB, buffer, sizeof(buffer));

        if(result == null)
        {
            SQL_GetError(DB, buffer, sizeof(buffer));
            LogError("%s", buffer);
            delete DB;
            return Plugin_Handled;
        }

        if(SQL_FetchRow(result))
        {
            SQL_FetchString(result, 0, buffer, sizeof(buffer));

            GroupId group = FindAdmGroup(buffer);
            if(group != INVALID_GROUP_ID)
            {
                GetClientAuthId(client, AuthId_Steam2, buffer, sizeof(buffer));

                Format(buffer, sizeof(buffer), "UPDATE sb_vip_random_codes SET steamid = '%s', expire = DATE_ADD(CURRENT_DATE, INTERVAL 1 MONTH) WHERE code = '%s'", buffer, args);
                //PrintToServer(buffer);

                if(!SQL_FastQuery(DB, buffer))
                {
                    SQL_GetError(DB, buffer, sizeof(buffer));
                    LogError("%s", buffer);                    
                }
                else
                {
                    SQL_TConnect(Connect_callback, "sourcebans");
                }
            }
        }

        delete result;
        delete DB;
    }

    return Plugin_Handled;
}


public void Connect_callback(Handle owner, Handle hndl, const char[] error, any data)
{
    if(hndl == null) return;

    char buffer[300];

    
    Format(buffer, sizeof(buffer), "SELECT steamid, admin_group FROM sb_vip_random_codes WHERE expire >= CURDATE() AND steamid REGEXP '^STEAM_[[:digit:]]\\:[[:digit:]]\\:[[:digit:]]+$'"); //"STEAM_1:1:111111"
    SQL_TQuery(hndl, Query_callback, buffer, data, DBPrio_Low);

    delete hndl;
}

public void Query_callback(Handle owner, Handle hndl, const char[] error, any data)
{

    if(hndl == null)
    {
        SetFailState("ERROR - %s", error);
    }


    GroupId group;
    AdminId admin;

    char buffer[300];

    while (SQL_FetchRow(hndl))
    {
        SQL_FetchString(hndl, 1, buffer, sizeof(buffer));

        group = FindAdmGroup(buffer);
        if(group == INVALID_GROUP_ID) continue; // No such admin group on server

        SQL_FetchString(hndl, 0, buffer, sizeof(buffer));

        admin = FindAdminByIdentity("steam", buffer);

        if(admin == INVALID_ADMIN_ID)
        {
            admin = CreateAdmin("vip");
            if(!BindAdminIdentity(admin, "steam", buffer))
            {
                RemoveAdmin(admin);
                continue;
            }
        }

        bool IsInGroup;

        for(int x = 0; x < GetAdminGroupCount(admin); x++)
        {
            if(GetAdminGroup(admin, x, "", 0) == group)
            {
                IsInGroup = true;
                break;
            }
        }

        if(IsInGroup) continue;

        AdminInheritGroup(admin, group);
    }
}